Télécharger la plaquette Cast3M


fr en

Télécharger propag.procedur

Retour à la liste

Numérotation des lignes : 

  1. * PROPAG    PROCEDUR  CB215821  15/12/02    21:15:16     8719           
  2.   'DEBPROC' PROPAG ETAB*'TABLE';
  3. ************************************************************************
  4. *                                                                      *
  5. *    PROCEDURE PERMETTANT D" OBTENIR LA LOI MOMENT-COURBURE POUR       *
  6. *    L"ELEMENT DE TUYAU FISSURE A PARTIR DE LA COURBE DE TRACTION      *
  7. *    (SIG,EPS) ET DE LA COURBE (J,DELTA A) DU MATERIAU.                *
  8. *                                                                      *
  9. *    PLUSIEURS METHODES SONT PROPOSEES POUR DETERMINER CETTE LOI       *
  10. *    MOMENT-COURBURE.                                                  *
  11. *                                                                      *
  12. ************************************************************************
  13. ************************************************************************
  14. *                                                                      *
  15. *               LA PROCEDURE PROPAG UTILISE :                          *
  16. *                                                                      *
  17. *   SOIT UNE BASE DE DONNEES EXPERIMENTALES                            *
  18. *            - DEFR                                                    *
  19. *                                                                      *
  20. *   SOIT DES METHODES SIMPLIFIEES                                      *
  21. *            - TADA-PARIS                                              *
  22. *            - LBB-NRC                                                 *
  23. *            - LBB1                                                    *
  24. *            - LBB2                                                    *
  25. *                                                                      *
  26. *   ELLE FAIT APPEL AUX ARGUMENTS SUIVANTS:                            *
  27. *                                                                      *
  28. *                                                                      *
  29. * ENTREES                                                              *
  30. *                                                                      *
  31. *    ETAB.'METHODE'   =  MOT CLE INDIQUANT LA METHODE EMPLOYEE         *
  32. *    ETAB.'COUTRA'    =  COURBE DE TRACTION (SIG,EPS) DU MATERIAU      *
  33. *    ETAB.'JDA'       =  COURBE (J,DELTA-A) DU MATERIAU                *
  34. *    ETAB.'YOUN'      =  MODULE D'YOUNG                                *
  35. *    ETAB.'SIG1'      =  CONTRAINTE POUR UNE DEFORMATION DE 0.002      *
  36. * OU ETAB.'SIGF'      =  CONTRAINTE D'ECOULEMENT                       *
  37. *    ETAB.'REXT'      =  RAYON EXTERIEUR DU TUYAU FISSURE              *
  38. *    ETAB.'EPAI'      =  EPAISSEUR DU TUYAU FISSURE                    *
  39. *    ETAB.'ANGLE'     =  ANGLE TOTAL DE LA FISSURE (EN DEGRES)         *
  40. *    ETAB.'COUL'      =  COULEUR AFFECTEE A LA COURBE                  *
  41. *   (ETAB.'ALFA')     =  VALEURS FACULTATIVES PERMETTANT DE FITER      *
  42. *   (ETAB.'N')        =  LA COURBE DE TRACTION (METHODE LBBNRC)        *
  43. *                                                                      *
  44. *                                                                      *
  45. * SORTIES                                                              *
  46. *                                                                      *
  47. *    EVO6             =  COURBE  (M,PHI) AVEC PROPAGATION              *
  48. *                                                                      *
  49. ************************************************************************
  50.  
  51.  
  52. *----------------------RECEPTION DES ARGUMENTS-------------------------*
  53.  
  54.   COUL = ETAB . 'COUL';
  55.   ANINI = ETAB . 'ANGLE';
  56.   RAY = ETAB . 'REXT';
  57.   EPA = ETAB . 'EPAI';
  58.   E = ETAB . 'YOUN';
  59.   EVO2 = ETAB . 'JDA';
  60.   LISTJ = PROG 90 * 0.;
  61.   LA1 = PROG 90 * 0.;
  62.   LA2 = PROG 90 * 0.;
  63.   LSOLPHI = PROG 300 * 0.;
  64.   LSOLM = PROG 300 * 0.;
  65.   IN = 2;
  66.   AN = ANINI;
  67.   I = 1;
  68.   RAYM = RAY - (EPA / 2.);
  69.  
  70.  
  71.   JPP = 0.;
  72.   'REPE' SB1;
  73.       I = I + 1;
  74.       ETAB . 'ANGLE' = AN;
  75.       EVTE CM KF = TRACTUFI ETAB;
  76.       LISS1 = 'EXTR' EVTE ABSC;
  77.       LISS2 = 'EXTR' EVTE ORDO;
  78.       D = 'DIME' LISS1;
  79.       LISS1 = LISS1 ET (PROG (('EXTR' LISS1 D) * 10.));
  80.       LISS2 = LISS2 ET (PROG ('EXTR' LISS2 D));
  81.       EVTE = EVOL MANU LISS1 LISS2;
  82.       P = (I - 2);
  83.       'SI' (P <EG 0);
  84.          EVOINIT = EVTE;
  85.          KF0 = KF;
  86.          CM0 = CM;
  87.       'FINSI';
  88.       PHIMAX = 'EXTR' LISS1 (D + 1);
  89.  
  90. *------------------------CALCUL DE J1C--------------------------------*
  91.  
  92.       TET1 = (AN * PI) / 180.;
  93.       TET2 = (ANINI * PI) / 180.;
  94.       DA = (RAYM * (TET1 - TET2)) / 2.;
  95.  
  96.       LDA = 'EXTR' EVO2 ABSC;
  97.       LJ = 'EXTR' EVO2 ORDO;
  98.       DE = 'DIME' LDA;
  99.       DAMAX = 'EXTR' LDA DE;
  100.       'SI' (DA >EG DAMAX);
  101.            I = I - 1;
  102.            'QUITTER' SB1;
  103.       'FINSI';
  104.       J1C = IPOL DA LDA LJ;
  105.  
  106. *--------------ENCADREMENT DE PHI SOLUTION POUR TETA DONNE-------------*
  107.       GG = 0;
  108.       KK = 1;
  109.       'REPE' SB3;
  110.             BX = 'EXTR' LA1 (I - 1);
  111.             BX = BX + (KK * 0.01);
  112.             'SI' (BX < PHIMAX);
  113.                   D2 = 'IPOL' BX LISS1 LISS2;
  114.             'SINON';
  115.                   'SI' ('EGA' GG 1);
  116.                       I = I - 1;
  117.                       'QUITTER' SB1;
  118.                   'FINSI';
  119.                   BX = 0.9999 * PHIMAX;
  120.                   D2 = 'IPOL' BX LISS1 LISS2;
  121.                   GG = 1;
  122.             'FINSI';
  123.             'REMP' LA1 I BX;
  124.             'REMP' LA2 I D2;
  125.  
  126. *--------------------------CALCUL DE J TOTAL---------------------------*
  127.  
  128. *---------CALCUL D"UN DELTAJP SUPPLEMENTAIRE DU AU IEME POINT----------*
  129.  
  130.             AX = 'EXTR' LA1 (I - 1);
  131.             D1 = 'EXTR' LA2 (I - 1);
  132.             C = (AX + BX) / 2.;
  133.             MMOY = IPOL C LISS1 LISS2;
  134.             SIGMOY = MMOY / (4 * RAYM * RAYM * EPA *
  135.               (('COS'(AN / 4.)) - (0.5 * ('SIN'(AN / 2.)))));
  136.             DPHIP = (BX - AX) - (CM0 * (D2 - D1));
  137.             JP = JPP + ((SIGMOY * RAYM * (('COS'(AN / 2.))
  138.                                + ('SIN'(AN / 4.)))) * DPHIP);
  139. *----------------------CALCUL DE JE-------------------------------------
  140.  
  141.             JE = ((KF0 * D2) ** 2) / E;
  142.  
  143.             J = JE + JP;
  144.             LOG4 = (J > J1C);
  145.             'SI' LOG4;
  146.                  'QUITTER' SB3;
  147.             'SINON';
  148.                  KK = KK + 1;
  149.             'FINSI';
  150.  
  151.       'FIN' SB3;
  152.  
  153. *-------------RECHERCHE DE PHI SOLUTION PAR DICHOTOMIE-------------*
  154.  
  155.       PHIINF0 = 'EXTR' LA1 (I - 1);
  156.       PHIINF = PHIINF0;
  157.       PHISUP = 'EXTR' LA1 I;
  158.       'REPE' SB4;
  159.            PHICOUR = (PHIINF + PHISUP) / 2.;
  160.            MCOUR = 'IPOL' PHICOUR LISS1 LISS2;
  161.            SI ('EGA' PHIINF PHIINF0);
  162.                  MINF = 'EXTR' LA2 (I - 1);
  163.            SINON;
  164.                MINF = 'IPOL' PHIINF LISS1 LISS2;
  165.            FINSI;
  166.            PHIMOY = (PHIINF + PHICOUR) / 2.;
  167.            MMOY = IPOL PHIMOY LISS1 LISS2;
  168.            SIGMOY = MMOY / (4 * RAYM * RAYM * EPA *
  169.                (('COS'(AN / 4.)) - (0.5 * ('SIN'(AN / 2.)))));
  170.            DPHIP = (PHICOUR - PHIINF) - (CM0 * (MCOUR - MINF));
  171.            JP = JPP + ((SIGMOY * RAYM * (('COS'(AN / 2.))
  172.                                     + ('SIN'(AN / 4.)))) * DPHIP);
  173.  
  174.            JE = ((KF0 * MCOUR) ** 2) / E;
  175.            J = JE + JP;
  176.            TEST = ABS((J - J1C) / J1C);
  177.            LOG5 = (TEST &lt;EG 10.D-4);
  178.            'SI' LOG5;
  179.               'QUITTER' SB4;
  180.            'SINON';
  181.               'SI' (J > J1C);
  182.                   PHISUP = PHICOUR;
  183.               'SINON';
  184.                   PHIINF = PHICOUR;
  185.                   JPP = JP;
  186.               'FINSI';
  187.            'FINSI';
  188.       'FIN' SB4;
  189.    'REMP' LA1 I PHICOUR;
  190.    'REMP' LA2 I MCOUR;
  191.    JPP = JP;
  192.    'REMP' LISTJ I J;
  193. *---------------STOCKAGE DE LA COURBE SOLUTION-------------------
  194.  
  195.    K11 = 2;
  196.    PHIPREC = 'EXTR' LA1 (I - 1);
  197.    'REPE' BOC1 ;
  198.        U1 = 'EXTR' LISS1 K11;
  199.        U2 = 'EXTR' LISS2 K11;
  200.        'SI' ((U1 &lt;EG PHICOUR) ET (U1 > PHIPREC));
  201.              'REMP' LSOLPHI IN U1;
  202.              'REMP' LSOLM IN U2;
  203.              IN = IN + 1;
  204.              K11 = K11 + 1;
  205.        'SINON';
  206.           'SI' (U1 > PHICOUR);
  207.                'REMP' LSOLPHI IN PHICOUR;
  208.                'REMP' LSOLM IN MCOUR;
  209.                IN = IN + 1;
  210.                'QUITTER' BOC1;
  211.           'SINON';
  212.                K11 = K11 + 1;
  213.           'FINSI';
  214.        'FINSI';
  215.    'FIN' BOC1;
  216.  
  217.  
  218.    AN = AN + (AN / 200.);
  219.  'FIN' SB1;
  220.  
  221. *-------RESTRICTION DE LF1 ET LF2 A UNE DIMENSION CORRECTE--------------
  222.  
  223.   IN = IN - 1;
  224.   R = 2;
  225.   LF1 = PROG IN * 0.;
  226.   LF2 = PROG IN * 0.;
  227.   'REPE' S4 ;
  228.          A2 = 'EXTR' LSOLPHI R;
  229.          A3 = 'EXTR' LSOLM R;
  230.          'REMP' LF1 R A2;
  231.          'REMP' LF2 R A3;
  232.          R = (R + 1);
  233.          'SI' (R > IN);
  234.               'QUITTER' S4;
  235.          'FINSI';
  236.   'FIN' S4;
  237.  
  238.  
  239.  EVO6 = EVOL COUL 'MANU' LF1 LF2;
  240.  ETAB . 'ANGLE' = ANINI;
  241.  
  242.   'FINPROC' EVO6;
  243.  
  244.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales