Sources Esope | Cast3M

hbmzfx
C HBMZFX    SOURCE    CB215821  26/06/25    21:15:13     12581          
 
*=======================================================================
* Rajoute les forces de couplage Fluide-Elastique : ZX=ZX+Ff = Zf*X
*=======================================================================
 
      SUBROUTINE HBMZFX(NT,NDDL,OMEG,Q1,AiDi,Di,LAMBD,VCTCS,ZX)
 
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
 
      INTEGER NHBM,NT,NDDL,H
      REAL*8 ZX(NT),Q1(NT),VCTCS(7),LAMBD(NDDL),AiDi(2),Di(2),bi(2)
      REAL*8 OMEG,V,cf0,mf0,sf0,dmfej,cfei,dniR,dniI
 
*-----------------------------------------------------------------------
* 0. Recuperation des coefficients
      V = VCTCS(4)
*    Coefficient de couplage: mf0 = -(rho_f/2)*(dCLdy)*V^2
      mf0  = -VCTCS(1)*VCTCS(7)*(V**2)
*    Coefficient d'amortissement: cf0 = (rho_f/2)*(DIAM)*(CD)*V
      cf0  = VCTCS(1)*VCTCS(5)*VCTCS(6)*V
*    Coefficient de raideur: sf0 = mf0*alpha_0
      sf0  = mf0*VCTCS(3)
      DO I = 1,2
        bi(I) = Di(I)*V/VCTCS(5)
      ENDDO
      NHBM = (NT/NDDL - 1)/2
 
*-----------------------------------------------------------------------
* 1. Termes de raideur/amortissement ajoutes
*  1.1 Composante statique
      DO I=1,NDDL
        ZX(I) = ZX(I) + sf0*LAMBD(I)*Q1(I)
      ENDDO
*  1.2 Boucle sur les harmoniques
      DO J=2,2*NHBM,2
        dmfej = REAL(J/2)*OMEG*cf0
        DO I=1,NDDL
*         Cos
          ZX(NDDL*(1+(J-2))+I) = ZX(NDDL*(1+(J-2))+I)
     &    + sf0  *LAMBD(I)*Q1(NDDL*(1+(J-2))+I)
     &    + dmfej*LAMBD(I)*Q1(NDDL*(1+(J-1))+I)
*         Sin
          ZX(NDDL*(1+(J-1))+I) = ZX(NDDL*(1+(J-1))+I)
     &    + sf0  *LAMBD(I)*Q1(NDDL*(1+(J-1))+I)
     &    - dmfej*LAMBD(I)*Q1(NDDL*(1+(J-2))+I)
        ENDDO
      ENDDO
 
*-----------------------------------------------------------------------
** 2. Effet memoire
** Boucle sur le nombre de termes
      DO JJ = 1,2
        cfei = mf0*AiDi(JJ)*V/VCTCS(5)
*   2.1 Composante statique
        DO I=1,NDDL
          ZX(I) = ZX(I) + cfei*LAMBD(I)*Q1(I)/bi(JJ)
        ENDDO
*   2.2 Boucle sur les harmoniques >0
        DO H = 2,2*NHBM,2
          Xtmp = (bi(JJ))**2+(REAL(H/2)*OMEG)**2
          dniR =         bi(JJ)/ Xtmp
          dniI = OMEG*REAL(H/2)/ Xtmp
**       Boucle sur les DDL
          DO K = 1,NDDL
*          Cos
            ZX(NDDL*(1+(H-2))+K) = ZX(NDDL*(1+(H-2))+K)
     &          + LAMBD(K)*cfei* ( dniR*Q1(NDDL*(1+(H-2))+K)
     &                            -dniI*Q1(NDDL*(1+(H-1))+K) )
*          Sin
            ZX(NDDL*(1+(H-1))+K) = ZX(NDDL*(1+(H-1))+K)
     &          + LAMBD(K)*cfei*( dniR*Q1(NDDL*(1+(H-1))+K)
     &                           +dniI*Q1(NDDL*(1+(H-2))+K) )
          ENDDO
        ENDDO
      ENDDO
 
      RETURN
      END