Télécharger la plaquette Cast3M


fr en

Télécharger topoacti.procedur

Retour à la liste

Numérotation des lignes : 

  1. * TOPOACTI  PROCEDUR  FD218221  23/11/29    21:15:05     11799          
  2. * TOPOACTI  PROCEDUR  CB215821  21/04/15    14:10:01     9715
  3.  
  4. ************************************************************************
  5. ** Procedure called by TOPOPTIM for generating the mesh, model,
  6. ** material and contact of the active zone.
  7. **
  8. ** Author:
  9. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  10. **
  11. ** Version:
  12. ** 1.0 2021/04/15
  13. ************************************************************************
  14.  
  15. DEBP TOPOACTI tab0*'TABLE' ;
  16.  
  17. * Input data
  18. * **********
  19.  
  20. wtab0 = tab0.'WTABLE' ;
  21. bool0 = wtab0.'BOOL' ;
  22.  
  23. * Cleaning previous step
  24. * **********************
  25.  
  26. OTER (wtab0.'MAILLAGE') 'A' ;
  27. SI bool0.'MECANIQUE' ;
  28.     OTER (wtab0.'MECANIQUE'.'MODELE') 'A' ;
  29.     OTER (wtab0.'MECANIQUE'.'CARACTERISTIQUES') 'A' ;
  30. FINS ;
  31. SI bool0.'THERMIQUE' ;
  32.     OTER (wtab0.'THERMIQUE'.'MODELE') 'A' ;
  33.     OTER (wtab0.'THERMIQUE'.'CARACTERISTIQUES') 'A' ;
  34. FINS ;
  35. SI bool0.'CONTACT' ;
  36.     OTER (wtab0.'CONTACT'.'MODELE') 'A' ;
  37.     OTER (wtab0.'CONTACT'.'CARACTERISTIQUES') 'A' ;
  38. FINS ;
  39. OTER (wtab0.'RESOLUTION') 'A' ;
  41.  
  42. * Active mesh
  43. * ***********
  44.  
  45. SI bool0.'ZONE_FIGEE' ;
  46.     mshA = (wtab0.'MAXDENSITE' + wtab0.'UN'.(2)) ELEM 'SUPE' tab0.'SEUIL' ;
  47. SINO ;
  48.     mshA = wtab0.'MAXDENSITE' ELEM 'SUPE' tab0.'SEUIL' ;
  49. FINS ;
  50. wtab0.'MAILLAGE'.'A' = mshA ;
  51.  
  52. * Active model
  53. * ************
  54.  
  55. SI bool0.'MECANIQUE' ;
  56.     wtab0.'MECANIQUE'.'MODELE'.'A' = REDU wtab0.'MECANIQUE'.'MODELE'.(0) mshA ;
  57. FINS ;
  58. SI bool0.'THERMIQUE' ;
  59.     wtab0.'THERMIQUE'.'MODELE'.'A' = REDU wtab0.'THERMIQUE'.'MODELE'.(0) mshA ;
  60. FINS ;
  61.  
  62. * Active material
  63. * ***************
  64.  
  65. SI bool0.'MECANIQUE' ;
  66.     matMA = TOPOMATE wtab0.'MECANIQUE'.'MODELE'.(1)
  67.                      wtab0.'MECANIQUE'.'CARACTERISTIQUES'.(1)
  68.                      wtab0.'MECANIQUE'.'DENSITE' ;
  69.     SI bool0.'ZONE_FIGEE' ;
  70.         matMA = matMA ET wtab0.'MECANIQUE'.'CARACTERISTIQUES'.(2) ;
  71.     FINS ;
  72.     matMA = REDU matMA mshA ;
  73.     wtab0.'MECANIQUE'.'CARACTERISTIQUES'.'A' = matMA ;
  74. FINS ;
  75. SI bool0.'THERMIQUE' ;
  76.     matTA = TOPOMATE wtab0.'THERMIQUE'.'MODELE'.(1)
  77.                      wtab0.'THERMIQUE'.'CARACTERISTIQUES'.(1)
  78.                      wtab0.'THERMIQUE'.'DENSITE' ;
  79.     SI bool0.'ZONE_FIGEE' ;
  80.         matTA = matTA ET wtab0.'THERMIQUE'.'CARACTERISTIQUES'.(2) ; 
  81.     FINS ;
  82.     matTA = REDU matTA mshA ;
  83.     wtab0.'THERMIQUE'.'CARACTERISTIQUES'.'A' = matTA ;
  84. FINS ;
  85.  
  86. * Active contact
  87. * **************
  88.  
  89. SI bool0.'CONTACT' ;
  90.     tmp0 = DIFF wtab0.'MAILLAGE'.(0) mshA ;
  91.     SI ((NBEL tmp0) > 0) ;
  92.         tmp0 = (MANU 'CHPO' tmp0 1 'SCAL'1.0) POIN 'SUPE' 0.0 ;
  93.         tmp0 = wtab0.'CONTACT'.'MAILLAGE'.(0) ELEM 'APPU' 'LARG' tmp0 ;
  94.         mshCA = DIFF wtab0.'CONTACT'.'MAILLAGE'.(0) tmp0 ;
  95.     SINO ;
  96.         mshCA = wtab0.'CONTACT'.'MAILLAGE'.(0) ;
  97.     FINS ;
  98.     wtab0.'CONTACT'.'MAILLAGE'.'A' = mshCA ;
  99.     wtab0.'CONTACT'.'MODELE'.'A' = REDU wtab0.'CONTACT'.'MODELE'.(0) mshCA ;
  100.     wtab0.'CONTACT'.'CARACTERISTIQUES'.'A' = REDU wtab0.'CONTACT'.'CARACTERISTIQUES'.(0) mshCA ;
  101. FINS ;
  102.  
  103. FINP ;
  104.  
  105.  
  106.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales