Procédures | Cast3M

* ELECNEUT  PROCEDUR  AURI      98/12/29    21:16:17     3419           
DEBPROC ELECNEUT TB3*TABLE TBC2*OBJET TBPAR2*OBJET LIMODI/LISTENTI ;
*********************************************************************
*
*      recherche de la neutralité électrique
*
*********************************************************************
MSINEUT=VRAI ;
**
'MESS''Voulez afficher les speciations ?' ;
'OBTE' ISPECI ;
IIMPI= VALE 'IMPI' ;
IIMP1= VALE 'IMPI' ;
SI ('EGA' ISPECI 'OUI' ) ;
IIMP1= 1 ;
'FINSI' ;
OPTION IMPI IIMP1 ;
 TB4 = CHI2 TB3  TBC2 TBPAR2 ;
OPTION IMPI IIMPI ;
**
EPS= 1.D-3 ;
CHACHA= 'NEUT' TB3 TB4.'SOLU' ;
      'MESS' 'Voulez vous afficher le bilan électrique' ;
      'OBTE' ISUITE ;
      'SI' ('EGA' ISUITE 'OUI') ;
       NTAB CHACHA 'TITR' 'BILAN ELECTRIQUE' ;
      'FINSI' ;
CHAPLUS= 'EXCO' CHACHA 'CATI' 'SCAL' ;
CHAMOIN= 'EXCO' CHACHA 'ANIO' 'SCAL' ;
CHANEUT= (CHAPLUS +CHAMOIN)*2. / ( CHAPLUS -CHAMOIN);
TEST= (ABS CHANEUT) MASQ 'SUPERIEUR' 'SOMME' EPS ;
SI ( TEST 'EGA' 0) ;
             MESS ' Neutralité électrique vérifiée' ;
             MSINEUT=FAUX ;
SINON ;
'SI' ('NON'( 'EXIS' LIMODI)) ;
        MESS ' Entrez la liste des composants dont on peut modifier '
        'les concentrations totales ' ;
         OBTE LIMODI*LISTENTI ;
'FINSI' ;
 DDZZ=  CHAPLUS+ CHAMOIN ;
 NBIDX=DIME TB3.DESCHI.IDX ;
 TOTO= TBC2%ACCES GTOT ;
 TOT1= COPI TOTO   ;
 NBMODI= DIME LIMODI ;
 TABCHA= TABLE ;
 'REPE' BOUNEUT 20 ;
 CHATOT= 0 ;
 'REPE' BCHAR NBMODI ;
 NN1= EXTR LIMODI &BCHAR ;
 REPE BOUDX NBIDX ;
       NUII= EXTR (TB3.DESCHI.IDX) &BOUDX ;
       SI( 'EGA' NUII NN1) ;
          CHACDX= EXTR(TB3.DESCHI.CHARGE) &BOUDX ;
          TABCHA.NN1= CHACDX ;
       FINSI ;
 FIN BOUDX ;
 CHATOT= CHATOT+(ABS  CHACDX)  ;
 FIN BCHAR ;
 'REPE' BNTOT NBMODI ;
 NN1= EXTR LIMODI &BNTOT ;
 CHACDX= TABCHA.NN1 ;
 MAPLU= MASQ ( DDZZ*CHACDX) SUPERIEUR 0. ;
 MANEG= MASQ  (DDZZ*CHACDX) INFERIEUR 0. ;
 TOTN= ((ABS DDZZ)/CHATOT ) * MANEG ;
 TOTP= ((ABS DDZZ)/CHATOT ) * MAPLU ;
*MESS ' TOTI ' ; LIST TOTI ;
 MO4 MO3 NU2 = NOCOMCHI TB3 'NUMCOMP' NN1 ;
 TOTN= NOMC MO3 TOTN ;
 TOTP= NOMC MO3 TOTP ;
 TOTO=TOTO+TOTN - TOTP ;
 SI (NEG NN1 50) ;
 TOT2= 'EXCO' TOTO MO3  MO3 ;
 TES2= TOT2 MASQ 'INFERIEUR' 'SOMME' 0 ;
 SI (TES2 > 0) ;
 MSINEUT= VRAI ;
 QUITTER BOUNEUT ;
 FINSI ;
 FINSI ;
 FIN BNTOT ;
 TBC2%GTOT  TOTO  ;
*TB4 = SPECHI2 TB3  TBC2 TBPAR2 ;
**
'MESS''Voulez afficher les speciations ?' ;
'OBTE' ISPECI ;
IIMPI= VALE 'IMPI' ;
IIMP1= VALE 'IMPI' ;
SI ('EGA' ISPECI 'OUI' ) ;
IIMP1= 1 ;
'FINSI' ;
OPTION IMPI IIMP1 ;
 TB4 = CHI2 TB3  TBC2 TBPAR2 ;
OPTION IMPI IIMPI ;
**
CHACHA= 'NEUT' TB3 TB4.'SOLU' ;
      'MESS' 'Voulez vous afficher le bilan électrique' ;
      'OBTE' ISUITE ;
      'SI' ('EGA' ISUITE 'OUI') ;
       NTAB CHACHA 'TITR' 'BILAN ELECTRIQUE' ;
      'FINSI' ;
CHAPLUS= 'EXCO' CHACHA 'CATI' 'SCAL' ;
CHAMOIN= 'EXCO' CHACHA 'ANIO' 'SCAL' ;
CHANEUT= (CHAPLUS +CHAMOIN)*2. / ( CHAPLUS -CHAMOIN);
TEST= (ABS CHANEUT) MASQ 'SUPERIEUR' 'SOMME' EPS ;
SI ( TEST 'EGA' 0) ;
       MSINEUT=FAUX ;
       MESS ' Neutralité électrique vérifiée' ;
       OUBLIE TOT1 ;
        QUITTER BOUNEUT ;
FINSI ;
   DDZZ=  CHAPLUS+ CHAMOIN ;
 'FIN' BOUNEUT ;
 SI MSINEUT ;
 TBC2%GTOT TOT1 ;
 'MESS' ' On ne peut atteindre l équilibre electrique en '
  'modifiant les concentrations de ces composants' ;
  OUBLIE TOTO ;
 FINSI ;
 FINSI ;
'FINP' MSINEUT ;