Procédures | Cast3M

* CALMU     PROCEDUR  MAGN      06/02/17    21:15:01     5314           
DEBPROC CALMU ;
'ARGU' T/'CHPOINT'
       TF/'FLOTTANT'
       TL/'LISTREEL' ;
*-------------------------------------------------*
* calcul de la viscosite dynamique                *
*           pour les incondensables en fonction   *
* de la temperature  (J/kg/K)                     *
*                                                 *
* Entree T en K                                   *
* Sortie Mu en Kg/m/s                             *
*                                                 *
* PS : le resultat est du meme type que l'entree  *
*-------------------------------------------------*
A0 = 0.1541D-6 ;
A1 = -17.856 ;
A2 = 1.703   ;
B0 = 0.5865D-6 ;
B1 = 27.183 ;
B2 = 1.630 ;
C0 = 0.7406D-6 ;
C1 = 48.16 ;
C2 = 1.610  ;
D0 = 1.791D-6 ;
D1 = 140.812  ;
D2 = 1.469   ;
E0 = 0.136D-6 ;
E1 = -59.30   ;
E2 = 1.810     ;
F0 = 0.573D-6 ;
F1 = 46.45    ;
F2 = 1.620     ;
G0 = 2.142D-6 ;
G1 = 890.0 ;
G2 = 1.500 ;
 
'SI' ( 'EXIST' T ) ;
    Muh2  =(((T ** A2 ) * A0 ) / ( T + A1 ))           ;
    Muhe  =(((T ** B2 ) * B0 ) / ( T + B1 ))           ;
    Muo2  =(((T ** C2 ) * C0 ) / ( T + C1 ))           ;
    Mun2  =(((T ** D2 ) * D0 ) / ( T + D1 ))           ;
    Muco2 =(((T ** E2 ) * E0 ) / ( T + E1 ))           ;
    Muco  =(((T ** F2 ) * F0 ) / ( T + F1 ))           ;
    Muvap =(((T ** G2 ) * G0 ) / ( T + G1 ))           ;
    Muair = (0.8*Mun2) + (0.2*Muo2) ;
    'RESPROC' Muh2 Muhe Muo2 Mun2 Muco2 Muco Muvap Muair ;
    'QUITTER' CALMU ;
'FINSI' ;
'SI' ( 'EXIST' TF) ;
    Muh2  =(((TF** A2 ) * A0 ) / ( TF+ A1 ))           ;
    Muhe  =(((TF** B2 ) * B0 ) / ( TF+ B1 ))           ;
    Muo2  =(((TF** C2 ) * C0 ) / ( TF+ C1 ))           ;
    Mun2  =(((TF** D2 ) * D0 ) / ( TF+ D1 ))           ;
    Muco2 =(((TF** E2 ) * E0 ) / ( TF+ E1 ))           ;
    Muco  =(((TF** F2 ) * F0 ) / ( TF+ F1 ))           ;
    Muvap =(((TF** G2 ) * G0 ) / ( TF+ G1 ))           ;
    Muair = (0.8*Mun2) + (0.2*Muo2) ;
    'RESPROC' Muh2 Muhe Muo2 Mun2 Muco2 Muco Muvap Muair ;
    'QUITTER' CALMU ;
'FINSI' ;
'SI' ( 'EXIST' TL) ;
    T00 = TL / TL ;
    A10 = A1 * T00 ;
    B10 = B1 * T00 ;
    C10 = C1 * T00 ;
    D10 = D1 * T00 ;
    E10 = E1 * T00 ;
    F10 = F1 * T00 ;
    G10 = G1 * T00 ;
 
    Muh2  =(((TL** A2) * A0) / ( TL+ A10))           ;
    Muhe  =(((TL** B2) * B0) / ( TL+ B10))           ;
    Muo2  =(((TL** C2) * C0) / ( TL+ C10))           ;
    Mun2  =(((TL** D2) * D0) / ( TL+ D10))           ;
    Muco2 =(((TL** E2) * E0) / ( TL+ E10))           ;
    Muco  =(((TL** F2) * F0) / ( TL+ F10))           ;
    Muvap =(((TL** G2) * G0) / ( TL+ G10))           ;
    Muair = (0.8*Mun2) + (0.2*Muo2) ;
    'RESPROC' Muh2 Muhe Muo2 Mun2 Muco2 Muco Muvap Muair ;
    'QUITTER' CALMU ;
 
'FINSI' ;
'ERRE' 5 ;
FINPROC                ;