Télécharger la plaquette Cast3M


fr en

Télécharger hrayo.procedur

Retour à la liste

Numérotation des lignes : 

  1. * HRAYO     PROCEDUR  MB234859  26/11/04    21:15:05     12691          
  2. 'DEBPROC' HRAYO RAYTYP*'MOT' MODRAY*'MMODEL' MATRAY*'MCHAML' CHPT*'CHPOINT'
  3.                 stefan/'FLOTTANT' ;
  4. *-----------------------------------------------------------------------
  5. * Calcul d'un coefficient d'échange linéarisé pour les rayonnement de 
  6. * type FACE A FACE ou INFINI .
  7. *
  8. * Entrees :
  9. * ---------
  10. *   RAYTYP : MOT valant FACE A FACE ou INFINI selon le modele
  11. *   MODRAY : Modele de rayonnement
  12. *   MATRAY : Materiau associe au modele de rayonnement
  13. *   CHPT   : CHPOINT de temperature courant
  14. *   stefan : Valeur de la constante de Stefan-Boltzmann
  15. *
  16. * Sortie  :
  17. * ---------
  18. *   HR     : Coefficient d'echange linearise appuye sur MODRAY
  19. *-----------------------------------------------------------------------
  20.   'SI' ('NON' ('EXIS' stefan)) ;
  21.     stefan = 5.673e-8 ;
  22.   'FINSI' ;
  23. *
  24.   CHPT = 'ENLE' CHPT 'LX' ;
  25.   EMIS = 'CHAN' 'CHPO' MATRAY MODRAY ;
  26. *
  27.   bFAF = 'EGA' RAYTYP 'FACE_A_FACE' ;
  28.   'SI' bFAF ;
  29. *   Exprimer les champs sur GEO1 : transfert de GEO2 -> GEO1 via GEO3
  30.     GEO1 GEO2 = 'EXTR' MODRAY 'OBJE' ;
  31.     GEO3  = 'EXTR' MODRAY 'MAIL' ;
  32. *
  33.     EMIS1 = 'REDU' ('EXCO' EMIS 'EMI1' 'SCAL') GEO1 ;
  34.     EMIS2 = 'REDU' ('EXCO' EMIS 'EMI2' 'SCAL') GEO2 ;
  35.     EMIS2 = 'KPRO' EMIS2 GEO3 ;
  36. *
  37.     CHPT  = 'NOMC' CHPT 'SCAL' ;
  38.     CHPT1 = 'REDU' CHPT  GEO1 ;
  39.     CHPT2 = 'REDU' CHPT  GEO2 ;
  40.     CHPT2 = 'KPRO' CHPT2 GEO3 ;
  41.   'SINON' ;
  42.     EMIS1 = 'EXCO' EMIS 'EMIS' 'SCAL' ;
  43.     EMIS2 = 1.D0 ;
  44.     'SI' ('EXIS' EMIS 'E_IN' ) ;
  45.       EMIS2 = 'EXCO' EMIS 'E_IN' 'SCAL';
  46.     'FINSI' ;
  47.     CHPT1 = 'NOMC' ('ENLE' CHPT 'TERA') 'SCAL' ;
  48.     CHPT2 = 'EXCO' CHPT 'TERA' 'SCAL' ;
  49.   'FINSI' ;
  50. *
  51.   COEF1 = 1. '-' EMIS1 ;
  52.   COEF2 = 1. '-' EMIS2 ;
  53.   COEF3 = COEF1 '*' COEF2 ;
  54.   DENOM = 1. '-' COEF3 ;
  55.   NUMER = EMIS1 '*' EMIS2 ;
  56.   ee    = NUMER '/' DENOM ;
  57.   sie   = stefan '*'ee ;
  58.   CHPT12= CHPT1 '*' CHPT1; 
  59.   CHPT22= CHPT2 '*' CHPT2;
  60.   hh1   = (CHPT12 '+' CHPT22) '*' (CHPT1 '+' CHPT2) ;
  61.   hh    = sie '*' hh1 ;
  62.   'SI' bFAF ;
  63.     hh2 = 'KPRO' hh GEO3 ;
  64.     hh  = hh 'ET' hh2 ;
  65.   'FINSI' ;
  66.   HR = 'NOMC' hh 'H' ;
  67.   HR = 'CHAN' 'CHAM' HR MODRAY 'RIGIDITE' ;
  68.   HR = 'CHAN' 'TYPE' HR 'CARACTERISTIQUE' ;
  69. 'FINPROC' HR ;
  70.  
  71.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales