Sources Esope | Cast3M

ttri6
C TTRI6     SOURCE    OF166741  23/12/04    21:15:25     11800          
 
C=======================================================================
C=                            T T R I 6                                =
C=                            ---------                                =
C=                                                                     =
C=  Fonction :                                                         =
C=  ----------                                                         =
C=   Acquisition des caracteristiques d'integration aux noeuds, aux    =
C=   points d'integration (Gauss) ou au centre de gravite pour         =
C=   l'element thermique support TRI6.                                 =
C=                                                                     =
C=  Parametres :  (E)=Entree  (S)=Sortie                               =
C=  ------------                                                       =
C=   ISUPTH  (E)   Indique le support d'integration demande            =
C=   IPINTE  (S)   Pointeur sur le segment MINTE associe               =
C=======================================================================
 
      SUBROUTINE TTRI6 (ISUPTH,IPINTE)
 
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8 (A-H,O-Z)
 
-INC SMINTE
 
      PARAMETER ( O0 = 0.D0)
      PARAMETER ( O1=1.D0, O2=2.D0, O3=3.D0, O4=4.D0, O5=0.5D0, O6=6.D0,
     &            O9=9.D0, O12=12.D0, O21=21.D0, O80=80.D0, O155=155.D0,
     &            O2400=2400.D0 )
 
      NBNO = 6
      IF      (ISUPTH.EQ.1) THEN
        NBPGAU = 6
      ELSE IF (ISUPTH.EQ.2) THEN
        NBPGAU = 7
      ELSE IF (ISUPTH.EQ.3) THEN
        NBPGAU = 1
      ELSE
        RETURN
      ENDIF
      SEGINI,MINTE
 
C COORDONNEES DES 6 NOEUDS
      IF (ISUPTH.EQ.1) THEN
        QSIGAU(1) = O0
        QSIGAU(2) = O5
        QSIGAU(3) = O1
        QSIGAU(4) = O5
        QSIGAU(5) = O0
        QSIGAU(6) = O0
        ETAGAU(1) = O0
        ETAGAU(2) = O0
        ETAGAU(3) = O0
        ETAGAU(4) = O5
        ETAGAU(5) = O1
        ETAGAU(6) = O5
        POIGAU(1) = O1/O12
        POIGAU(2) = O1/O12
        POIGAU(3) = O1/O12
        POIGAU(4) = O1/O12
        POIGAU(5) = O1/O12
        POIGAU(6) = O1/O12
 
C COORDONNEES DES 7 POINTS DE GAUSS
      ELSE IF (ISUPTH.EQ.2) THEN
        rac15 = SQRT(15.D0)
        QSIGAU(1) = O1/O3
        QSIGAU(2) = (O9-O2*rac15)/O21
        QSIGAU(3) = (O6+rac15)/O21
        QSIGAU(4) = (O6+rac15)/O21
        QSIGAU(5) = (O9+O2*rac15)/O21
        QSIGAU(6) = (O6-rac15)/O21
        QSIGAU(7) = (O6-rac15)/O21
        ETAGAU(1) = O1/O3
        ETAGAU(2) = (O6+rac15)/O21
        ETAGAU(3) = (O9-O2*rac15)/O21
        ETAGAU(4) = (O6+rac15)/O21
        ETAGAU(5) = (O6-rac15)/O21
        ETAGAU(6) = (O9+O2*rac15)/O21
        ETAGAU(7) = (O6-rac15)/O21
        POIGAU(1) = O9/O80
        POIGAU(2) = (O155+rac15)/O2400
        POIGAU(3) = (O155+rac15)/O2400
        POIGAU(4) = (O155+rac15)/O2400
        POIGAU(5) = (O155-rac15)/O2400
        POIGAU(6) = (O155-rac15)/O2400
        POIGAU(7) = (O155-rac15)/O2400
 
C COORDONNEES DU CENTRE DE GRAVITE
      ELSE IF (ISUPTH.EQ.3) THEN
        QSIGAU(1) = O1/O3
        ETAGAU(1) = O1/O3
        POIGAU(1) = O5
      ENDIF
 
C FONCTIONS DE FORME ET LEURS DERIVEES AU(X) NBPGAU POINT(S)
      DO I = 1, NBPGAU
        XI = QSIGAU(I)
        YI = ETAGAU(I)
 
        SHPTOT(1,1,I) = (O1-XI-YI)*(O1-O2*(XI+YI))
        SHPTOT(1,2,I) = O4*XI*(O1-XI-YI)
        SHPTOT(1,3,I) = XI*(XI+XI-O1)
        SHPTOT(1,4,I) = O4*XI*YI
        SHPTOT(1,5,I) = YI*(YI+YI-O1)
        SHPTOT(1,6,I) = O4*YI*(O1-XI-YI)
 
        SHPTOT(2,1,I) = O4*(XI+YI)-O3
        SHPTOT(2,2,I) = O4*(O1-XI-XI-YI)
        SHPTOT(2,3,I) = O4*XI-O1
        SHPTOT(2,4,I) = O4*YI
        SHPTOT(2,5,I) = O0
        SHPTOT(2,6,I) = -O4*YI
 
        SHPTOT(3,1,I) = O4*(XI+YI)-O3
        SHPTOT(3,2,I) = -O4*XI
        SHPTOT(3,3,I) = O0
        SHPTOT(3,4,I) = O4*XI
        SHPTOT(3,5,I) = O4*YI-O1
        SHPTOT(3,6,I) = O4*(O1-XI-YI-YI)
 
      ENDDO
 
      IPINTE = MINTE
 
c      RETURN
      END