Accueil | Cast3M

* fichier :  trkg.dgibi
************************************************************************
************************************************************************
*
*  Enceinte 2D Axisymetrique Cas de Torrance et Rockett
*
'OPTI' 'DIME' 2 'ELEM' 'CU20' ;
 'OPTI' 'MODE' 'AXIS' ;
 
 opti trac 'PSC' ;
 COMPLET= VRAI                                          ;
 COMPLET= FAUX                                          ;
*GRAPH  = VRAI                                          ;
 GRAPH  = FAUX                                          ;
 
 echl=2.e-1;
*echl=5.e-1;
*echl=1.e-1;
 'SI' COMPLET ;
  nbit=100    ;
  nbit=20     ;
  DT0 = 1.    ;
  ds1= 0.02*echl;
  ds2= 0.2*echl ;
  n1=5 ;
  n2=10;
  n3=20;
 'SINON'      ;
  nbit=100   ;
* nbit=2    ;
  DT0 = 40.;
  ds1= 0.02*echl;
  ds2= 0.2*echl ;
  n1=5 ;
  n2=10;
  n3=20;
 'FINSI'      ;
 
r0=0.1*echl ;
r1=1.*echl ;
rm=0.5*echl ;
hm=0.5*echl ;
h1=1.*echl ;
 
eps=1.e-2*echl ;
eps=1.e-4*echl ;
epsi=1.e-4*echl ;
 
p1=eps 0 ;
p11=r0 0 ;
p2=rm 0. ;
p3=r1 0 ;
p4=r1 hm;
p5=r1 h1 ;
 
 
breche = p1  'DROI' n1 p11;
bas= p11 'DROI' dini ds1 dfin ds2 p2 d dini ds2 dfin ds1  p3 ;
paroid=p3 'DROI' dini ds1 dfin ds2 p4 'DROI' dini ds2 dfin ds1 p5 ;
 
plaf=inve ( (breche et bas ) plus (0 h1));
axe =inve ( paroid moins ((r1-eps) 0)) ;
elim (breche et bas et paroid et plaf et axe) epsi ;
mt= 'DALLER' (breche 'ET' bas) paroid plaf axe ;
Si GRAPH ; trace mt ; Finsi ;
 
rxt = 'TABLE' ;
rxt.'VERSION'= 'V0'                                           ;
rxt.'vtf'=mt ;
rxt.'axe'   = axe ;
rxt.'epsi'= epsi ;
rxt.'pi'  = 0.5 0.5 ;
rxt.'DT0'  = DT0     ;
rxt.'DISCR'= 'QUAF';
rxt.'KPRE' = 'MSOMMET';
rxt.'TYPINV'=1 ;
rxt.'GRAPH'  = GRAPH ;
rxt.'MODTURB'='NUTURB'  ;
rxt.'NUT'    =1.e-7  ;
rxt.'CORTEMP'=FAUX ;
 
 rxt.'TF0'    =        20.0                         ;
 rxt.'PT0'    =        1.0e5                       ;
 
 rxt.'TIMP'              = table                              ;
 rxt.'TIMP'.'TIMP1'             = table                       ;
 rxt.'TIMP'.'TIMP1'.'MAILLAGE'  = breche                      ;
 rxt.'TIMP'.'TIMP1'.'t'         = prog   0.0 900000.0         ;
 rxt.'TIMP'.'TIMP1'.'TIMP'      = prog  21.     21.           ;
 rxt.'TIMP'.'TIMP1'.'ECHAN'     = 1.e2                        ;
 
 rxt.'TIMP'.'TIMP2'             = table                       ;
 rxt.'TIMP'.'TIMP2'.'MAILLAGE'  = (bas et paroid et plaf)     ;
 rxt.'TIMP'.'TIMP2'.'t'         = prog   0.0 900000.0         ;
 rxt.'TIMP'.'TIMP2'.'TIMP'      = prog  20.0  20.0            ;
 rxt.'TIMP'.'TIMP2'.'ECHAN'     = 1.e2                        ;
 
 
execrxt nbit rxt ;
 
 
$vtf=rxt.'GEO'.'$vtf' ;
vtf=doma $vtf maillage;
rho=rxt.'TIC'.'RHO' ;
tf =rxt.'TIC'.'TF' ;
un =rxt.'TIC'.'UN';
 
$axe=rxt.'GEO'.'$axe';
axe=doma $axe maillage ;
ixe=inve axe ;
evauz = evol chpo (exco un 'UY') ixe ;
evarh = evol chpo rho ixe ;
evatf = evol chpo tf  ixe ;
 
 
luz= (extr evauz 'ORDO' );
lrh= (extr evarh 'ORDO' );
ltf= (extr evatf 'ORDO' );
list luz ; list lrh ; list ltf ;
 
luzr= prog
*  3.07237E-42 -2.34123E-03  2.56887E-03  6.54417E-03  1.62324E-02
*  2.40888E-02  2.50937E-02  2.65036E-02  2.59309E-02  2.53052E-02
*  2.60378E-02  2.60663E-02  2.63601E-02  2.57449E-02  2.55996E-02
*  2.49561E-02  2.43348E-02  2.32284E-02  2.10423E-02  1.78512E-02
*  1.39740E-02  8.69525E-03  3.46774E-03  7.10408E-04 -5.08355E-43;
  1.51890E-42 -2.37360E-03  2.32262E-03  6.07648E-03  1.56239E-02
  2.33899E-02  2.47391E-02  2.65114E-02  2.61377E-02  2.59326E-02
  2.69223E-02  2.75933E-02  2.85105E-02  2.87585E-02  2.92365E-02
  2.90317E-02  2.83702E-02  2.68461E-02  2.42700E-02  2.02241E-02
  1.62119E-02  1.04393E-02  5.00558E-03  9.75119E-04  5.53846E-42 ;
 
lrhr=prog
*   1.1842       1.1845       1.1848       1.1852       1.1855
*   1.1859       1.1862       1.1865       1.1868       1.1870    
*   1.1872       1.1874       1.1875       1.1876       1.1877
*   1.1877       1.1878       1.1878       1.1878       1.1878    
*   1.1879       1.1879       1.1879       1.1880       1.1882;
   1.1842       1.1845       1.1848       1.1852       1.1855
   1.1859       1.1862       1.1865       1.1868       1.1870
   1.1872       1.1874       1.1875       1.1876       1.1876
   1.1877       1.1877       1.1877       1.1878       1.1878
   1.1878       1.1878       1.1879       1.1880       1.1882  ; 
 
ltfr=prog
*   20.994       20.905       20.829       20.740       20.651
*   20.565       20.482       20.404       20.337       20.275
*   20.223       20.177       20.142       20.115       20.095
*   20.082       20.072       20.065       20.058       20.054
*   20.050       20.045       20.036       20.020       20.001;
   20.994       20.906       20.831       20.742       20.655
   20.570       20.489       20.414       20.349       20.292
   20.244       20.202       20.171       20.148       20.132
   20.121       20.113       20.107       20.102       20.099
   20.095       20.091       20.078       20.048       20.003  ;
 
ERUZ=(SOMM (abs (luz - luzr)))*0.04 ;
MESS 'ERUZ=' ERUZ ;
Si (ERUZ '>' 1.e-3) ; erreur 5 ; Finsi ;
 
ERRH=(SOMM (abs (lrh - lrhr)))*0.04 ;
MESS 'ERRH=' ERRH ;
Si (ERRH '>' 1.e-3) ; erreur 5 ; Finsi ;
 
ERTF=(SOMM (abs (ltf - ltfr)))*0.04/20. ;
MESS 'ERTF=' ERTF ;
Si (ERTF '>' 1.e-3) ; erreur 5 ; Finsi ;
 
 
 
 
 
Si GRAPH ;
 
 dess evauz 'TITRE' 'Vitesse sur l axe';
 dess evarh 'TITRE' 'Densite melange sur l axe';
 dess evatf 'TITRE' 'Temperature sur l axe';
 
ung= vect un 1.  ux uy jaune;
trace ung vtf;
opti isov suli ;
trace rho vtf 'TITRE' ' Rho' ;
trace tf  vtf (prog 20. pas 0.001  20.02);
trace tf  vtf (prog 20. 20.0001 20.001 20.005 20.01 20.1) ;
*trace rh2 vtf 'TITRE' ' Rh2' ;
*trace rco2 vtf 'TITRE' ' Rco2' ;
*trace tf  vtf 'TITRE' ' Tf ' ;
Finsi ;
 
 FIN ;