Télécharger la plaquette Cast3M


fr en

Télécharger steinb.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  steinb.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. **************************************************
  5. *                                                *  
  6. *  TEST DE VALIDATION D'UNE LOI DE COMPORTEMENT  *  
  7. *  --------------------------------------------  * 
  8. *              DE MATERIAU                       * 
  9. *              -----------                       *   
  10. *                                                *  
  11. *  LOI DE COMPORTEMENT DE:                       * 
  12. *   STEINBERG-COCHRAN-GUINAN                     * 
  13. *                                                *  
  14. *  MAILLAGE:                                     *  
  15. *   UNE BARRE DE SECTION CARREE                  * 
  16. *   LONGUEUR L=.5 M                              *  
  17. *   LARGEUR  l=.01 M                             * 
  18. *                                                *  
  19. *  CHARGEMENT:                                   * 
  20. *   ESSAI DE TRACTION                            * 
  21. *   DEPLACEMENTS IMPOSES                         * 
  22. *                                                * 
  23. **************************************************  
  24. * 
  25. * 
  26. *  
  27. opti echo 0 dime 3 elem cub8 ;
  28. *  
  29. *  
  30. *  Maillage 
  31. *  
  32. l1 = .5 ; 
  33. l2 = .01 ; 
  34. l3 = .01 ;  
  35. n1 = 50 ; 
  36. n2 = 1 ; 
  37. n3 = 1 ; 
  38. p1 = 0. 0. 0. ; 
  39. p2 = l1 0. 0. ; 
  40. p3 = l1 l2 0. ; 
  41. p4 = 0. l2 0. ; 
  42. p5 = 0. 0. l3 ; 
  43. p6 = l1 0. l3 ; 
  44. p7 = l1 l2 l3 ; 
  45. p8 = 0. l2 l3 ; 
  46. d1 = d p1 n3 p5 ; 
  47. d2 = d p5 n2 p8 ; 
  48. d3 = d p8 n3 p4 ; 
  49. d4 = d p4 n2 p1 ; 
  50. sur1 = 'DALL' d1 d2 d3 d4 ; 
  51. d5 = d p2 n3 p6 ; 
  52. d6 = d p6 n2 p7 ;  
  53. d7 = d p7 n3 p3 ; 
  54. d8 = d p3 n2 p2 ; 
  55. sur2 = 'DALL' d5 d6 d7 d8 ; 
  56. vol1 = sur1 'VOLU' n1 sur2 ;    
  57. *  
  58. *    Modele de calcul 
  59. * 
  60. INCO_GT = 'EVOL' 'MANU' 'T' ( 'PROG' -273. 27. 1027. ) 
  61.           'GT' ( 'PROG' 5133.E6 0. -17110.E6 ) ;   
  62. mod1 = 'MODE' vol1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 
  63.        'PLASTIQUE' 'STEINBERG' ; 
  64. mat1 = 'MATE' mod1 'YOUN' 2.1E11 'NU' 0.3 
  65.        'RHO' 7.8E3 'ALPHA' 0. 'TALP' 0. 'TREF' 0. 'SIGY' 410.E6  
  66.        'BETA' 125 'N' .1 'EPSI' 0.  
  67.        'GP' 1.79 'GT' INCO_GT 'YMAX' 680.E6 'TMO' 1220. 
  68.        'MU' 1.95 ;
  69. *  
  70. *  Modele thermique  
  71. *  
  72. mod2 = 'MODE' vol1 'THERMIQUE' 'ISOTROPE' ; 
  73. mat2 = 'MATE' mod2 'K' 50. 'C' 140. 'RHO' 7.8E3 ;  
  74. *  
  75. mod3 = 'MODE' ( 'ENVE' vol1 ) thermique 'CONVECTION' 
  76.         ; 
  77. mat3 = 'MATE' mod3 'H' 750. ; 
  78. *  
  79. *  Modele total 
  80. *  
  81. mod0 = mod1 'ET' mod2 'ET' mod3 ; 
  82. mat0 = mat1 'ET' mat2 'ET' mat3 ;  
  83. *
  84. *    Conditions aux limites 
  85. *  
  86. cl1 = 'BLOQ' sur1 'UX' ; 
  87. cl2 = 'BLOQ' sur2 'UX' ; 
  88. cl3 = 'BLOQ' p1 'UX' 'UY' 'UZ' ;  
  89. cl4 = 'BLOQ' p5 'UX' 'UY' ; 
  90. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 ;  
  91. * 
  92. *  Chargement  
  93. *   
  94. dep1 = 'DEPI' cl2 .1 ; 
  95. tex0 = 'MANU' 'CHPO' ( 'ENVE' vol1 ) 1 'T' 500. ;  
  96. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 1000. ) y ( 'PROG' 0. 1. ) ; 
  97. cha1 = 'CHAR' 'DIMP' dep1 ev0 ;  
  98. cha2 = 'CHAR' 'TECO' tex0 ev0 ; 
  99. cha0 = cha1 'ET' cha2 ;  
  100. * 
  101. *  Temps du calcul  
  102. *  
  103. dt0 = 10. ; 
  104. tfin0 = 100. ;  
  105. *   
  106. *   
  107. *  Resolution par PASAPAS  
  108. *---------------------------------------
  109. *    
  110. ta1 = 'TABLE' ; 
  111. ta1 .'MODELE' = mod0 ; 
  112. ta1 .'CARACTERISTIQUES' = mat0 ; 
  113. ta1 .'BLOCAGES_MECANIQUES' = cl0 ; 
  114. ta1 .'CHARGEMENT' = cha0 ; 
  115. ta1 .'PROCEDURE_THERMIQUE' = LINEAIRE ; 
  116. ta1 .'TEMPS_CALCULES' = 'PROG' 0. 'PAS' dt0 tfin0 ; 
  117. *  
  118. TMASAU=table;
  119. ta1 . 'MES_SAUVEGARDES'=TMASAU;
  120. TMASAU .'DEFTO'=VRAI;
  121. TMASAU .'DEFIN'=VRAI;
  122. ta1 .'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  123. PASAPAS ta1 ; 
  124. *  
  125. *  
  126. *  Post-traitement 
  127. *-----------------------------------------
  128. * 
  129. *  Quelques donnees du calcul 
  130. *  
  131. youn1 = 'EXTR' ( 'EXCO' mat0 'YOUN' 'SCAL' ) 'SCAL' 1 1 1 ; 
  132. xnu0 = 'EXTR' ( 'EXCO' mat0 'NU' 'SCAL' ) 'SCAL' 1 1 1 ;
  133. sig0 = 'EXTR' ( 'EXCO' mat0 'SIGY' 'SCAL' ) 'SCAL' 1 1 1 ; 
  134. m0 = 'EXTR' ( 'EXCO' mat0 'N' 'SCAL' ) 'SCAL' 1 1 1 ; 
  135. beta0 = 'EXTR' ( 'EXCO' mat0 'BETA' 'SCAL' ) 'SCAL' 1 1 1 ; 
  136. G0 = youn1 / ( 2. * ( 1. + xnu0 ) ) ; 
  137. GP0 = 'EXTR' ( 'EXCO' mat0 'GP' 'SCAL' ) 'SCAL' 1 1 1 ;  
  138. eps_el0 = sig0 / youn1 ;
  139. *  
  140. *  Post-traitement 
  141. *-----------------------------------------
  142. * 
  143. sigx1 = 'PROG' 0. ; 
  144. sigx2 = 'PROG' 0. ; 
  145. depx1 = 'PROG' 0. ;  
  146. depx2 = 'PROG' 0. ; 
  147. sig_1 = 'PROG' 0. ; 
  148. def_1 = 'PROG' 0. ;   
  149. eps_th1 = 'PROG' 0. ; 
  150. con_th1 = 'PROG' 0. ; 
  151. err_e1 = 'PROG' 0. ; 
  152. err_s1 = 'PROG' 0. ; 
  153. tp_max1 = 'PROG' 0. ; 
  154. tp_min1 = 'PROG' 0. ;  
  155. A1 = 2. * ( 1. + xnu0 ) ; 
  156. B1 = A1 / ( 3. * ( 1. - ( 2. * xnu0 ) ) ) ; 
  157. dim0 = 'DIME' ta1 .'TEMPS' - 1 ; 
  158. mod0 = ta1 .'MODELE' ; 
  159. 'REPETER' bloc1 dim0 ; 
  160.   i1 = &bloc1 ; 
  161.   mat0 = ta1 .'CARACTERISTIQUES' ;
  162.   depl0 = ta1 .'DEPLACEMENTS'.i1 ; 
  163.   sigm0 = ta1 .'CONTRAINTES'.i1 ; 
  164.   depeq0 = ta1 .'VARIABLES_INTERNES'.i1 ;  
  165.   def0 = ta1 .'DEFORMATIONS_INELASTIQUES'.i1 ;  
  166.   cht0 = ta1 .'TEMPERATURES'.i1 ; 
  167.   GT0 = 'EXCO' ( 'VARI' 'NUAG' mod1 mat1 cht0 ) 'GT' 'SCAL' ;  
  168.   GT0 = 'EXTR' GT0 'SCAL' 1 1 1 ;  
  169.   t1 = 'EXTR' cht0 'T' ( 'NOEUD' 1 ) ; 
  170. *  'MESS' ' Temperature au temps ' i1 ' = ' t1 ; 
  171.   tp_max0 = 'MAXI' cht0 ; 
  172.   tp_min0 = 'MINI' cht0 ;  
  173.   tp_max1 = tp_max1 'ET' ( 'PROG' tp_max0 ) ; 
  174.   tp_min1 = tp_min1 'ET' ( 'PROG' tp_min0 ) ;   
  175.   sigx0 = 'MAXI' ( 'VMIS' mod1 sigm0 ) ;     
  176.   sigx00 = 'MINI' ( 'VMIS' mod1 sigm0 ) ; 
  177.   depx0 = 'MAXI' ( 'EXCO' depeq0 'EPSE' 'SCAL' ) ;   
  178.   depx00 = 'MINI'( 'EXCO' depeq0 'EPSE' 'SCAL' ) ;  
  179.   sig_00 = 'EXCO' sigm0 'SMXX' 'SCAL' ; 
  180.   sig_0 = 'EXTR' sig_00 'SCAL' 1 1 1 ;    
  181.   def_00 = 'EXCO' def0 'EIXX' 'SCAL' ; 
  182.   def_0 = 'EXTR' def_00 'SCAL' 1 1 1 ; 
  183.   sigx1 = sigx1 'ET' ( 'PROG' sigx0 ) ; 
  184.   sigx2 = sigx2 'ET' ( 'PROG' sigx00 ) ;  
  185.   depx1 = depx1 'ET' ( 'PROG' depx0 ) ;  
  186.   depx2 = depx2 'ET' ( 'PROG' depx00 ) ; 
  187.   sig_1 = sig_1 'ET' ( 'PROG' sig_0 ) ; 
  188.   def_1 = def_1 'ET' ( 'PROG' def_0 ) ;  
  189. *  
  190. *  Eta  
  191. *  
  192.   eps00 = 'EPSI' mod1 depl0 ; 
  193.   epsx = 'EXTR' ( 'EXCO' eps00 'EPXX' 'SCAL' ) 'SCAL' 1 1 1 ; 
  194.   epsy = 'EXTR' ( 'EXCO' eps00 'EPYY' 'SCAL' ) 'SCAL' 1 1 1 ; 
  195.   epsz = 'EXTR' ( 'EXCO' eps00 'EPZZ' 'SCAL' ) 'SCAL' 1 1 1 ; 
  196.   treps0 = epsx + epsy + epsz ; 
  197.   eta = 1. / ( 1. + treps0 ) ; 
  198. * 
  199. *  Courbe theorique 
  200. * 
  201. eps0 = epsx ;  
  202. sig1 = sig0 * ( 1. + ( ( GP0 / G0 ) * ( -1. * sig_0 / 3. ) ) + 
  203. ( GT0 / G0 ) ) ; 
  204. pente0 = GP0 / ( 3. * ( eta ** ( 1. / 3. ) ) ) ;  
  205. pente1 = G0 + GT0 ; 
  206. *
  207. 'SI' ( sigx0 > sig1 ) ; 
  208. x0 = 0. ; 
  209. x2 = x0 ; 
  210. tr1 = treps0 - ( A1 * ( eps0 - x2 ) / ( 3. * B1 ) ) ;
  211. tr1 = tr1 / 3. ;
  212. y2 = ( sig0 * ( ( 1 + ( beta0 * ( x2 - tr1 ) ) ) ** m0 ) ) ; 
  213. y2 = y2 + ( A1 * G0 * x2 ) ;  
  214. y2 = y2 - ( A1 * G0 * eps0 )  ; 
  215. *
  216. x1 = eps0 ; 
  217. x2 = x1 ;   
  218. tr1 = treps0 - ( A1 * ( eps0 - x2 ) / ( 3. * B1 ) ) ;
  219. tr1 = tr1 / 3. ;
  220. y2 = ( sig0 * ( ( 1 + ( beta0 * ( x2 - tr1 ) ) ) ** m0 ) ) ; 
  221. y2 = y2 + ( A1 * G0 * x2 ) ; 
  222. y2 = y2 - ( A1 * G0 * eps0 ) ; 
  223. *  
  224. 'REPETER' bloc2 ; 
  225. *  
  226. x2 = ( x0 + x1 ) / 2. ; 
  227. tr1 = treps0 - ( A1 * ( eps0 - x2 ) / ( 3. * B1 ) ) ;
  228. tr1 = tr1 / 3. ;
  229. y2 = ( sig0 * ( ( 1 + ( beta0 * ( x2 - tr1 ) ) ) ** m0 ) ) ; 
  230. y2 = y2 + ( A1 * G0 * x2 ) ; 
  231. y2 = y2 - ( A1 * G0 * eps0 ) ;  
  232. *  
  233. 'SI' ( y2 > 1.E-4 ) ; 
  234.   x1 = x2 ; 
  235. 'SINON' ; 
  236.   'SI' ( y2 <  -1.E-4 ) ; 
  237.      x0 = x2 ; 
  238.   'SINON' ; 
  239.      eps_th0 = x2 ; 
  240.      con_th0 = ( A1 * pente1 * ( eps0 - x2 ) ) ; 
  241.      con_th0 = con_th0 / ( 1. + ( A1 * pente0 * ( eps0 - x2 ) ) ) ;  
  242.     'QUITTER' bloc2 ;  
  243.   'FINSI' ; 
  244. 'FINSI' ; 
  245. *  
  246. 'FIN' bloc2 ;
  247. *  
  248. 'SINON' ; 
  249. eps_th0 = 0. ; 
  250. con_th0 = ( A1 * pente1 * eps0 ) ;
  251. con_th0 = con_th0 / ( 1. + ( A1 * pente0 * eps0 ) ) ;  
  252. 'FINSI' ; 
  253. *    
  254. *  'MESS' ' Fin du calcul de restitution pour le pas' ta1 .'TEMPS'.i1 ;  
  255.   eps_th1 = eps_th1 'ET' ( 'PROG' eps_th0 ) ; 
  256.   con_th1 = con_th1 'ET' ( 'PROG' con_th0 ) ;   
  257.   max0 = ( 'ABS' ( con_th0 - sig_0 ) + con_th0 + sig_0 ) ; 
  258.   max0 = 0.5 * max0 ; 
  259.   max1 = ( 'ABS' ( eps_th0 - def_0 ) + eps_th0 + def_0 ) ; 
  260.   max1 = 0.5 * max1 ;  
  261.   'SI' ( ( 'ABS' max0 ) > 1.E-6 ) ; 
  262.      err_s0 = ( 'ABS' ( con_th0 - sig_0 ) ) / max0 ;  
  263.      err_s0 = err_s0 * 100. ;  
  264.   'SINON' ;  
  265.      err_s0 = 0. ; 
  266.   'FINSI' ; 
  267.   'SI' ( ( 'ABS' max1 ) > ( 1.E-1 * eps_el0 ) ) ; 
  268.      err_e0 = ( 'ABS' ( eps_th0 - def_0 ) ) / max1 ;  
  269.      err_e0 = err_e0 * 100. ;  
  270.   'SINON' ;  
  271.      err_e0 = 0. ; 
  272.   'FINSI' ; 
  273.   'SI' ( ( err_e0 '>' 2.E-2 ) 'OU' ( err_s0 '>' 2.E-2 ) ) ; 
  274.       'ERRE' 5 ; 
  275.   'FINSI' ; 
  276.   err_s1 = err_s1 'ET' ( 'PROG' err_s0 ) ; 
  277.   err_e1 = err_e1 'ET' ( 'PROG' err_e0 ) ;  
  278. *  
  279. *'MESS' ' Deformation plastique theorique =' eps_th0 ; 
  280. *'MESS' ' Deformation plastique calculee  =' def_0 ;  
  281. * 
  282. *   
  283. 'FIN' bloc1 ; 
  284. *  
  285. *  Trace  
  286. *  
  287. trac1 = 'EVOL' 'ROUG' 'MANU' 'epsp' depx1 'sigm' sigx1 ; 
  288. *'DESSIN' trac1 'TITR' 'Contraintes - Deformation plastique' ; 
  289. trac2 = 'EVOL' 'ROUG' 'MANU' 'epsp' depx2 'sigm' sigx2 ;  
  290. TAB = 'TABLE' ; 
  291. TAB.1 = 'MARQ CROI ' ;
  292. TAB.2 = 'MARQ PLUS ' ;
  293. TAB.'TITRE' = 'TABLE' ;
  294. TAB.'TITRE'. 1 = MOT 'MAXI' ;
  295. TAB.'TITRE'. 2 = MOT 'MINI' ;
  296. *'DESSIN' ( trac1 'ET' trac2 )
  297. *'TITR' 'Comparaison mini - maxi de la contrainte equivalente '
  298. *'LEGE' TAB ;
  299. trac3 = 'EVOL' 'ROUG' 'MANU' 'def_pl_xx' def_1 'tp_max' tp_max1 ; 
  300. trac31 = 'EVOL' 'ROUG' 'MANU' 'def_pl_xx' def_1 'tp_max' tp_min1 ;  
  301. TAB = 'TABLE' ;
  302. TAB.1 = 'MARQ CROI ' ;
  303. TAB.2 = 'MARQ PLUS ' ;
  304. TAB.'TITRE' = 'TABLE' ;
  305. TAB.'TITRE'. 1 = MOT 'MAXI' ;
  306. TAB.'TITRE'. 2 = MOT 'MINI' ;
  307. *'DESSIN' ( trac3 'ET' trac31 )
  308. *'TITR' 'Comparaison mini - maxi de la temperature '
  309. *'LEGE' TAB ;
  310. trac4 = 'EVOL' 'ROUG' 'MANU' 'def_pl_xx' def_1 'Sig_xx' sig_1 ;  
  311. trac5 = 'EVOL' 'ROUG' 'MANU' 'eps_pl' eps_th1 'Sig_xx' con_th1 ; 
  312. TAB= 'TABLE' ; 
  313. TAB.1 = 'MARQ CROI ' ;
  314. TAB.2 = 'MARQ PLUS ' ;
  315. TAB.'TITRE' = 'TABLE' ;
  316. TAB.'TITRE'. 1 = MOT 'Calcul' ;
  317. TAB.'TITRE'. 2 = MOT 'Theorie' ;
  318. *'DESSIN' ( trac4 'ET' trac5 )
  319. *'TITR' ' Courbe theorique et calculee'
  320. *'LEGE' TAB ;
  321. trac6 = 'EVOL' 'ROUG' 'MANU' 'epsp' def_1 'erreur %' err_s1 ; 
  322. trac7 = 'EVOL' 'ROUG' 'MANU' 'epsp' def_1 'erreur %' err_e1 ; 
  323. TAB = 'TABLE' ; 
  324. TAB.1 = 'MARQ PLUS ' ;
  325. TAB.2 = 'MARQ CROI ' ;
  326. TAB.'TITRE' = 'TABLE' ;
  327. TAB.'TITRE'. 1 = MOT 'CONTRAINTES' ;
  328. TAB.'TITRE'. 2 = MOT 'DEFORMATIONS' ;
  329. *'DESSIN' ( trac6 'ET' trac7 )
  330. *'TITR' 'Erreur sur les contraintes et la deformation plastiques '
  331. *'LEGE' TAB ;
  332. *  
  333. *'MESS' ' deformation plastique theorique ' eps_th0 ; 
  334. *'MESS' ' deformation plastique calculee  ' def_0 ; 
  335. *'MESS' ' contrainte theorique            ' con_th0 ; 
  336. *'MESS' ' contrainte calculee             ' sig_0 ;  
  337. *'MESS' ' deformation totale finale       ' eps0 ; 
  338. *  
  339. *    
  340. 'FIN' ;
  341.  
  342.  
  343.  
  344.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales