$$$$ HRAYO
* HRAYO     PROCEDUR  MB234859  26/11/04    21:15:05     12691          
'DEBPROC' HRAYO RAYTYP*'MOT' MODRAY*'MMODEL' MATRAY*'MCHAML' CHPT*'CHPOINT'
                stefan/'FLOTTANT' ;
*-----------------------------------------------------------------------
* Calcul d'un coefficient d'échange linéarisé pour les rayonnement de 
* type FACE A FACE ou INFINI .
*
* Entrees :
* ---------
*   RAYTYP : MOT valant FACE A FACE ou INFINI selon le modele
*   MODRAY : Modele de rayonnement
*   MATRAY : Materiau associe au modele de rayonnement
*   CHPT   : CHPOINT de temperature courant
*   stefan : Valeur de la constante de Stefan-Boltzmann
*
* Sortie  :
* ---------
*   HR     : Coefficient d'echange linearise appuye sur MODRAY
*-----------------------------------------------------------------------
  'SI' ('NON' ('EXIS' stefan)) ;
    stefan = 5.673e-8 ;
  'FINSI' ;
*
  CHPT = 'ENLE' CHPT 'LX' ;
  EMIS = 'CHAN' 'CHPO' MATRAY MODRAY ;
*
  bFAF = 'EGA' RAYTYP 'FACE_A_FACE' ;
  'SI' bFAF ;
*   Exprimer les champs sur GEO1 : transfert de GEO2 -> GEO1 via GEO3
    GEO1 GEO2 = 'EXTR' MODRAY 'OBJE' ;
    GEO3  = 'EXTR' MODRAY 'MAIL' ;
*
    EMIS1 = 'REDU' ('EXCO' EMIS 'EMI1' 'SCAL') GEO1 ;
    EMIS2 = 'REDU' ('EXCO' EMIS 'EMI2' 'SCAL') GEO2 ;
    EMIS2 = 'KPRO' EMIS2 GEO3 ;
*
    CHPT  = 'NOMC' CHPT 'SCAL' ;
    CHPT1 = 'REDU' CHPT  GEO1 ;
    CHPT2 = 'REDU' CHPT  GEO2 ;
    CHPT2 = 'KPRO' CHPT2 GEO3 ;
  'SINON' ;
    EMIS1 = 'EXCO' EMIS 'EMIS' 'SCAL' ;
    EMIS2 = 1.D0 ;
    'SI' ('EXIS' EMIS 'E_IN' ) ;
      EMIS2 = 'EXCO' EMIS 'E_IN' 'SCAL';
    'FINSI' ;
    CHPT1 = 'NOMC' ('ENLE' CHPT 'TERA') 'SCAL' ;
    CHPT2 = 'EXCO' CHPT 'TERA' 'SCAL' ;
  'FINSI' ;
*
  COEF1 = 1. '-' EMIS1 ;
  COEF2 = 1. '-' EMIS2 ;
  COEF3 = COEF1 '*' COEF2 ;
  DENOM = 1. '-' COEF3 ;
  NUMER = EMIS1 '*' EMIS2 ;
  ee    = NUMER '/' DENOM ;
  sie   = stefan '*'ee ;
  CHPT12= CHPT1 '*' CHPT1; 
  CHPT22= CHPT2 '*' CHPT2;
  hh1   = (CHPT12 '+' CHPT22) '*' (CHPT1 '+' CHPT2) ;
  hh    = sie '*' hh1 ;
  'SI' bFAF ;
    hh2 = 'KPRO' hh GEO3 ;
    hh  = hh 'ET' hh2 ;
  'FINSI' ;
  HR = 'NOMC' hh 'H' ;
  HR = 'CHAN' 'CHAM' HR MODRAY 'RIGIDITE' ;
  HR = 'CHAN' 'TYPE' HR 'CARACTERISTIQUE' ;
'FINPROC' HR ;