Procédures | Cast3M

* TOPOCHAN  PROCEDUR  FD218221  25/12/18    21:15:03     12429          
 
************************************************************************
** Procedure called by TOPOPTIM to switch the associated model of an
** element field expressed at the centroid of the elements.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** 1.2 2025/11/21 Use EXTR instead of PROI to save computation time
** 1.1 2021/04/20 Fixed a minor issue by adding 'SCALAIRE' type
** 1.0 2017/04/18 Initial version
************************************************************************
 
DEBP TOPOCHAN inpfld*'MCHAML' mod*'MMODEL' ctrmsh*'MAILLAGE' ;
 
*   List of components of inpfld
    lstcpn = EXTR inpfld 'COMP' ;
 
*   If there is only one component
    SI ((DIME lstcpn) EGA 1) ;
 
*       Extract the name of the component and the type of the input field
        cpn = EXTR lstcpn 1 ;
        typ = EXTR (EXTR inpfld 'TYPE') 1 ;
*       Extract all values in the order of ctrmsh
        val = EXTR inpfld 'VALE' cpn ;
*       Get the element field associated with the given model
        outfld = MANU 'CHML' mod 'REPA' cpn val 'TYPE' typ 'GRAVITE' ;
*       In thermal mode, the 'GRAVITE' option is not respected
*       This issue is resolved by using CHAN 'GRAVITE' outfld mod
 
*   If there is more than one component
    SINO ;
 
*       Loop over each component
        REPE itr (DIME lstcpn) ;
            cpn = EXTR lstcpn &itr ;
            tmp = TOPOCHAN (EXCO inpfld cpn) mod ctrmsh ;
            SI (&itr EGA 1) ;
                outfld = tmp ;
            SINO ;
                outfld = outfld ET tmp ;
            FINS ;
        FIN itr ;
 
    FINS ;
 
FINP outfld ;