Procédures | Cast3M

* DEADFONC  PROCEDUR  GOUNAND   26/01/12    21:15:02     12448          
************************************************************************
* NOM         : DEADFONC
* DESCRIPTION : La fonctionnelle de Huang à minimiser
*
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
*               mél : gounand@semt2.smts.cea.fr
**********************************************************************
* VERSION    : v1, 21/03/2006, version initiale
* HISTORIQUE : v1, 21/03/2006, création
* HISTORIQUE : 2018/01/22 : chgt nom composante hors diago G21 au lieu
*                           de G12
* HISTORIQUE : 2018/10/10 : NLINP au lieu de NLIN
* HISTORIQUE : 2025/12/29 : simplication donnees NLIN
* HISTORIQUE :
************************************************************************
* Prière de PRENDRE LE TEMPS de compléter les commentaires
* en cas de modification de ce sous-programme afin de faciliter
* la maintenance !
************************************************************************
*
*
'DEBPROC' DEADFONC ;
'ARGUMENT' _mt*'MAILLAGE' ;
'ARGUMENT' theta*'FLOTTANT' ;
'ARGUMENT' gamma*'FLOTTANT' ;
'ARGUMENT' met/'CHPOINT' ;
lmet = 'EXISTE' met ;
'ARGUMENT' motelem/'MOT' ;
lelem = 'EXIS' motelem ;
'SI' lelem ;
   'SI' ('NEG' motelem 'ELEM') ;
*1052 2
*Mot-cle incorrect "%M1:4". Voici la liste des valeurs admises : %M5:40
      'ERRE' 1052 'AVEC' motelem 'ELEM' ;
   'FINS' ;
'FINS' ;
*
gdisc = DEADUTIL 'TYPM' _mt ;
'SI' ('EGA' gdisc 'LINE') ;
   methgau = 'GAM1' ;
'SINON' ;
   methgau = 'GAM2' ;
'FINSI' ;
idim  = 'VALEUR' 'DIME' ;
vdim  = DEADUTIL 'DIMM' _mt ;
*
debloi = 'CHAINE' 'AHU' ;
ncmet  = '/' ('*' idim ('+' idim 1)) 2 ;
loi = 'CHAINE' debloi 'F' ;
*
*
* Calcul de la fonctionnelle
*
numop  = 1 ;
numvar = 1 ;
numder = vdim ;
numdat = 0 ;
numcof = 0 ;
*
   A = ININLIN numop numvar numdat numcof numder ;
   A . 'VAR' . 1 . 'VALEUR' = 1.D0 ;
*
   numvar = 1 ;
   numdat = '+' ncmet 2 ;
   numcof = 1 ;
   B = ININLIN numop numvar numdat numcof numder ;
   'SI' lelem ;
      B . 'VAR' . 1 . 'VALEUR' = 1.D0 ;
   'SINO' ;
      B . 'VAR' . 1 . 'NOMDDL' = 'SCAL' ;
      B . 'VAR' . 1 . 'DISC' = gdisc ;
   'FINS' ;
*
   idat = 0 ;
   'REPETER' idi idim ;
      nomdat = 'CHAINE' 'G' &idi &idi ;
*         'MESSAGE' ('CHAINE' 'nomdat=' nomdat) ;
      idat = '+' idat 1 ;
      B . 'DAT' . idat . 'NOMDDL' = nomdat ;
      B . 'DAT' . idat . 'DISC'   = gdisc ;
      'SI' lmet ;
*         B . 'DAT' . idat . 'VALEUR' = 'EXCO' nomdat met nomdat ;
         B . 'DAT' . idat . 'VALEUR' = met ;
      'SINON' ;
         B . 'DAT' . idat . 'VALEUR' = 1.D0 ;
      'FINSI' ;
   'FIN' idi ;
   'REPETER' idi idim ;
      nj = '-' idim &idi ;
*      'MESSAGE' ('CHAINE' 'nj=' nj) ;
      'SI' ('>EG' nj 1) ;
         'REPETER' jdi nj ;
* Mise en cohérence avec Castem
*            nomdat = 'CHAINE' 'G' &idi ('+' &idi &jdi) ;
            nomdat = 'CHAINE' 'G' ('+' &idi &jdi) &idi ;
*               'MESSAGE' ('CHAINE' 'nomdat=' nomdat) ;
            idat = '+' idat 1 ;
            B . 'DAT' . idat . 'NOMDDL' = nomdat ;
            B . 'DAT' . idat . 'DISC'   = gdisc ;
            'SI' lmet ;
*               B . 'DAT' . idat . 'VALEUR' = 'EXCO' nomdat met nomdat ;
               B . 'DAT' . idat . 'VALEUR' = met ;
            'SINON' ;
               B . 'DAT' . idat . 'VALEUR' = 0.D0 ;
            'FINSI' ;
         'FIN' jdi ;
      'FINSI' ;
   'FIN' idi ;
   lisdat = 'LECT' 1 'PAS' 1 'NPAS' ('-' numdat 1) ;
   idat = '+' idat 1 ;
   B . 'DAT' . idat . 'VALEUR' = theta ;
   idat = '+' idat 1 ;
   B . 'DAT' . idat . 'VALEUR' = gamma ;
*
   B . 'COF' . 1 . 'COMPOR' = loi ;
   B . 'COF' . 1 . 'LDAT'   = lisdat ;
*
   A . 1 . 1 . 0  = 0 ;
   B . 1 . 1 . 0  = 1 ;
*
'SI' lelem ;
   vfonc = NLIN gdisc _mt A B 'EREF' 'CHAM' methgau ;
'SINO' ;
   vfonc = NLIN gdisc _mt A B 'EREF' methgau ;
   vfonc = 'MAXIMUM' ('RESULT' vfonc) ;
'FINSI' ;
*
'RESPRO' vfonc ;
*
* End of procedure file DEADFONC
*
'FINPROC' ;