Télécharger la plaquette Cast3M


fr en

Télécharger detowp.eso

Retour à la liste

Numérotation des lignes : 

detowp

  1. C DETOWP    SOURCE    CB215821  16/11/21    21:15:01     9196           
  2.       SUBROUTINE DETOWP(P,T,X,AH2,AH2O,AO2,TINT,W,IINT,NBC,NBT)
  3. C---------------------------------------------------------------------
  4. C Calcul des taux de production de chaque espece, N2 étant neutre.
  5. C---------------------------------------------------------------------
  6. C
  7. C---------------------------
  8. C Parametres Entree/Sortie :
  9. C---------------------------
  10. C
  11. C E/  P         : Pression du mélange (Pa)
  12. C E/  T         : Température du mélange (K)
  13. C E/  X(NBC)    : Fraction molaire (-)
  14. C E/  AH2(NBT)  : Coeff du devt en T des propriétés de h2
  15. C E/  AH2O(NBT) : Coeff du devt en T des propriétés de h2o
  16. C E/  AO2(NBT)  : Coeff du devt en T des propriétés de o2
  17. C E/  TINT      : Température seuil (K)
  18. C  /S W(NBC)    : Taux de production de chacune des espèces
  19. C E/  IINT      : Nombre de coeff nécessaire à T donnée
  20. C E/  NBC       : Nombre de constituants du mélange
  21. C E/  NBT       : Nombre de coeff total
  22. C
  23. C---------------------
  24. C Variables internes :
  25. C---------------------
  26. C
  27. C AKP : Constante d'équilibre de la réaction
  28. C AKF : Vitesse de la réaction dans le sens gauche->droite
  29. C AKT : Vitesse de la réaction dans le sens droite->gauche
  30. C AKC : Constante cinétique (AKF/AKT)
  31. C
  32. C---------------------------------------------------------------------
  33. C
  34. C Langage : FORTRAN
  35. C
  36. C Auteurs : F.DABBENE et E.STUDER 02/99
  37. C
  38. C---------------------------------------------------------------------
  39.       IMPLICIT INTEGER(I-N)
  40.       IMPLICIT REAL*8 (A-H,O-Z)
  41.       DIMENSION X(*),W(*),AH2(*),AH2O(*),AO2(*)
  42. C
  43. C- Décalage dans la table suivant la borne TINT
  44. C
  45.       IINTM2 = IINT - 2
  46.       IINTM1 = IINT - 1
  47.       II = 0
  48.       IF (T.LT.TINT) II = IINT
  49. C
  50. C- Description du modele chimique de combustion
  51. C-> Correspondance indice/espece : 1=H2 2=O2 3=H2O 4=N2
  52. C-> Cinétique à une réaction     : 2.H2 + 1.O2 = 2.H2O
  53. C-> Vitesse réaction (Arrhenius) : AKF = A * T**B * exp(-E/RT)
  54. C
  55.       ANP1 = REAL(2.D0)
  56.       ANP2 = REAL(1.D0)
  57.       ANP3 = REAL(0.D0)
  58.       ANS1 = REAL(0.D0)
  59.       ANS2 = REAL(0.D0)
  60.       ANS3 = REAL(2.D0)
  61.       ANU1 = ANS1 - ANP1
  62.       ANU2 = ANS2 - ANP2
  63.       ANU3 = ANS3 - ANP3
  64.       DANU = ANU1 + ANU2 + ANU3
  65. C
  66. C- Constantes de la cinétique à une réaction (loi d'Arrhenius)
  67. C- A et E correspondent à des énergies en Joules
  68. C
  69.       A = REAL(1.2D14)
  70.       B = REAL(-0.9D0)
  71.       E = REAL(4.184D0*16511.D0)
  72. C
  73. C- Calcul de l'enthalpie/RT et de l'entropie/R des constituants
  74. C- H2, O2 et H2O en fonction de la température (en mol/gramme)
  75. C      
  76.       XLOGT= LOG(T)
  77.       SH2  = AH2 (1+II) * XLOGT
  78.       SO2  = AO 2(1+II) * XLOGT
  79.       SH2O = AH2O(1+II) * XLOGT
  80.  
  81.       HH2  = AH2 (1+II)
  82.       HO2  = AO2 (1+II)
  83.       HH2O = AH2O(1+II)
  84.  
  85.       IF (IINTM2 .GE. 2) THEN
  86.         DO 10 I = 2,IINTM2
  87.            TPOW = T**(I-1)
  88.            HH2  = HH2  + AH2 (I+II) * TPOW / REAL(I)
  89.            HO2  = HO2  + AO2 (I+II) * TPOW / REAL(I)
  90.            HH2O = HH2O + AH2O(I+II) * TPOW / REAL(I)
  91.            SH2  = SH2  + AH2 (I+II) * TPOW / REAL(I-1)
  92.            SO2  = SO2  + AO2 (I+II) * TPOW / REAL(I-1)
  93.            SH2O = SH2O + AH2O(I+II) * TPOW / REAL(I-1)
  94.  10     CONTINUE
  95.       ENDIF
  96.       HH2  = HH2  + AH2(IINTM1+II)  / T
  97.       HO2  = HO2  + AO2(IINTM1+II)  / T
  98.       HH2O = HH2O + AH2O(IINTM1+II) / T
  99.       SH2  = SH2  + AH2(IINT+II)
  100.       SO2  = SO2  + AO2(IINT+II)
  101.       SH2O = SH2O + AH2O(IINT+II)
  102. C
  103. C- Calcul de la constante d'équilibre de la réaction
  104. C- AKP = EXP(-DG/RT) avec G = h - Ts
  105. C
  106.       AKP = EXP(ANU1*(SH2-HH2)+ANU2*(SO2-HO2)+ANU3*(SH2O-HH2O))
  107. C
  108. C- Calcul de la constante cinétique de la réaction (AKC) et des vitesses
  109. C- de réaction dans le sens gauche->droite AKF et droite->gauche AKT
  110. C
  111.       AKC = AKP*(1.01325D6/(8.314D0*1.D7*T))**DANU
  112.       AKF = A*(T**B)*EXP(-E/8.314D0/T)
  113.       AKT = AKF / AKC
  114. C
  115. C- Calcul des taux de production/destruction de chaque espèce
  116. C- (X(i)*(P/(8.314D0*T)*1.D-7) = concentration molaire de i)
  117. C
  118. C       Q = (AKF * X(1)**ANP1 * X(2)**ANP2 * X(3)**ANP3 )
  119. C     %    * (P/8.314D0/T*1.D-7)**(ANP1+ANP2+ANP3)
  120. C    %    - (AKT * X(1)**ANS1 * X(2)**ANS2 * X(3)**ANS3 )
  121. C     %    * (P/8.314D0/T*1.D-7)**(ANS1+ANS2+ANS3)
  122. C
  123. C ANS1=ANS2=ANP3=0 =>
  124.         Q = (AKF * X(1)**ANP1 * X(2)**ANP2 )
  125.      %    * (P/8.314D0/T*1.D-7)**(ANP1+ANP2)
  126.      %    - (AKT * X(3)**ANS3 )
  127.      %    * (P/8.314D0/T*1.D-7)**ANS3
  128. C
  129.       W(1) = ANU1*Q
  130.       W(2) = ANU2*Q
  131.       W(3) = ANU3*Q
  132.       W(4) = 0.D0
  133. C
  134.       RETURN
  135.       END
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales