Télécharger la plaquette Cast3M


fr en

Télécharger usexpl.procedur

Retour à la liste

Numérotation des lignes : 

  1. * USEXPL    PROCEDUR  MB234859  24/02/06    21:15:03     11833          
  2. ***********************************************************************
  3. *                         PROCEDURE USEXPL 
  4. *
  5. * Procedure pour appliquer l'usure en utilisant un schema explicite :
  6. * - le facteur de saut de cycle est determine (USACCE)
  7. * - l'increment d'usure est calcule
  8. * - des post-traitements intermediaires sont realises (USPOST)
  9. * - les maillages sont actualises (USDEPL)
  10. *
  11. * Entrees :
  12. *   T1    : Table de PASAPAS
  13. *
  14. * Appelee par USURE
  15. *
  16. ************************************************************************
  17. 'DEBP' USEXPL T1*'TABLE' ;
  18. *
  19.   'MESS' ; 'MESS' '[Schema explicite]';
  20. *
  21.   BOITE_US = T1.'BOITES_USURE' ; 
  22.   NbCycRe  = BOITE_US.'INFOS'.'NB_CYCLES_RESTANTS' ;
  23.   CycActu  = BOITE_US.'INFOS'.'INDICE_CYCLE_ACTUEL' ;
  24. *-----------------------------------------------------------------------
  25. * - FACTEUR D'ACCELERATION ET NOMBRE DE CYCLES RESTANTS A CALCULER
  26. *-----------------------------------------------------------------------
  27.   FactAcce = USACCE T1 ;
  28.   BOITE_US.'INFOS'.'NB_CYCLES_RESTANTS' = NbCycRe '-' FactAcce ; 
  29. *-----------------------------------------------------------------------
  30. * - PROFIL D'USURE : CALCUL ET ACTUALISATION DU MAILLAGE
  31. *-----------------------------------------------------------------------
  32.   'REPE' BU BOITE_US.'INFOS'.'N_BOITES' ;
  33. *  
  34.     IncUsure = FactAcce '*' BOITE_US. &BU .'VITESSE_USURE' ;
  35.     UsurePre = BOITE_US. &BU .'USURE_TOT'. (CycActu '-' 1) ;
  36.     UsureTot = UsurePre + IncUsure ; 
  37. *
  38.     'SI' ('NON' BOITE_US.'INFOS'.'ITRID') ;
  39.       SUR_APPL = BOITE_US. &BU .'SURFACE_APPLICATION'  ;
  40.       EvUsureT = 'EVOL' 'TURQ' 'CHPO' UsureTot SUR_APPL ; 
  41.       EvUsureT = 'EXTR' EvUsureT 'COUR' 1 ; 
  42.       EvUsureT = 'CHAN' EvUsureT 'LEGE' 'Usure_Totale' ; 
  43.       BOITE_US. &BU .'EVO_USURE_TOT'. CycActu = EvUsureT ;
  44. *
  45.       'SI' (BOITE_US.'INFOS'.'TRACE_DEBUG') ;
  46.         EvUsureN = 'EVOL' 'OR' 'CHPO' IncUsure SUR_APPL ;
  47.         EvUsureN = 'EXTR' EvUsureN 'COUR' 1 ; 
  48.         EvUsureN = 'CHAN' EvUsureN 'LEGE' 'Usure_Nouvelle' ;
  49. *
  50.         TITZ = 'CHAI' 'Usure nouvelle(OR)-totale(TURQ) Boite ' &BU ;
  51.         'DESS' (EvUsureN 'ET' EvUsureT) 'TITR' TITZ 'LEGE' ; 
  52.       'FINSI' ; 
  53.     'FINSI' ;
  54. *
  55.     BOITE_US. &BU .'USURE_CYCLE'        = IncUsure ;
  56.     BOITE_US. &BU .'INC_USURE'. CycActu = IncUsure ;
  57.     BOITE_US. &BU .'USURE_TOT'. CycActu = UsureTot ;
  58. * 
  59. *   Post-traitement supplementaire    
  60.     USPOST T1 &BU; 
  61. *   Application du profil d'usure au maillage
  62.     USDEPL T1 &BU ;
  63. *
  64.   'FIN' BU ;  
  65. *-----------------------------------------------------------------------
  66. 'FINP' ;
  67.  
  68.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales