Télécharger la plaquette Cast3M


fr en

Télécharger pas_modl.procedur

Retour à la liste

Numérotation des lignes : 

  1. * PAS_MODL  PROCEDUR  JK148537  25/12/17    21:15:04     12424          
  2. DEBPROC PAS_MODL TPASA1*'TABLE' ;
  3. ************************************************************************
  4. * Cette procedure initialise ou met a jour les indices relatifs aux 
  5. * modeles de la table WTABLE de PASAPAS, ainsi que les caracteristiques
  6. * associees.
  7. *
  8. * Pour plus de details, voir la notice.
  9. *
  10. ************************************************************************
  11. WTAB = TPASA1.'WTABLE' ;
  12. *
  13. 'SI' ('NON' (('EXIS' WTAB 'MODELE') 'ET' ('EXIS' WTAB 'CARACTERISTIQUES')));
  14.   'ERRE' '***** Il manque le MODELE ou les CARACTERISTIQUES dans Wtable' ;
  15.   'QUIT' PAS_MODL ;
  16. 'FINSI' ;
  17. *
  18. * Modele global :
  19. mod0 = WTAB.'MODELE' ;
  20.  
  21. * Le modele a-t-il ete actualise
  22. 'SI' ('EXIS' WTAB 'MODELE_COURANT') ;
  23.   'SI' ('EGA' mod0 (WTAB.'MODELE_COURANT')) ;
  24.     'QUIT' PAS_MODL ;
  25.   'FINSI' ;
  26. 'FINSI' ;
  27. WTAB.'MODELE_COURANT' = mod0 ;
  28.  
  29. * Caracteristiques :
  30. mat0 = WTAB.'CARACTERISTIQUES' ;
  31. *mess '*****  Appel a PAS_MODL ' ;
  32. *-----------------------------------------------------------------------
  33. *             Indices pour TRANSNON/TRANSLIN/DUPONT2
  34. *-----------------------------------------------------------------------
  35. WTAB.'THE1'        = 'EXIS' mod0 'FORM' 'THERMIQUE' ;
  36. WTAB.'THM1'        = 'EXIS' mod0 'FORM' 'THERMOHYDRIQUE' ;
  37. WTAB.'FOR_DIFF'    = 'EXIS' mod0 'FORM' 'DIFFUSION' ;
  38. WTAB.'FOR_METALLU' = 'EXIS' mod0 'FORM' 'METALLURGIE' ;
  39. WTAB.'FOR_PHASE'   = 'EXIS' mod0 'FORM' 'CHANGEMENT_PHASE' ;
  40. WTAB.'FOR_THER'    = WTAB.'THE1' 'OU' WTAB.'THM1' ;
  41. *
  42. 'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF' 'OU' WTAB.'FOR_METALLU' 'OU' WTAB.'FOR_PHASE') ;
  43.   'SI' WTAB.'THE1' ;
  44.      WTAB.'MOD_THE' = 'EXTR' mod0 'FORM' 'THERMIQUE';
  45.      WTAB.'MAT_THE' = 'REDU' mat0 WTAB.'MOD_THE';
  46.      WTAB.'MOD_T'   = WTAB.'MOD_THE' ;
  47.      WTAB.'MAT_T'   = WTAB.'MAT_THE' ;
  48.   'FINSI' ;
  49. *
  50.   'SI' WTAB.'THM1' ;
  51.     WTAB.'MOD_THM' = 'EXTR' mod0 'FORM' 'THERMOHYDRIQUE' ;
  52.     WTAB.'MAT_THM' = 'REDU' mat0 WTAB.'MOD_THM';
  53.     WTAB.'MOD_T'   = WTAB.'MOD_T' 'ET' WTAB.'MOD_THM' ;
  54.     WTAB.'MAT_T'   = WTAB.'MAT_T' 'ET' WTAB.'MAT_THM' ;
  55.   'FINSI' ;
  56. *
  57.   WTAB.'MOD_TOT' = WTAB.'MOD_T' ;
  58. *
  59.   'SI' WTAB.'FOR_DIFF' ;
  60.     WTAB.'MOD_DIF' ='EXTR' mod0 'FORM' 'DIFFUSION' ;
  61.     WTAB.'MAT_DIF' ='REDU' mat0 WTAB.'MOD_DIF'     ;
  62.     WTAB.'MOD_TOT' = WTAB.'MOD_TOT' 'ET' WTAB.'MOD_DIF' ;
  63.     WTAB.'MOD_THE' = WTAB.'MOD_THE' 'ET' WTAB.'MOD_DIF' ;
  64.     WTAB.'MAT_THE' = WTAB.'MAT_THE' 'ET' WTAB.'MAT_DIF' ;
  65.   'FINSI' ;
  66. *
  67.   WTAB.'CONVECTION' = 'EXISTE' mod0 'MATE' 'CONVECTION' ;
  68.   'SI' WTAB.'CONVECTION' ;
  69.     WTAB.'MOD_CON' = 'EXTR' mod0 'MATE' 'CONVECTION';
  70.     WTAB.'MAT_CON' = 'REDU' mat0 WTAB.'MOD_CON';
  71.   'FINSI';
  72. *
  73.   WTAB.'RAYO' = 'EXISTE' mod0 'MATE' 'RAYONNEMENT' ;
  74.   'SI' WTAB.'RAYO' ;
  75.     WTAB.'MOD_RAY' = 'EXTR' mod0 'MATE' 'RAYONNEMENT';
  76.     WTAB.'MAT_RAY' = 'REDU' mat0 WTAB.'MOD_RAY';
  77.   'FINSI';
  78. *
  79.   WTAB.'CONDUCTION' = 'EXISTE' mod0 'MATE' 'CONDUCTION' ;
  80.   'SI' WTAB.'CONDUCTION' ;
  81.     WTAB.'MOD_COND' = 'EXTR' mod0 'MATE' 'CONDUCTION';
  82.     WTAB.'MAT_COND' = 'REDU' mat0 WTAB.'MOD_COND';
  83.   'FINSI';
  84. *
  85.   WTAB.'SOURCE_Q' = 'EXISTE' mod0 'MATE' 'SOURCE' ;
  86.   'SI' WTAB.'SOURCE_Q' ;
  87.     WTAB.'MOD_SOQ' = 'EXTR' mod0 'MATE' 'SOURCE';
  88.     WTAB.'MAT_SOQ' = 'REDU' mat0 WTAB.'MOD_SOQ';
  89.   'FINSI';
  90. *
  91.    WTAB.'ADVECTION' = 'EXISTE' mod0 'MATE' 'ADVECTION' ;
  92.   'SI' WTAB.'ADVECTION' ;
  93.      WTAB.'MOD_ADV' = 'EXTR' mod0 'MATE' 'ADVECTION';
  94.      WTAB.'MAT_ADV' = 'REDU' mat0 WTAB.'MOD_ADV';
  95.   'FINSI';
  96. *
  97. * Formulation Metallurgie (T.L. en juin 2018) :
  98.   'SI' WTAB.'FOR_METALLU' ;
  99.     WTAB.'MOD_MET' = 'EXTR' mod0 'FORM' 'METALLURGIE';
  100.     WTAB.'MAT_MET' = 'REDU' mat0  WTAB.'MOD_MET'     ;
  101.     WTAB.'MOD_TOT' = WTAB.'MOD_TOT' 'ET' WTAB.'MOD_MET' ;
  102.   'FINS';
  103. *
  104. * Formulation CHANGEMENT_PHASE (CB215821 2019) :
  105.   WTAB.'PHASE'      = FAUX ;
  106.   WTAB.'SOLUBILITE' = FAUX ;
  107.   'SI' ('EXIS' mod0 'FORM' 'CHANGEMENT_PHASE');
  108.     MOPHA='EXTR' mod0 'FORM' 'CHANGEMENT_PHASE' ;
  109.     MAPHA='REDU' mat0 MOPHA ;
  110.     'SI' ('EXIS' MOPHA 'MATE' 'SOLUBILITE');
  111. *      Cas 'SOLUBILITE'
  112.        WTAB.'SOLUBILITE' = VRAI ;
  113.        MOSOL='EXTR' MOPHA 'MATE' 'SOLUBILITE' ;
  114.        WTAB.'MOD_SOL' = MOSOL ;
  115.        WTAB.'MAT_SOL' ='REDU' mat0 MOSOL ;
  116.  
  117.     'SINO';
  118. *      Cas 'PARFAIT'
  119.        WTAB.'PHASE' = VRAI ;
  120.        MOPAR = 'EXTR' MOPHA 'MATE' 'PARFAIT' ;
  121.        WTAB.'MOD_PHA' = MOPAR ;
  122.        WTAB.'MAT_PHA' ='REDU' mat0 MOPAR ;
  123.     'FINS';
  124.  
  125.      WTAB.'MOD_THE' = WTAB.'MOD_THE' 'ET' MOPHA ;
  126.      WTAB.'MAT_THE' = WTAB.'MAT_THE' 'ET' MAPHA ;
  127.      WTAB.'MOD_TOT' = WTAB.'MOD_TOT' 'ET' MOPHA ;
  128.   'FINSI';
  129.  
  130.   WTAB.'MAT_TOT' = 'REDU' mat0 WTAB.'MOD_TOT' ;
  131.  
  132. 'FINSI' ;
  133. *-----------------------------------------------------------------------
  134. *                          Indices pour UNPAS
  135. *-----------------------------------------------------------------------
  136. WTAB.'MEC1'     = 'EXIS' mod0 'FORM' 'MECANIQUE' ;
  137. WTAB.'POR1'     = 'EXIS' mod0 'FORM' 'POREUX' ;
  138. WTAB.'FCHA'     = 'EXIS' mod0 'FORM' 'CHARGEMENT' ;
  139. WTAB.'FLIA'     = 'EXIS' mod0 'FORM' 'LIAISON' ;
  140. WTAB.'CONTACT'  = 'EXIS' mod0 'FORM' 'CONTACT' ;
  141. WTAB.'FOR_MECA' = WTAB.'MEC1' 'OU' WTAB.'POR1' 'OU' WTAB.'FCHA' ;
  142. *
  143. 'SI' (WTAB.'FOR_MECA' 'OU' WTAB.'FLIA' 'OU' WTAB.'CONTACT') ;
  144. *
  145.   WTAB.'MOD_SPE' = 'VIDE' 'MMODEL' ;
  146.   WTAB.'MO_TOT'  = 'VIDE' 'MMODEL' ;
  147. *
  148.   'SI' WTAB.'MEC1' ;
  149.  
  150.     WTAB.'MOD_MEC' = 'EXTR' mod0 'FORM' 'MECANIQUE';
  151.     WTAB.'MAT_MEC' = 'REDU' mat0  WTAB.'MOD_MEC';
  152.  
  153.     WTAB.'ADVECTION_MECANIQUE' = 'EXISTE' WTAB.'MOD_MEC' 'MATE' 'ADVECTION' ;
  154.     'SI' WTAB.'ADVECTION_MECANIQUE' ;
  155.       WTAB.'MOMEC_ADV' = 'EXTR' WTAB.'MOD_MEC' 'MATE' 'ADVECTION';
  156.     'FINSI';
  157.  
  158.     'SI' ('EXISTE' mod0 'FORM' 'MELANGE');
  159.       'SI' ('EXISTE' mod0 'MATE' 'PARALLELE');
  160.         MOPAL1 = 'EXTR' mod0 'MATE' 'PARALLELE' ;
  161.         'SI' ('EXISTE' MOPAL1 'FORM' 'MECANIQUE');
  162.           MAPAL1 = 'REDU' 'STRI' mat0 MOPAL1 ;
  163.           WTAB.'MOD_MEC' = MOPAL1 'ET' WTAB.'MOD_MEC' ;
  164.           WTAB.'MAT_MEC' = MAPAL1 'ET' WTAB.'MAT_MEC' ;
  165.         'FINSI' ;
  166.       'FINSI' ;
  167.     'FINSI';
  168.     WTAB.'MO_TOT' = WTAB.'MO_TOT' 'ET' WTAB.'MOD_MEC' ;
  169.   'FINSI';
  170. *
  171.   'SI' WTAB.'POR1' ;
  172.     WTAB.'MOD_POR' = 'EXTR' mod0 'FORM' 'POREUX';
  173.     WTAB.'MAT_POR' = 'REDU' mat0  WTAB.'MOD_POR';
  174.     WTAB.'MO_TOT'  = WTAB.'MO_TOT' 'ET' WTAB.'MOD_POR' ;
  175.   'FINSI';
  176. *
  177. * Initialisation des comportements d'apres le modele
  178.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'PLASTIQUE');
  179.     WTAB.'PLASTIQUE'      = VRAI;
  180.     WTAB.'IPLAVI'         = VRAI;
  181.   'FINSI';
  182.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'PLASTIQUE_ENDOM');
  183.     WTAB.'PLASTIQUE'      = VRAI;
  184.     WTAB.'ENDOMMAGEMENT'  = VRAI;
  185.     WTAB.'IPLAVI'         = VRAI;
  186.     MODZ = 'EXTR' WTAB.'MO_TOT' 'MATE' 'PLASTIQUE_ENDOM' ;
  187.     WTAB.'MOD_SPE' = WTAB.'MOD_SPE' 'ET' MODZ ;
  188.   'FINSI';
  189.   'SI' (('EXISTE' WTAB.'MO_TOT' 'MATE' 'VISCOPLASTIQUE') 'OU'
  190.         ('EXISTE' WTAB.'MO_TOT' 'MATE' 'FLUAGE'        ));
  191.     WTAB.'VISCOPLASTIQUE' = VRAI;
  192.     WTAB.'IPLAVI'         = VRAI;
  193.   'FINSI';
  194.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'VISCODOMMAGE');
  195.     WTAB.'VISCODOMMAGE'   = VRAI;
  196.     WTAB.'IPLAVI'         = VRAI;
  197.     MODZ = 'EXTR' WTAB.'MO_TOT' 'MATE' 'VISCODOMMAGE' ;
  198.     WTAB.'MOD_SPE' = WTAB.'MOD_SPE' 'ET' MODZ ;
  199.   'FINSI';
  200.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'ENDOMMAGEABLE');
  201.     WTAB.'ENDOMMAGEMENT'  = VRAI;
  202.     WTAB.'IPLAVI'         = VRAI;
  203.     MODZ = 'EXTR' WTAB.'MO_TOT' 'MATE' 'ENDOMMAGEABLE' ;
  204.     WTAB.'MOD_SPE' = WTAB.'MOD_SPE' 'ET' MODZ ;
  205.   'FINSI';
  206.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'ENDOMMAGEMENT') ;
  207.     WTAB.'ENDOMMAGEMENT'  = VRAI;
  208.     WTAB.'IPLAVI'         = VRAI;
  209.   'FINSI';
  210.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'NON_LINEAIRE') ;
  211.     WTAB.'NON_LINEAIRE'   = VRAI;
  212.     WTAB.'IPLAVI'         = VRAI;
  213.     WTAB.'UTILISATEUR'    = 'EXISTE' WTAB.'MO_TOT' 'MATE' 'UTILISATEUR' ;
  214.   'FINSI';
  215.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'VISCO_EXTERNE') ;
  216.     WTAB.'VISCO_EXTERNE'  = VRAI;
  217.     WTAB.'IPLAVI'         = VRAI;
  218.   'FINSI';
  219.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'CERAMIQUE');
  220.     WTAB.'CERAMIQUE'      = VRAI;
  221.     WTAB.'IPLAVI'         = VRAI;
  222.   'FINSI';
  223.   'SI' (('EXISTE' WTAB.'MO_TOT' 'MATE' 'MODAL'    ) 'OU'
  224.         ('EXISTE' WTAB.'MO_TOT' 'MATE' 'STATIQUE' ));
  225.     WTAB.'MODAL'          = VRAI;
  226.     WTAB.'IPLAVI'         = VRAI;
  227.   'FINSI';
  228.   'SI' ('EXISTE' WTAB.'MO_TOT' 'MATE' 'IMPEDANCE');
  229.     WTAB.'IMPEDANCE'      = VRAI;
  230.     WTAB.'IPLAVI'         = VRAI;
  231.   'FINSI';
  232. *
  233.   WTAB.'MO_VARI' = 'DIFF' WTAB.'MO_TOT' WTAB.'MOD_SPE' ;
  234. *
  235. * Creation, si besoin, du chargement de flux neutronique pour le modele mistral
  236.   'SI' ('EXIS' WTAB.'MO_TOT' 'MATE' 'MISTRAL');
  237.     'SI' ('NON' ('EXISTE' (WTAB.'CHARGEMENT') 'FI  ')) ;
  238.       MAI_TOT = 'EXTR' WTAB.'MO_TOT' 'MAIL' ;
  239.       FIZER = 'MANU' 'CHPO' MAI_TOT 1 'FI  ' 0. 'NATURE' 'DIFFUS' ;
  240.       WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT' 'ET' ('CHAR' 'FI' FIZER
  241.         ('EVOL' 'MANU'  ('PROG' 0. 10.e10 ) ('PROG' 1. 1.)));
  242.     'FINSI';
  243.   'FINSI';
  244. * Creation, si besoin, du chargement de densite de fissions pour gatt_monerie & uo2
  245.   'SI' (('EXIS' WTAB.'MO_TOT' 'MATE' 'UO2') 'OU'
  246.         ('EXIS' WTAB.'MO_TOT' 'MATE' 'GATT_MONERIE') ) ;
  247.     'SI' ('NON' ('EXISTE' (WTAB.'CHARGEMENT') 'DFIS')) ;
  248.       MAI_TOT = 'EXTR' WTAB.'MO_TOT' 'MAIL' ;
  249.       DFISZER = 'MANU' 'CHPO'  MAI_TOT 1 'DFIS' 0. 'NATURE' 'DIFFUS' ;
  250.       WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT' 'ET' ('CHAR' 'DFIS' DFISZER
  251.         ('EVOL' 'MANU'   ('PROG' 0. 10.e10 ) ('PROG' 1. 1.))) ;
  252.     'FINSI';
  253.   'FINSI';
  254. *
  255. * Non LOCale
  256.   lognlmo = 'EXIS' mod0 'NON_LOCAL' 'MOYE' ;
  257.   lognlsb = 'EXIS' mod0 'NON_LOCAL' 'SB  ' ;
  258.   lognlhe = 'EXIS' mod0 'NON_LOCAL' 'HELM' ;
  259.   WTAB.'NLOC' = lognlmo 'OU' lognlsb 'OU' lognlhe ;
  260.  
  261.   'SI' WTAB.'NLOC' ;
  262.  
  263. *   Verifier qu'il n'y a qu'un seul type de formulation non locale
  264.     'SI' ((lognlmo 'ET' lognlsb) 'OU' (lognlsb 'ET' lognlhe) 'OU' (lognlhe 'ET' lognlmo)) ;
  265.       'ERREUR' 'On ne peut pas avoir deux formulations non locales differentes' ;
  266.     'FINSI' ;
  267.  
  268. *   Cas 'MOYE'
  269.     'SI' lognlmo ;
  270.        WTAB.'NON_LOCAL' = 'MOT' 'MOYE' ;
  271.     'FINSI' ;
  272.  
  273. *    Cas 'SB'
  274.     'SI' lognlsb ;
  275.        WTAB.'NON_LOCAL' = 'MOT' 'SB' ;
  276.     'FINSI' ;
  277.  
  278. *    Cas 'HELM'
  279.     'SI' lognlhe ;
  280.        WTAB.'NON_LOCAL' = 'MOT' 'HELM' ;
  281.     'FINSI' ;
  282.  
  283.     WTAB.'NLOC_MODL' = 'EXTR' mod0 'NON_LOCAL' WTAB.'NON_LOCAL' ;
  284.  
  285.     'SI' lognlsb ;
  286.        MOD_SB = WTAB.'NLOC_MODL' ;
  287.        CHM_1 = 'MANU' 'CHML' MOD_SB 'LONG' 1.0 'STRESSES' 'TYPE' 'CARACTERISTIQUES' ;
  288.        CHM_L = 'INTG' 'ELEM' MOD_SB CHM_1 'LONG' ;
  289.        CHM_L = 'CHAN' 'COMP' 'LONG' CHM_L ;
  290.        CHM_L = 'CHAN' 'STRESSES' MOD_SB CHM_L ;
  291.        TAIL1 = CHM_L ** (1. / ('VALE' 'DIME')) ;
  292.        FTCH  = 'EXCO' mat0 'SBFT' 'SBFT' ;
  293.        FTCH  = 'CHAN' 'STRESSES' MOD_SB FTCH ;
  294.        MALVIA = TAIL1 '+' FTCH ;
  295.        WTAB.'NLOC_SB_REGU' = 'CHAN' MALVIA 'TYPE' 'VARIABLES INTERNES' ;
  296.     'FINSI' ;
  297.  
  298.   'FINSI' ;
  299. *
  300.   'SI' WTAB.'FCHA' ;
  301.     WTAB.'MOD_CHA' = 'EXTR' mod0 'FORM' 'CHARGEMENT' ;
  302.     WTAB.'MAT_CHA' = 'REDU' mat0 WTAB.'MOD_CHA' ;
  303.     'SI' ('EXIS' WTAB.'MOD_CHA' 'MATE' 'PRESSION') ;
  304.       WTAB.'MOD_PRE' = 'EXTR' (WTAB.'MOD_CHA') 'COMP' 'PRESSION' ;
  305. *   A t-on un MATE associe?
  306.       MATZ = 'REDU' mat0 WTAB.'MOD_PRE' ;
  307.       'SI' ('NEG' ('DIME' ('EXTR' MATZ 'COMP')) 0) ;
  308.         WTAB.'MAT_PRE' = MATZ ;
  309.       'FINSI' ;
  310.     'FINSI' ;
  311.     WTAB.'MO_VARI' = WTAB.'MO_VARI' 'ET' WTAB.'MOD_CHA' ;
  312.   'FINSI' ;
  313.  
  314. * Formulation LIAISON
  315.   'SI' WTAB.'FLIA' ;
  316.     WTAB.'MOD_LIA' = 'EXTR' mod0 'FORM' 'LIAISON' ;
  317.     WTAB.'MAT_LIA' = 'REDU' mat0 WTAB.'MOD_LIA' ;
  318.     WTAB.'MO_TOT'  = WTAB.'MO_TOT'  'ET' WTAB.'MOD_LIA' ;
  319.     WTAB.'MO_VARI' = WTAB.'MO_VARI' 'ET' WTAB.'MOD_LIA' ;
  320.   'FINSI' ;
  321. *
  322. * Formulation CONTACT :
  323.   'SI' WTAB.'CONTACT' ;
  324.     WTAB.'MODCONTA' = 'EXTR' mod0  'FORM' 'CONTACT';
  325.     MATCONTA = 'REDU' mat0 WTAB.'MODCONTA' ;
  326.     LSTCOMP  = 'EXTR' MATCONTA 'COMP' ;
  327.     'SI' ('NEG' ('DIME' LSTCOMP) 0) ;
  328.       WTAB.'MATCONTA' = MATCONTA ;
  329. *     A t-on la composante ADHE?
  330.       WTAB.'ADHERENCE' = 'EXIS' LSTCOMP 'ADHE' ;
  331.     'FINSI' ;
  332.     WTAB.'FROCOUL' = 'EXIS' WTAB.'MODCONTA' 'MATE' 'COULOMB' ;
  333.     WTAB.'FROCABL' = 'EXIS' WTAB.'MODCONTA' 'MATE' 'FROCABLE' ;
  334.     WTAB.'CAFROTTE' = WTAB.'FROCOUL' 'OU' WTAB.'FROCABL' ;
  335.   'FINSI';
  336. *
  337. * Informations pour COMP
  338.   WTAB.'LPAR0'     = 'EXTR' WTAB.'MO_TOT' 'PARA';
  339.   WTAB.'PARA_EXTE' = ('NEG' ('DIME' WTAB.'LPAR0') 0) ;
  340. *
  341.   WTAB.'MA_TOT' = 'REDU' mat0 WTAB.'MO_TOT' ;
  342.   WTAB.'LDEVA'  = 'EXTR' WTAB.'MA_TOT' 'DEVA';
  343.   LDEVA_DI      = 'DIME' WTAB.'LDEVA' ;
  344.   WTAB.'MATVAR' = ('NEG' LDEVA_DI 0) ;
  345.   'SI' WTAB.'MATVAR' ;
  346.     'SI' ('NON' (('EGA' LDEVA_DI 1) 'ET' 
  347.                  ('EGA' ('EXTR' WTAB.'LDEVA' 1) 'ALPH' ) ));
  348.       WTAB.'RECARI'= VRAI;
  349.     'FINSI';
  350.     'SI' WTAB.'FREQUENTIEL' ; WTAB.'MATVAR'= FAUX; 'FINSI';
  351.   'FINSI';
  352. *
  353. * Uniquement initialisation, sinon indice gere par UNPAS
  354.   'SI' ('NON' ('EXIS' WTAB 'MO_TOT_PREC')) ;
  355.     WTAB.'MO_TOT_PREC' = WTAB.'MO_TOT' ;
  356.   'FINSI' ;
  357. *
  358. 'FINSI';
  359. *
  360. * Formulation NAVIER_STOKES
  361. WTAB.'NVSTNL' = ('EXISTE' mod0 'FORM' 'NAVIER_STOKES')
  362.            'ET' ('EXISTE' mod0 'MATE' 'NLIN') ; 
  363. 'SI' WTAB. 'NVSTNL' ;
  364.   WTAB.'MOD_NSL' = 'EXTR' mod0 'MATE' 'NLIN' ;
  365.   WTAB.'MAT_NSL' = 'REDU' mat0 WTAB . 'MOD_NSL' ;
  366.   WTAB.'MO_TOT'  = WTAB.'MOD_NSL' ;
  367. 'FINSI' ;
  368. *
  369. 'FINP' TPASA1 ;
  370.  
  371.  
  372.  
  373.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales