Télécharger la plaquette Cast3M


fr en

Télécharger endo.eso

Retour à la liste

Numérotation des lignes : 

endo

  1. C ENDO      SOURCE    CB215821  26/08/24    21:16:26     12622          
  2.       SUBROUTINE ENDO(EPSILO,NSTRS,NVARI,CMAT,DEP,SIGF,VAR0,
  3.      *                   VARF,NMAT,IFOUR)
  4. C
  5. C_________________________________________________________________
  6. C
  7. C  CALCUL DE L ENDOMMAGEMENT ET DES CONTRAINTES APPARENTES FINALES
  8. C_________________________________________________________________
  9. C
  10. C     declaration des variables
  11. C
  12. C
  13.       IMPLICIT INTEGER(I-N)
  14.       IMPLICIT REAL*8(A-H,O-Z)
  15.       DIMENSION EPS33(3,3),EPSIPP(3),EPSILT(3),VALP33(3,3)
  16.       DIMENSION SIGP(3),SIGPT(3),SIGPC(3)
  17.       DIMENSION EPSILO(NSTRS),SIGF(NSTRS),CMAT(NMAT)
  18.       DIMENSION DEP(NSTRS,NSTRS),VARF(NVARI),VAR0(NVARI)
  19. C
  20.       XZERO=0.D0
  21.       UN=1.D0
  22.       XPETIT=1.D-12
  23. C
  24. C RECUPERATION DES PARAMETRES MATERIAUX
  25. C         ET DES VARIABLES INTERNES
  26. C
  27.       YOUN = CMAT(1)
  28.       XNU  = CMAT(2)
  29.       EPSD0= CMAT(5)
  30.       ATRA = CMAT(6)
  31.       BTRA = CMAT(7)
  32.       ACOM = CMAT(8)
  33.       BCOM = CMAT(9)
  34.       DINI = VAR0(2)
  35. C
  36. C CHANGEMENT EPSILO
  37. C  CONTRAINTES PLANES
  38. C
  39.       IF (IFOUR.EQ.-2) THEN
  40.         temp = EPSILO(3)
  41.         EPSILO(3) = EPSILO(4)
  42.         EPSILO(4) = temp
  43.       ENDIF
  44. C
  45. C REECRITURE DU VECTEUR DEFORMATION SOUS FORME MATRICIELLE
  46. C   ENTREE : EPSILO -> VECTEUR DEFORMATION ELASTIQUE
  47. C   SORTIE : EPS33 -> MATRICE DEFORMATION ELASTIQUE
  48. C      Le 2 correspond au cisaillement
  49. C
  50.        CALL ENDOCB (EPSILO,EPS33,2,IFOUR)
  51. C
  52. C DIAGONALISATION DE LA MATRICE DEFORMATION ELASTIQUE EPS33
  53. C    SORTIE : EPSIPP(3)   - VALEURS PROPRES
  54. C             VALP33(3,3) - VECTEURS PROPRES
  55. C
  56.        IF (IFOUR.EQ.2) THEN
  57.          CALL JACOB3 (EPS33,3,EPSIPP,VALP33)
  58.        ELSE
  59.          CALL JACOB3 (EPS33,2,EPSIPP,VALP33)
  60.        ENDIF
  61. C
  62. C CALCUL DES CONTRAINTES PRINCIPALES
  63. C
  64.        DO 41 I=1,3
  65.             SIGP(I)= XZERO
  66.             DO 10 J=1,3
  67.                SIGP(I)=SIGP(I)+DEP(I,J)*EPSIPP(J)
  68.   10   CONTINUE
  69.    41  CONTINUE
  70. C
  71. C ON COMPLETE LA DEFORMATION DANS LE CAS DES
  72. C  CONTRAINTES PLANES
  73. C
  74.       IF (IFOUR.EQ. -2) THEN
  75.          EPSIPP(3)= -(EPSIPP(1) + EPSIPP(2))*XNU / (UN-XNU)
  76.       ENDIF
  77. C
  78. C CALCUL DE EPSILON TILDA (DEFORMATION POSITIVE)
  79. C
  80.       EPSTIL=MAX( XZERO , EPSIPP(1) )**2 +
  81.      *       MAX( XZERO , EPSIPP(2) )**2 +
  82.      *       MAX( XZERO , EPSIPP(3) )**2
  83.       EPSTIL=SQRT (EPSTIL)
  84. C
  85. C TEST EPSTIL>EPSD0
  86. C
  87.       IF ( EPSTIL .GT. EPSD0) THEN
  88. C
  89. C       CALCUL DE L ENDOMMAGEMENT
  90. C
  91. C        CALCUL DE LA TRACE DES CONTRAINTES
  92. C          NEGATIVE (COMPRESSION) : TRSIGC
  93. C          POSITIVE (TRACTION)    : TRSIGT
  94. C
  95.         DO 20 I=1,3
  96.           IF (SIGP(I).LT. XZERO) THEN
  97.             SIGPC(I) = SIGP(I)
  98.             SIGPT(I) = XZERO
  99.           ELSE
  100.             SIGPT(I) = SIGP(I)
  101.             SIGPC(I) = XZERO
  102.           ENDIF
  103.   20    CONTINUE
  104. C
  105.         TRSIGT = SIGPT(1)+SIGPT(2)+SIGPT(3)
  106.         TRSIGC = SIGPC(1)+SIGPC(2)+SIGPC(3)
  107. C
  108. C     CALCUL DES DEFORMATIONS DUES AU CONTRAINTES POSITIVES
  109. C
  110.         DO 30 I=1,3
  111.           EPSILT(I) = (SIGPT(I)*(UN+XNU)-TRSIGT*XNU)/YOUN
  112.   30    CONTINUE
  113. C
  114. C     CALCUL DE ALFAT ET ALFAC
  115. C
  116.         ALFAT = MAX(XZERO,EPSIPP(1))*EPSILT(1) +
  117.      *          MAX(XZERO,EPSIPP(2))*EPSILT(2) +
  118.      *          MAX(XZERO,EPSIPP(3))*EPSILT(3)
  119.         ALFAT = ALFAT/(EPSTIL*EPSTIL)
  120.         ALFAC = UN - ALFAT
  121. C
  122. C     AMELIORATION DE LA REPONSE EN CISAILLEMENT
  123. C        POUR BETA > 1
  124. C
  125.         BETA = UN
  126.         IF (BETA .GT. UN) THEN
  127.            IF ( ALFAT .GT. XPETIT ) THEN
  128.              ALFAT=ALFAT**BETA
  129.            ENDIF
  130.            IF ( ALFAC .GT. XPETIT ) THEN
  131.              ALFAC=ALFAC**BETA
  132.            ENDIF
  133.          ENDIF
  134. C
  135. c      CALCUL DE DT, DC ET D
  136. C
  137.          DT = UN - (EPSD0/EPSTIL)*(
  138.      *             (UN + ATRA)*EXP(-BTRA*(EPSTIL-EPSD0)) -
  139.      *             ATRA*EXP(-2.D0*BTRA*(EPSTIL-EPSD0)))
  140.          DC = UN - (EPSD0/EPSTIL)*(
  141.      *             (UN + ACOM)*EXP(-BCOM*(EPSTIL-EPSD0)) -
  142.      *             ACOM*EXP(-2.D0*BCOM*(EPSTIL-EPSD0)))
  143.          D = ALFAT*DT + ALFAC*DC
  144. C
  145. C      ON BORNE LA VALEUR DE D a 0.99999
  146. C
  147.          D = MIN ( D , UN-1.D-05 )
  148. C
  149.       ELSE
  150.          D = XZERO
  151.       ENDIF
  152. C
  153. C    ON TESTE LA CROISSANCE DE D
  154. C
  155.       D=MAX ( D , DINI )
  156. C
  157. C STOCKAGE DES VARIABLES INTERNES FINALES
  158. C
  159.       VARF(2) = D
  160. C
  161. C CONTRAINTES APPARENTES
  162. C
  163.       DO 40 I=1,NSTRS
  164.         SIGF(I) = SIGF(I)*(1.D0-D)
  165.    40 CONTINUE
  166. C
  167. C CHANGEMENT EPSILO
  168. C  CONTRAINTES PLANES
  169. C
  170.       IF (IFOUR.EQ.-2) THEN
  171.         temp = EPSILO(3)
  172.         EPSILO(3) = EPSILO(4)
  173.         EPSILO(4) = temp
  174.       ENDIF
  175. C
  176.       END
  177.  
  178.  
  179.  
  180.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales