Télécharger repix.procedur

Retour à la liste

Numérotation des lignes :

  1. * REPIX PROCEDUR TTMF3 96/10/10 22:16:59 2322
  2. 'DEBPROC' REPIX ;
  3. 'ARGU' RV*'TABLE' ;
  4. *====================================================================
  5. * REPIX enlève de la table créée par EQEX les objets MATRIK et MATRAK
  6. *--------------------------------------------------------------------
  7. * Les objets MATRIK indésirables se trouvent
  8. * 1) à l'indice 'MATESI' des tables de sous types 'DOMAINE' stockées
  9. * dans la table rangée à l'indice 'DOMINC';
  10. * 2) à l'indice 'MATC' de la table stockée à l'indice 'PRESSION';
  11. * 3) à l'indice 'MATESI' de la table stockée à l'indice 'DOMAINE';
  12. * 4) à l'indice 'MATELM' des tables de sous type 'KIZX'.
  13. *====================================================================
  14. 'SI' ('EXIS' RV 'SOUSTYPE' ) ;
  15. 'SI' ('NEG' RV . 'SOUSTYPE' 'EQEX' ) ;
  16. 'QUIT' REPIX ;
  17. 'FINS' ;
  18. 'SINO' ;
  19. 'QUIT' REPIX ;
  20. 'FINS' ;
  21. TAB1 = 'INDEX' RV ;
  22. NOP1 = 'DIME' TAB1 ;
  23. 'SI' ('EGA' NOP1 0) ;
  24. 'QUIT' REPIX ;
  25. 'FINS' ;
  26. *
  27. *-----------------
  28. 'REPE' BOU1 NOP1 ;
  29. *-----------------
  30. *
  31. IND1 = MOT TAB1 . &BOU1 ;
  32. *
  33. *- Cas 1)
  34. *
  35. 'SI' ('EGA' IND1 'DOMINC' ) ;
  36. TAB2 = 'INDEX' ( RV . IND1 ) ;
  37. NOP2 = 'DIME' TAB2 ;
  38. 'SI' ('NEG' NOP2 0) ;
  39. 'REPE' BOU2 NOP2 ;
  40. IND2 = MOT TAB2 . &BOU2 ;
  41. 'SI' ('NEG' IND2 'SOUSTYPE' ) ;
  42. OBJ2 = RV . IND1 . IND2 ;
  43. TYP2 = 'TYPE' OBJ2 ;
  44. 'SI' ('EGA' TYP2 'TABLE ' ) ;
  45. 'SI' ('EXIS' OBJ2 'SOUSTYPE' ) ;
  46. 'SI' ('EGA' OBJ2 . 'SOUSTYPE' 'DOMAINE' ) ;
  47. OBJ2 . 'MATESI' = 0 ;
  48. 'FINS' ;
  49. 'FINS' ;
  50. 'FINS' ;
  51. 'FINS' ;
  52. 'FIN' BOU2 ;
  53. 'FINS' ;
  54. ITERER BOU1 ;
  55. 'FINS' ;
  56. *
  57. *- Cas 2)
  58. *
  59. 'SI' ('EGA' IND1 'PRESSION' ) ;
  60. OBJ1 = RV . IND1 ;
  61. TYP1 = 'TYPE' OBJ1 ;
  62. 'SI' ('EGA' TYP1 'TABLE ' ) ;
  63. 'SI' ('EXIS' OBJ1 'SOUSTYPE' ) ;
  64. 'SI' ('EGA' OBJ1 . 'SOUSTYPE' 'EQPR' ) ;
  65. 'SI' ('EXIS' OBJ1 'MATC' ) ;
  66. OBJ1 . 'MATC' = 0 ;
  67. 'FINS' ;
  68. 'FINS' ;
  69. 'FINS' ;
  70. 'FINS' ;
  71. ITERER BOU1 ;
  72. 'FINS' ;
  73. *
  74. *- Cas 3)
  75. *
  76. 'SI' ('EGA' IND1 'DOMAINE' ) ;
  77. OBJ1 = RV . IND1 ;
  78. TYP1 = 'TYPE' OBJ1 ;
  79. 'SI' ('EGA' TYP1 'TABLE ' ) ;
  80. 'SI' ('EXIS' OBJ1 'SOUSTYPE' ) ;
  81. 'SI' ('EGA' OBJ1 . 'SOUSTYPE' 'DOMAINE' ) ;
  82. 'SI' ('EXIS' OBJ1 'MATESI' ) ;
  83. OBJ1 . 'MATESI' = 0 ;
  84. 'FINS' ;
  85. 'FINS' ;
  86. 'FINS' ;
  87. 'FINS' ;
  88. ITERER BOU1 ;
  89. 'FINS' ;
  90. *
  91. *- Cas 4)
  92. *
  93. 'SI' ('NEG' IND1 'SOUSTYPE' ) ;
  94. OBJ1 = RV . IND1 ;
  95. TYP1 = 'TYPE' OBJ1 ;
  96. 'SI' ('EGA' TYP1 'TABLE ' ) ;
  97. 'SI' ('EXIS' OBJ1 'SOUSTYPE' ) ;
  98. 'SI' ('EGA' OBJ1 . 'SOUSTYPE' 'KIZX' ) ;
  99. OBJ1 . 'MATELM' = 0 ;
  100. 'FINS' ;
  101. 'FINS' ;
  102. 'FINS' ;
  103. ITERER BOU1 ;
  104. 'FINS' ;
  105. *
  106. *-----------
  107. 'FIN' BOU1 ;
  108. *-----------
  109. *
  110. 'FINPROC' ;
  111.  
  112.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales