Exemples de jeux de données Cast3M

* fichier topoptim_01.dgibi
************************************************************************
************************************************************************
 
************************************************************************
** Topology optimization of a simple 2D structure subjected to a
** mechanical loading.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
************************************************************************
 
graph0 = FAUX ;
 
* General options
OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' QUA4 ;
 
* Mesh
nelx0 = 60 ;
nely0 = 20 ;
p0 = 0.0 0.0 ;
p1 = 0.0 (FLOT nely0) ;
p2 = (FLOT nelx0) 0.0 ;
lgn0 = DROI nely0 p1 p0 ;
msh0 = TRAN lgn0 nelx0 p2 ;
p2 = msh0 POIN 'PROC' p2 ;
 
* Model and material
mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
 
* Boundary conditions and loading
bc0 = (BLOQ 'UX' lgn0) ET (BLOQ 'UY' p2) ;
load0 = FORC (0.0 -1.0) p1 ;
 
* Finite element model table
mdl0 = TABL ;
mdl0.'MODELE'              = mod0 ;
mdl0.'CARACTERISTIQUES'    = mat0 ;
mdl0.'BLOCAGES_MECANIQUES' = bc0 ;
mdl0.'CHARGEMENT'          = load0 ;
 
* Optimization table
tab0 = TABL ;
tab0.'RESOLUTION_LINEAIRE' = mdl0 ;
tab0.'FRACTION_VOLUME'     = 0.5 ;
tab0.'TRAC'                = graph0 ;
 
* Optimization
TOPOPTIM tab0 ;
 
* Plot to screen
topo0    = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
SI graph0 ;
    TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
         (PROG 0.0 'PAS' (1.0 / 56.0) 1.0) ;
FINS ;
 
FIN ;