Télécharger la plaquette Cast3M


fr en

Télécharger intcn1.eso

Retour à la liste

Numérotation des lignes : 

intcn1

  1. C INTCN1    SOURCE    OF166741  24/08/06    21:15:03     11982          
  2.  
  3. ************************************************************************
  4. *
  5. *                             I N T C N 1
  6. *                             -----------
  7. *
  8. * FONCTION:
  9. * ---------
  10. *     INTEGRATION NUMERIQUE DANS UN DOMAINE UNIDIMENSIONNEL DU PRODUIT:
  11. *                     COEF. * TRANSPOSEE( N )
  12. *     COEF. : GRANDEUR PHYSIQUE REPRESENTEE PAR UN CHAMELEM
  13. *     N     : FONCTIONS DE FORME DE L'ELEMENT MAILLANT LE DOMAINE
  14. *             CONSIDERE
  15. *
  16. * PARAMETRES:   (E)=ENTREE   (S)=SORTIE   (+ = CONTENU DANS UN COMMUN)
  17. * -----------
  18. *
  19. *     IPVATE  (E)  POINTEUR SUR UN SEGMENT MELVAL CONTENANT LES
  20. *                  VALEURS DE LA TEMPERATURE EXTERIEURE
  21. *     IPVAHC  (E)  POINTEUR SUR UN SEGMENT MELVAL CONTENANT LES
  22. *                  VALEURS DU COEFFICIENT D'ECHANGE
  23. *     IPGEOM  (E)  POINTEUR SUR UN OBJET MAILLAGE ELEMENTAIRE
  24. *                  DU DOMAINE D'INTEGRATION
  25. *     IPINTE  (E)  POINTEUR SUR UN SEGMENT MINTE CONTENANT LES
  26. *                  CARACTERISTIQUES D'INTEGRATION DES FACES
  27. *     IPVAEQ  (S)  POINTEUR SUR UN SEGMENT MELVAL CONTENANT LES VALEURS
  28. *                  NODALES EQUIVALENTES (APRES INTEGRATION NUMERIQUE)
  29. *
  30. * VARIABLES:
  31. * ----------
  32. *
  33. *     XE(3,NBPTEL)  =  CORDONNEES DES ELEMENTS DANS LE REPERE GLOBAL
  34. *     FACE          =  LONGUEUR DE DE L'ELEMENT CONSIDERE
  35. *     A             =  TABLEAU DE TRAVAIL
  36. *
  37. *
  38. * REMARQUES:
  39. * ----------
  40. *     L'UTILISATION DE CE S-P PRESUPPOSE UN PRE ET POST-TRAITEMENT
  41. *     DES SEGMENTS MELVAL PASSES EN TANT QUE PARAMETRES
  42. *
  43. * AUTEUR, DATE DE CREATION:
  44. * -------------------------
  45. *     DENIS ROBERT,LE 15 AVRIL 1988.
  46. *
  47. * LANGAGE:
  48. * --------
  49. *     ESOPE + FORTRAN77
  50. *
  51. ************************************************************************
  52.  
  53.       SUBROUTINE INTCN1 (IPVATE,IPVAHC,IPGEOM,IPINTE,IPVAEQ)
  54.  
  55.       IMPLICIT INTEGER(I-N)
  56.       IMPLICIT REAL*8 (A-H,O-Z)
  57.  
  58. -INC PPARAM
  59. -INC CCOPTIO
  60. -INC CCREEL
  61.       PARAMETER (X2Pi=6.283185307179586476925286766559D0)
  62.  
  63. -INC SMCOORD
  64. -INC SMCHAML
  65. -INC SMELEME
  66. -INC SMINTE
  67.  
  68.       SEGMENT,MMAT1
  69.         REAL*8 XEL(3,NBPTEL),AEL(NBPTEL)
  70.       ENDSEGMENT
  71.  
  72. * OPTION INDISPONIBLE
  73.       IF (IDIM.NE.2) THEN
  74.         CALL ERREUR(19)
  75.         RETURN
  76.       ENDIF
  77.  
  78. * ON RECUPERE UN DES MAILLAGES ELEMENTAIRES DE L'ENVELOPPE
  79.       MELEME = IPGEOM
  80.       NBPTEL = meleme.NUM(/1)
  81.       NEL    = meleme.NUM(/2)
  82.  
  83. C  ON RECUPERE LES CARACTERISTIQUES D'INTEGRATION DES FACES
  84.       MINTE  = IPINTE
  85.       NBPGAU = minte.POIGAU(/1)
  86.  
  87. *  ON RECUPERE LES VALEURS DE LA TEMPERATURE
  88.       MELVA1 = IPVATE
  89.       N1_1   = MELVA1.VELCHE(/1)
  90.       N2_1   = MELVA1.VELCHE(/2)
  91.  
  92. *  ON RECUPERE LES VALEURS DU COEFFICIENT
  93.       MELVA2 = IPVAHC
  94.       N1_2   = MELVA2.VELCHE(/1)
  95.       N2_2   = MELVA2.VELCHE(/2)
  96.  
  97. *  INITIALISATION DU MELVAL QUI CONTIENDRA LES VALEURS EQUIVALENTES
  98.       N1PTEL = NBPTEL
  99.       N1EL   = NEL
  100.       N2PTEL = 0
  101.       N2EL   = 0
  102.       SEGINI,MELVAL
  103.  
  104.       SEGINI,MMAT1
  105.  
  106. * ========
  107. *  BOUCLE (1) SUR LES ELEMENTS
  108. * ========
  109.       DO IEL = 1, NEL
  110.  
  111.         IEMN1 = MIN(IEL,N2_1)
  112.         IEMN2 = MIN(IEL,N2_2)
  113.  
  114.         DO INOE = 1, NBPTEL
  115.           AEL(INOE) = XZERO
  116.         ENDDO
  117.  
  118. *   ON CHERCHE LES COORDONNEES DES ELEMENTS DANS LE REPERE GLOBAL
  119.         CALL DOXE(XCOOR,IDIM,NBPTEL,NUM,IEL,XEL)
  120.  
  121. * ========
  122. *  BOUCLE (10) SUR LES POINTS D'INTEGRATION
  123. * ========
  124.         DO IGAU = 1, NBPGAU
  125.  
  126.           DLX = XZERO
  127.           DLY = XZERO
  128.           DO INOE = 1, NBPTEL
  129.             DLX = DLX + SHPTOT(2,INOE,IGAU)*XEL(1,INOE)
  130.             DLY = DLY + SHPTOT(2,INOE,IGAU)*XEL(2,INOE)
  131.           END DO
  132.           FACE = SQRT(DLX*DLX+DLY*DLY) * POIGAU(IGAU)
  133. *      CAS DES ELEMENTS AXISYMETRIQUES
  134.           IF (IFOMOD.EQ.0) THEN
  135.             RR = XZERO
  136.             DO INOE = 1, NBPTEL
  137.               RR = RR + SHPTOT(1,INOE,IGAU)*XEL(1,INOE)
  138.             END DO
  139.             FACE = X2Pi * RR * FACE
  140.           ENDIF
  141.  
  142.           INMN1 = MIN(IGAU,N1_1)
  143.           INMN2 = MIN(IGAU,N1_2)
  144.           r_z = MELVA1.VELCHE(INMN1,IEMN1) * MELVA2.VELCHE(INMN2,IEMN2)
  145.  
  146.           r_z = r_z * FACE
  147.  
  148.           DO INOE = 1, NBPTEL
  149.             AEL(INOE) = AEL(INOE) + SHPTOT(1,INOE,IGAU) * r_z
  150.           END DO
  151.  
  152.         END DO
  153. * ========
  154. *  BOUCLE (10) FIN
  155. * ========
  156.  
  157.         DO INOE = 1, NBPTEL
  158.           VELCHE(INOE,IEL) = AEL(INOE)
  159.         END DO
  160.  
  161.       END DO
  162. * ========
  163. *  BOUCLE (1) - FIN
  164. * ========
  165.  
  166.       SEGSUP,MMAT1
  167.  
  168.       IPVAEQ = MELVAL
  169.  
  170. c      return
  171.       END
  172.  
  173.  
  174.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales