Télécharger la plaquette Cast3M


fr en

Télécharger condens.procedur

Retour à la liste

Numérotation des lignes : 

  1. * CONDENS   PROCEDUR  FD144363  22/12/22    21:15:03     11536          
  2. 'DEBP' CONDENS RXT*TABLE $paroic*MMODEL MTP*MOT MTF*MOT MRVP*MOT
  3.        KHcu*'FLOTTANT' ;
  4. *
  5. *-----------------------------------------------------------------------
  6. * Modélisation de la ondensation en paroi
  7. *-----------------------------------------------------------------------
  8. *
  9. * E/  rxt     : Interface avec l'utilisateur
  10. * E/  $paroic : MMODEL de la paroi condensante
  11. * E/  MTP     : Nom dans INCO de la température paroi 
  12. * E/  MTF     : Nom dans INCO de la température fluide 
  13. * E/  MRVP    : Nom dans INCO de la densité vapeur 
  14. * E/  KHCU    : Borne inf. du coefficient d'échange sensible (W/m2/K)
  15. *
  16. *  /S QC    : FLOTTANT  : Flux de vapeur condensé sur $paroic (kg/s)
  17. *  /S FCOND : CHPO (SS) : Débit de condensation surfacique (kg/m2/s)
  18. *  /S ECOND : FLOTTANT  : Energie vers la paroi due à la condensation (W)
  19. *  /S HCOND : FLOTTANT  : Enthalpie vers la paroi due à la condensation (W) 
  20. *  /S KKC   : CHPO (SC) : Coefficient de transfert de masse (m/s)
  21. *  /S RvI   : CHPO (SS) : Densité vapeur à l'interface = ROsat(Psat(Tw),Tw) (kg/m3)
  22. *  /S FHP   : CHPO (SC) : Puissance surfacique totale vers la paroi (W/m2)
  23. *  /S HT    : CHPO (SS) : Coefficient de transfert thermique par
  24. *                         convecton (energie sensible, W/m2/K)
  25. *
  26. *-----------------------------------------------------------------------
  27. * Les flux de masse Jv et de chaleur Phi sont calculés via l'analogie
  28. * de Chilton-Colburn :
  29. *   Jv  = kc ro (Yv - Yvsat)   (en kg/s/m2),
  30. *   Phi = HT (Tg - Tw) + Jv Lv (en W/m2)
  31. * où kc (resp. H_T) est la somme d'une contribution de convection
  32. * naturelle et d'une contribution de convection forcée :  
  33. *   Sh  = k L / Dv = Sh1 + Sh2   Nu  = HT L / lambda = Nu1 + Nu2
  34. *   Sh2 = 0.13 (Gr Sc)**1/3      Nu1 = 0.13 (Gr Pr)**1/3    
  35. *         (convection naturelle, corrélation de Mc Adams)
  36. *   Sh1 = 0.0296 Re**0.8 Sc**1/3 Nu2 = 0.0296 Re**0.8 Pr**1/3 
  37. *         (couche limite turbulente sur une plaque plane))
  38. *-----------------------------------------------------------------------
  39. * Hypotheses :
  40. * 1. On néglige la résistance du film liquide : Ti=Tw et Pv,i=Psat(Tw)
  41. * 2. Même composition du mélange en air sec au bulk et à l'interface
  42. *------------------------------------------------------------------------
  43. *
  44. 'SI' ('NON' rxt . 'TBT' . 'VAPEUR') ;
  45.   'QUIT' CONDENS ;
  46. 'FINS' ;
  47. tbt = rxt . 'TBT' ;
  48. tic = rxt . 'TIC' ;
  49. geo = rxt . 'GEO' ;
  50. *
  51. paroic = 'DOMA' $paroic 'MAILLAGE' ;
  52. Diagpc = 'DOMA' $paroic 'XXDIAGSI' ;
  53. *
  54. ndlc  = 'DIME' tic . 'PT' ;
  55. Pt    = 'EXTR' tic . 'PT'    ndlc ;
  56. Rhomn = 'EXTR' tic . 'Rhomn' ndlc ;
  57. Cpm   = 'EXTR' tic . 'Cpm'   ndlc ;
  58. *
  59. *
  60. *- Paroi condensante (P)
  61. *
  62. *
  63. * Densités du mélange, des incondensables
  64. * transportés, de la vapeur et de l'air
  65. ROP = 'REDU' tic . 'RHO' paroic ;
  66. RH2P RHEP RO2P RN2P RCO2P RCOP = 0. 0. 0. 0. 0. 0. ;
  67. 'SI' TBT . 'TH2' ;
  68.   RH2P  = 'REDU' tic . 'RH2'  paroic ;
  69. 'FINS' ;
  70. 'SI' TBT . 'THE' ;
  71.   RHEP  = 'REDU' tic . 'RHE'  paroic ;
  72. 'FINS' ;
  73. 'SI' TBT . 'TO2' ;
  74.   RO2P  = 'REDU' tic . 'RO2'  paroic ;
  75. 'FINS' ;
  76. 'SI' TBT . 'TN2' ;
  77.   RN2P  = 'REDU' tic . 'RN2'  paroic ;
  78. 'FINS' ;
  79. 'SI' TBT . 'TCO2' ;
  80.   RCO2P = 'REDU' tic . 'RCO2' paroic ;
  81. 'FINS' ;
  82. 'SI' TBT . 'TCO' ;
  83.   RCOP  = 'REDU' tic . 'RCO'  paroic ;
  84. 'FINS' ;
  85. RvP = 'REDU' tic . MRVP paroic ;
  86. RvP = 'KOPS' RvP '|<' 1.e-10 ;
  87. *
  88. * Rnc : densité des incondensables (air non compris)
  89. * Correction 1 : RairP=0 et RvP=ROP - Rnc si Rair<0
  90. * Correction 2 : RvP = 0 si ROP - Rnc < 0
  91. Rnc   = Rh2P '+' RheP '+' Ro2P '+' Rn2P '+' Rco2P '+' RcoP ;
  92. Rtest = ROP '-' Rnc ;
  93. RvP   = 'MINI' RvP Rtest ;
  94. RvP   = 'KOPS' RvP '|<' 1.e-10 ;
  95. RairP = ROP '-' RvP '-' Rnc ;
  96. RairP ='KOPS' RairP '|<' 1.e-10 ;
  97. *
  98. * Fractions massiques
  99. IROP  = 'INVE' ROP     ;
  100. YvP   = RvP   '*' IROP ;
  101. Yh2P  = Rh2P  '*' IROP ;
  102. YheP  = RheP  '*' IROP ;
  103. Yo2P  = Ro2P  '*' IROP ;
  104. Yn2P  = Rn2P  '*' IROP ;
  105. Yco2P = Rco2P '*' IROP ;
  106. YcoP  = RcoP  '*' IROP ;
  107. YairP = RairP '*' IROP ;
  108. *
  109. * Viscosité dynamique (Pa/s)
  110. MuP = 'REDU' tic . 'Mu' paroic ;
  111. *
  112. * Températures gaz et paroi (K)
  113. Tfk  = ('REDU' tic . MTF paroic) '+' 273.15 ;
  114. Twk  = ('REDU' tic . MTP paroic) '+' 273.15 ;
  115. *
  116. * Pvap
  117. PvP = RvP '*' TBT . 'Rgvap' '*' Tfk ;
  118. *
  119. *
  120. *- Interface (I)
  121. *
  122. *
  123. * P et RO de la vapeur :
  124. * Pvap=Psat(Tw) et ROvap = RO(Psat(Tw),Tw)
  125. PvI  = PSATT Twk ;
  126. RvI = PvI '*' ('INVE' (TBT . 'Rgvap' * Twk)) ;
  127. *
  128. * P et RO des incondensables avec filtre du cas YVP=1 (100% vapeur en paroi)
  129. * (hyp : même composition en air sec du mélange en (P) et en (I))
  130. PncI   = Pt  -  PvI ;
  131. epsyvp = 1.D-10 ;
  132. fyvp   = 'MASQUE' (1.0 '-' YVP) 'SUPERIEUR' epsyvp ;
  133. YncP   = (1. '-' YVP '*' fyvp) '+' (1.0 '-' fyvp '*' epsyvp) ;
  134. RgncI = (TBT . 'Rgo2'  '*' YO2P) '+' (TBT . 'Rgn2'  '*' YN2P)  '+'
  135.         (TBT . 'Rghe'  '*' YHEP) '+' (TBT . 'Rgh2'  '*' YH2P)  '+'
  136.         (TBT . 'Rgco'  '*' YCOP) '+' (TBT . 'Rgco2' '*' YCO2P) '+' 
  137.         (TBT . 'Rgair' '*' YAIRP) '/' YncP ;
  138. RncI  = PncI '*' ('INVE' (RgncI '*' Twk)) '*' fyvp ;
  139. *
  140. * RO du mélange
  141. ROI =  RvI '+' RncI ;
  142. *
  143. * Fraction massique vapeur
  144. YvI =  RvI '*' ('INVE' ROI) ;
  145. *
  146. *
  147. *- Corrélation
  148. *
  149. *
  150. * DV : Coefficient de diffusion de la vapeur dans le mélange (m2/s)
  151. YO2NP = YO2P '+' (YAIRP '*' 0.2329) ;
  152. YN2NP = YN2P '+' (YAIRP '*' 0.7671) ;
  153. DV = VAPDIF Pt Tfk YVP YH2P YHEP YO2NP YN2NP YCO2P YCOP ;
  154. *
  155. *
  156. * Corrélation de convection naturelle
  157. *
  158. *
  159. * Coefficient de transfert de masse k (m/s)
  160. BB  = 0.13 '*' ((9.81 * Rhomn '*' ('INVE' MuP)) '**' (1./3.)) ;
  161. DRO = (('ABS' (ROP '-' ROI)) '*' IROP) '**' (1./3.) ;
  162. 'SI' ('EGA' TBT.'MODCOND' 'CHIL1');
  163.    may1  = 'MASQUE' (1. '-' YVI) 'SUPERIEUR' 0.0001;
  164.    denom = (may1 * (1. '-' YVI)) + ((1. '-' may1) '*' 0.0001) ;
  165.    DRO   = DRO '*' ('INVE' DENOM) ;
  166. 'FINSI' ;
  167. KKCN = (DV '**' (2./3.)) '*' DRO '*' BB  ;
  168. *
  169. * Coefficient Echange convectif
  170. * hL/lambda = 0.13 (Gr Pr) ** 1/3
  171. * Ht = DRO*BB*Lambda * (rho*(inve MuP)) ** 1/3
  172. * or Pr = 1 donc Lambda = MuP*Cp
  173. LAMBM = MuP '*' Cpm ;
  174. HTCN  = DRO '*' BB '*' LAMBM '*' ((Rhomn '*' ('INVE' MuP))'**' (1./3.)) ;
  175. *
  176. *
  177. * Corrélation de convection forcée
  178. * Prise en compte si tic . 'LREF' existe
  179. *
  180. *
  181. 'SI' ('EXIS' tic 'LREF') ;
  182. *
  183. * Vitesse pour le Reynolds
  184.   un   = tic . 'UN' ;
  185.   lcu  = 'EXTR' un 'COMP' ;
  186.   modu = (un lcu 'PSCA' un lcu) '**' 0.5 ;
  187.   modu = 'NOEL' GEO . '$vtf' modu ;
  188.   modu = 'ELNO' GEO . '$vtf' modu ;
  189.   modu = 'NOEL' GEO . '$vtf' modu ;
  190.   modu = 'ELNO' GEO . '$vtf' modu ;
  191.   modu = 'NOEL' GEO . '$vtf' modu ;
  192.   modu = 'ELNO' GEO . '$vtf' modu ;
  193.   modu = 'REDU' modu paroic ;
  194. *
  195. * Filtre des valeurs négatives ou nulles de lref
  196.   lref = 'REDU' tic . 'LREF' paroic ;
  197.   lmin = 1.D-8 ;
  198.   IL1   = lref 'MASQ' 'EGSUP' lmin ;
  199.   lref  = (IL1 '*' lref) - (IL1 '-' 1. '*' lmin) ;
  200. *
  201. * Corrélation plaque plane turbulente
  202.   KKCF = (DV '**' (2./3.)) '*' (modu '**' 0.8)
  203.        '*' 0.0296 '*' (lref '**' (-0.2))
  204.        '*' ((Rhomn '*' ('INVE' MuP)) '**' (1.4/3.)) ;
  205. *
  206.   HTCF = (modu '**' 0.8) * LAMBM
  207.        '*' 0.0296 '*' (lref '**' (-0.2))
  208.        '*' ((Rhomn '*' ('INVE' MuP)) '**' 0.8) ;
  209. *
  210.   KKCF = IL1 '*' KKCF ;
  211.   HTCF = IL1 '*' HTCF ;
  212. *  
  213.   KK   = 'ABS' (KKCN '+' KKCF) ;
  214.   HT   = 'ABS' (HTCN '+' HTCF) ;
  215. 'SINO' ;
  216.   KK = 'ABS' KKCN ;
  217.   HT = 'ABS' HTCN ;
  218. 'FINS' ;
  219. *
  220. * Fonction indicatrice de la condensation
  221. IND  = (PvP - PvI) 'MASQ' 'EGSUP'  0. ;
  222. *
  223. * Khcu &lt;EG HT &lt;EG HTMAX
  224. HT    = (IND '*' HT) '-' (IND '-' 1. '*' KHcu) ;
  225. INDH  = HT 'MASQ' 'EGSUP' KHcu ;
  226. HT    = (INDH '*' HT) '-' (INDH '-' 1. '*' KHcu) ;
  227. HTMAX = 5000. ;
  228. IK1   = HT 'MASQ' 'INFERIEUR' HTMAX ;
  229. HT    = (IK1 '*' HT) - (IK1 '-' 1. '*' HTMAX) ;
  230. *
  231. * Jv = kc ro (Yv - Yvsat)  (en kg/s/m2)
  232. * Qc = intégrale de Jv sur paroic
  233. KKC = 'KCHT' $paroic 'SCAL' 'SOMMET' (KK  '*' IND) ; 
  234. KRO = 'KCHT' $paroic 'SCAL' 'SOMMET' (KKC '*' ROP) ;
  235. KKC = 'NOEL' $paroic KKC ;
  236. *fd
  237. *YVI='KOPS' YVI '>|' 0.99   ;
  238. *DYV = YvP - YvI ;
  239. *BM = (YVI '-' YVP) '/' (1.0 '-' YVI);
  240. *mess ' mini maxi BM ' ' ' (mini bm) ' ' (maxi Bm) ;
  241. *bm = 'ABS' bm ;
  242. *FSUC = ('LOG' (1.0 '+' BM)) '*' ('INVE' BM) ;
  243. *FCOND =  DYV * KRO * FSUC ;
  244. *fd
  245. Fcond =  (YvP '-' YvI) '*' KRO ;
  246. Qc    = Diagpc '*' Fcond ;
  247. QcT   = Qc '*' Tfk ;
  248. Qc    = 'ABS' ('SOMT' Qc) ;
  249. QcT   = 'ABS' ('SOMT' QcT) ;
  250. Econd = tbt . 'Cvvap' '*' QcT ;
  251. Hcond = tbt . 'Cpvap' '*' QcT ;
  252. *
  253. RvI   = 'KCHT' $paroic 'SCAL' 'SOMMET' RvI;
  254. Fcond = 'KCHT' $paroic 'SCAL' 'SOMMET' Fcond ;
  255. Fconv = 'KCHT' $paroic 'SCAL' 'SOMMET' (Tfk '-' Twk '*' HT) ;
  256. FHP   = 'NOEL' $paroic (Fcond '*' tbt . 'Lv' '+' Fconv) ;
  257. *
  258. **** Affichage de grandeurs moyennes
  259. *volp = 'SOMT' (Diagpc) ;
  260. *'MESS' '==> Tgaz moyen paroi = '((somt (Diagpc * Tfk))/volp) ;
  261. *'MESS' '==> Tpar moyen paroi = '((somt (Diagpc * Twk))/volp) ;
  262. *'MESS' '==> Yvpa moyen paroi = '((somt (Diagpc * YVP))/volp) ;
  263. *'MESS' '==> KKC (mini) (maxi) = ' (MINI KKC)  (MAXI KKC)   ;
  264. *
  265. 'FINP' Qc Fcond Econd Hcond KKC RvI FHP HT  ; 
  266.  
  267.  
  268.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales