Télécharger la plaquette Cast3M


fr en

Télécharger normalim.procedur

Retour à la liste

Numérotation des lignes : 

  1. * NORMALIM  PROCEDUR  BP208322  16/05/24    21:15:12     8932           
  2. *----------------------------------------------------------------------*
  3. *                                                                      *
  4. * PROCEDURE NORMALIM                                                   *
  5. *                                                                      *
  6. * NORMALISATION A 1 DE CHAQUE FONCTION M                               *
  7. *                                                                      *
  8. *----------------------------------------------------------------------*
  9. *                                                                      *
  10. * ENTREE                                                               *
  11. *                                                                      *
  12. * M      M/T CONTENANT N FONCTION DE MODULATIONS                       *
  13. *        TINI ET TFIN EGAUX POUR CHAQUE COURBE                         *
  14. *                                                                      *
  15. * DTIME  PAS DE TEMPS D'ANALYSE DE LA PREMIERE COURBE (POUR ONDELETTE) *
  16. *                                                                      *
  17. *                                                                      *
  18. *----------------------------------------------------------------------*
  19. *                                                                      *
  20. * SORTIE                                                               *
  21. *                                                                      *
  22. * MNORME M/T NORME                                                     *
  23. *                                                                      *
  24. * VALSPE (LISTREEL) MOYENNE DU SPECTRE DANS CHAQUE BANDE               *
  25. *                                                                      *
  26. *----------------------------------------------------------------------*
  27. 'DEBPROC' NORMALIM M*'EVOLUTION' DTIME/'FLOTTANT';
  28. *----------------------------------------------------------------------*
  29. 'SI' ('EXISTE' DTIME);
  30.   LONDEL=VRAI;
  31.   DDTIME=DTIME;
  32. 'SINON';
  33.   LONDEL=FAUX;
  34. 'FINSI'; 
  35. *
  36. 'SI' ('NON' LONDEL);
  37.   T1='EXTRAIRE' M 'ABSC' 1;
  38.   TI='EXTRAIRE' T1 1;
  39.   TF='EXTRAIRE' T1 ('DIMENSION' T1);
  40.   NI=1000;PAS=(TF-TI)/NI;
  41.   TT='PROG' TI 'PAS' PAS TF;
  42. 'FINSI';
  43. *
  45. *
  46. *----------------------------------------------------------------------*
  47. NCOURB='DIMENSION' M;
  48. ICOURB=0;
  49. 'REPETER' LABC NCOURB;
  50.   ICOURB=ICOURB+1;
  51.   MI='EXTRAIRE' M 'COURBE' ICOURB;
  52. *
  53.   'SI' LONDEL;
  54.     MIX='EXTRAIRE' MI 'ABSC' 1;
  55.     TI='EXTRAIRE' MIX 1;
  56.     TE=('EXTRAIRE' MIX ('DIMENSION' MIX)) - TI;
  57.     NPT='ENTIER' ((TE/DDTIME) + 1.E-5);
  58.     TTEST=TE-(NPT*DDTIME);
  59.     'SI' (('ABS' TTEST) '>' (DTIME*1.E-4));
  60.       'MESSAGE' 'Le pas de temps (DTIME) est incoherent avec la';
  61.       'MESSAGE' ' duree du signal ondelette (M) courbe' ICOURB;
  62.       'QUITTER' LABC;
  63.     'FINSI';
  64.     TT='PROG' TI 'PAS' DDTIME 'NPAS' NPT;
  65.   'FINSI';
  66. *
  67.   MMT='IPOL' TT ('EXTRAIRE' MI 'ABSC' 1) ('EXTRAIRE' MI 'ORDO' 1);
  68. *
  69.   'SI' LONDEL;
  70.     NORME=('LTL' MMT) * DDTIME;
  71.   'SINON';
  72.     MMT2=MMT**2;
  73.     MTT2='EVOL' 'MANU' TT MMT2;
  74.     NORME='EXTRAIRE' ('INTG' MTT2) 1;
  75.   'FINSI';
  76. *
  77.   NORME=NORME ** .5;
  78.   VALSPE='INSERER' VALSPE NORME ICOURB;
  79. *
  80.   'SI' (NORME EGA 0.); MINORME=MI;
  81.   'SINON';             MINORME=MI/NORME; 'FINSI';
  82.   'SI' (ICOURB EGA 1); MNORME=MINORME;
  83.   'SINON';             MNORME=MNORME 'ET' MINORME; 'FINSI';
  84. *
  85.   'SI' LONDEL; DDTIME=DDTIME/2; 'FINSI';
  86. 'FIN' LABC;
  87. *----------------------------------------------------------------------*
  88. 'FINPROC' VALSPE MNORME;
  89.  
  90.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales