Exemples de jeux de données Cast3M

Télécharger topoptim_13_Turbine_disk.dgibi
* fichier topoptim_13_Turbine_disk.dgibi
************************************************************************
************************************************************************
 
************************************************************************
** Topology optimization of a 2D axisymmetric structure, a turbine disk
** with von Mises stress constraint, subjected to centrifugal forces
** (i.e., penalized density-dependent loading), as proposed by Yan et al.
** 2023 and using, in the present case, the Coniglio et al. 2018 approach.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** V1.0 2025/12/05
************************************************************************
 
* Plot results
graph0 = FAUX ;
 
* Rotational speed [rad/s]
omega0 = 5000.0 * 2.0 * pi / 60 ;
* Pressure
press0 = 100.0e6 ;
 
* General options
OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
 
* Number of elements
nelr0 = 154 ;
nelz0 = 30 ;
 
* Dimensions
r0 = 0.083 ;
l0 = 0.237 - r0 ;
h0 =  0.030 ;
ha0 = 0.012 ;
 
* Mesh
p0 = r0 0.0 ;
p1 = r0 h0 ;
ln1 = DROI nelz0 p1 p0 ;
msh0 = ln1 TRAN nelr0 (l0 0.0) ;
ln2 = msh0 COTE 2 ;
ln3 = msh0 COTE 3 ;
tmp0 = ln3 POIN 'DROI' (0.0 0.0) (1.0 0.0) (ha0 * 0.99) ;
msh1 = (msh0 ELEM 'APPU' 'LARG' ln1) ET
       (msh0 ELEM 'APPU' 'LARG' tmp0) ;
 
* Model and material
mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
mat0 = MATE mod0 'YOUN' 192.0e9 'NU' 0.3 'RHO' 8.24e3 ;
 
* Boundary conditions
bc0 = BLOQ 'UZ' ln2 ;
 
* Constant loading: peripheral pressure
tmp0 = ln3 ELEM 'APPU' 'STRI' msh1 ;
load0 = PRES 'MASS' mod0 (-1.0 * press0) tmp0 ;
 
* Penalized density-dependent loading: centrifugal forces
DEBP TOPOUPDT tab0*'TABLE' ;
 
*   Input data
    Wtab   = tab0.'WTABLE' ;
    modMA  = Wtab.'MECANIQUE'.'MODELE_A' ;
    ZmatMA = Wtab.'MECANIQUE'.'CARACTERISTIQUES_Z_A' ;
 
*   Centrifugal force field
    Forc0 = (omega0**2) * (MASS modMA ZmatMA) * (CHAN 'COMP' 'UR' (msh0 COOR 1)) ;
*   Add the constant loading
    Forc0 = Forc0 ET load0 ;
 
*   Output
    tab0.'RESOLUTION_LINEAIRE'.'CHARGEMENT' = Forc0 ;
 
*   If it is the first cycles
    SI (EGA Wtab.'CYCLE' 1) ;
 
*       Model and material of the design zone (D)
        modMD = Wtab.'MECANIQUE'.'MODELE_D' ;
        matMD = Wtab.'MECANIQUE'.'CARACTERISTIQUES_D' ;
 
*       Elementwise field of the R coordinate
*       expressed on D at the element mass integration points
        r = CHAN 'MASSE' (modMD COOR 1) modMD ;
 
*       Elementwise field of the mass density
*       expressed on D at the element mass integration points
        rho = CHAN 'TYPE' (CHAN 'MASSE' (EXCO 'RHO' matMD) modMD) 'SCALAIRE' ;
 
*       Volume-normalized elementwise field of the derivative of
*       the centrifugal force with respect to the physical densities
*       expressed on D at the element mass integration points
        NdFdY = EXCO 'SCAL' ((omega0**2) * (r * rho)) 'FR' ;
 
*       Output
        tab0.'RESOLUTION_LINEAIRE'.'SENSIBILITE_NORMALISEE_CHARGEMENT' = NdFdY ;
 
    FINS ;
 
FINP ;
 
* Finite element model table
mdl0 = TABL ;
mdl0.'MODELE'                = mod0 ;
mdl0.'CARACTERISTIQUES'      = mat0 ;
mdl0.'BLOCAGES_MECANIQUES'   = bc0 ;
 
* Optimization table
tab0 = TABL ;
tab0.'TRAC'                  = graph0 ;
tab0.'RESOLUTION_LINEAIRE'   = mdl0 ;
tab0.'PROCEDURE_TOPOUPDT'    = VRAI ;
tab0.'ZONE_FIGEE'            = msh1 ;
 
tab0.'SIGMA_VM_LIMITATION'   = MOT 'CONIGLIO' ;
tab0.'SIGMA_VM_LIMITE'       = 1.0e9 ;
 
tab0.'OPTIMISEUR'            = MOT 'MMA' ;
tab0.'FILTRE'                = MOT 'CHAPEAU' ;
tab0.'FILTRE_CHAPEAU_RAYON'  = 3.5 * (l0 / nelr0) ;
*tab0.'FILTRE'                = MOT 'EDP' ;
*tab0.'FILTRE_EDP_RAYON'      = 3.5 * (l0 / nelr0) ;
tab0.'FILTRER'               = MOT 'DENSITE' ;
 
tab0.'SEUIL_ELEMENTS_ACTIFS' = 0.0 ;
tab0.'RAPPORT_RAIDEURS_MECANIQUES' = 1.0e-8 ;
tab0.'X_CHANGE_SEUIL'        = 0.01 ;
tab0.'CONVERGENCE_CRITERE'   = 0.001 ;
tab0.'MAX_CYCLES'            = 150 ;
 
tab0.'MES_SAUVEGARDES'       = TABL ;
tab0.'MES_SAUVEGARDES'.'RESOLUTION' = VRAI ;
 
* Optimization
TOPOPTIM tab0 ;
 
* Plot final topology (physical density)
* and final von Mises stress
topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
modA0    = REDU mod0 topomsh0 ;
topoA0   = REDU (tab0.'TOPOLOGIE'.(tab0.'CYCLE')) modA0 ;
sig0     = tab0.'RESOLUTION'.(tab0.'CYCLE').'CONTRAINTES' ;
vnmA0    = VMIS modA0 sig0 (REDU mat0 modA0) ;
SI graph0 ;
    TRAC topoA0 modA0
         (PROG 0.0 'PAS' (1.0 / 56.0) 1.0)
         'TITR' 'Topologie finale' ;
    TRAC vnmA0 modA0
         'TITR' 'Contraintes de von Mises finales' ;
FINS ;
 
* Plot output evolutions
SI graph0 ;
    REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
        evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
        DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
             'TITR' (CHAI 'Evolution de' ' ' evoname0
                          ' au cours des cycles d''optimisation') ;
    FIN loop0 ;
FINS ;
 
FINS ;
 
FIN ;