Télécharger la plaquette Cast3M


fr en

Télécharger sphere.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  sphere.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *==================================================================*
  5. *                                                                  *                                                                  *
  6. *              Sphere sous pression interne                        *
  7. *                                                                  *
  8. *                                                                  *
  9. *   R0 rayon interne aleatoire       LogNormale(50  , 2.5)         *
  10. *   R1 rayon externe aleatoire       LogNormale(100 , 5  )         *
  11. *   P0 pression interne aleatoire    LogNormale(130 , 8  )         *
  12. *   Fa limite d'ecoulement           LogNormale(300 , 20 )         *
  13. *                                                                  *
  14. *                                                                  *
  15. *                                                                  *
  16. *  BUT = Calcul de la probabilite de defaillance Pf                *
  17. *                                                                  *
  18. *         Pf = Probabilite(VonMises > Limite ecoulement)           *
  19. *                                                                  *
  20. *  Les resultats sont compares avec FORM, SORM                     *
  21. *                et surface de reponses                            *
  22. *                                                                  *
  23. *                                                                  *
  24. *==================================================================*
  25. OPTI ECHO 0;
  26. *                                                                               
  27. GRAPH = 'N';                                                                    
  28. *                                                                               
  30. OPTI ELEM QUA8;
  31. OPTI MODE AXIS;
  32. * Finesse angulaire du maillage 
  33. *
  34. NA = 20;
  35. * Finesse radiale du maillage 
  36. *
  37. NR = 10;
  38. *
  39. *==================================================================*
  40. *             Calcul des points d integration                      *
  41. *==================================================================*
  42. *
  43. NpR0 = 3;
  44. NpR1 = 3;
  45. NpP0 = 3;
  46. TabR0 = QUADRATU 'LOGN' 50. 2.5 NpR0;
  47. TabR1 = QUADRATU 'LOGN' 100. 5. NpR1;
  48. TabP0 = QUADRATU 'LOGN' 130. 8. NpP0;
  49. *
  50. *
  51. *==================================================================*
  52. *             Definition de la table globale                       *
  53. *==================================================================*
  54. *
  55. TabGLO = TABLE;
  56. ITEM = 0 ;
  57. REPE BcR0 NpR0;
  58.  REPE BcR1 NpR1;
  59.   REPE BcP0 NpP0;
  60.    ITEM = ITEM + 1 ;
  61.    TabGLO .ITEM = TABLE;
  62.    TabGLO .ITEM. 'POIDS' = 
  63.        TabR0 .&BcR0. 'POIDS' * 
  64.        TabR1 .&BcR1. 'POIDS' * 
  65.        TabP0 .&BcP0. 'POIDS';
  66.    TabGLO .ITEM. 'R0' = TabR0 .&BcR0. 'POINT';
  67.    TabGLO .ITEM. 'R1' = TabR1 .&BcR1. 'POINT';
  68.    TabGLO .ITEM. 'P0' = TabP0 .&BcP0. 'POINT';
  69.   FIN BcP0;
  70.  FIN BcR1;
  71. FIN BcR0;
  72. *
  73. *
  74. *==================================================================*
  75. *             Procedure de calcul du Von Mises                     *
  76. *==================================================================*
  77. DEBPROC CalVM R0*FLOTTANT R1*FLOTTANT P0*FLOTTANT;
  78. P1 = R0 0.;
  79. P2 = R1 0.;
  80. Li = P1 DROI NR P2;
  81. Su = Li ROTA NA 90. (0. 0.);
  82. Lip = COTE 4 Su;
  83. MO = MODEL SU MECANIQUE ELASTIQUE;
  84. MA = MATE MO YOUNG 100000. NU 0.3;
  85. RI = RIGI MO MA;
  86. BL = BLOQ UZ Li;
  87. FPr = PRESS MASSIF MO Lip P0;
  88. Dep = RESO (RI ET BL) FPr;
  89. SS = SIGMA Dep MO MA;
  90. SE = CHAN NOEUD MO SS;
  91. VM = VMIS SE MO;
  92. SMax = MAXI VM;
  93. FINPROC Smax;
  94. *
  95. *
  96. *
  97. *
  98. *==================================================================*
  99. *   CALCUL AUX POINT D INTEGRATION + MOMENTS STATISTIQUES          *
  100. *==================================================================*
  101. N = DIME TabGLO;
  102. TabRES = TABLE;
  103. ITEM = 0;
  104. REPE BOUC N;
  105.   TabRES .&BOUC = TABLE;
  106.   TabRES .&BOUC. POIDS = TabGLO .&BOUC. POIDS;
  107.   TabRES .&BOUC. POINT = 
  108.     CalVM TabGLO .&BOUC. R0 TabGLO .&BOUC. R1 TabGLO .&BOUC. P0;  
  109. FIN BOUC;
  110. *
  111. MU SIGMA RB1 B2 = PARASTAT TabRES;
  112. *
  113. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%';
  114. MESS '%%% CALCUL DES PARAMETRES STATISTIQUES ';
  115. MESS '%%% MOYENNE       ' MU;
  116. MESS '%%% ECART_TYPE    ' SIGMA;
  117. MESS '%%% SYMETRIE      ' RB1;
  118. MESS '%%% APLATISSEMENT ' B2 ;
  119. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%'; 
  120. opti echo 0;
  121. *
  122. *
  123. *
  124. SI (NEG GRAPH 'N');                                                             
  125.   PDF CDF = PROBDENS MU SIGMA RB1 B2;
  126.   DESS PDF;
  127.   DESS CDF;
  128. FINSI;                                                                          
  129. *
  130. *
  131. * Calcul de la probabilite de defaillance
  132. *     (L'utilisateur peut fournir une table qui contient les
  133. *      points et points d integration pour la limite
  134. *      d'écoulement)
  135. *
  136. *  Alternative : TabFa = QUADRATU 'LOGN' 300. 20. 10;
  137. *
  138. *
  139. TabFa = TABLE;
  140. REPE BOUC 11;
  141.   TabFa. &BOUC = TABLE;
  142. FIN BOUC;
  143. *
  144. TabFa. 1 .POINT = 221.666490;
  145. TabFa. 2 .POINT = 241.022813;
  146. TabFa. 3 .POINT = 258.919954;
  147. TabFa. 4 .POINT = 276.625787;
  148. TabFa. 5 .POINT = 294.715015;
  149. TabFa. 6 .POINT = 313.603185;
  150. TabFa. 7 .POINT = 333.701890;
  151. TabFa. 8 .POINT = 355.523462;
  152. TabFa. 9 .POINT = 379.835374;
  153. TabFa. 10 .POINT = 408.040037;
  154. TabFa. 11 .POINT = 443.670839;
  155. *
  156. TabFa. 1 .POIDS = 2.175677e-05;
  157. TabFa. 2 .POIDS = .002284;
  158. TabFa. 3 .POIDS = .038159;
  159. TabFa. 4 .POIDS = .191306;
  160. TabFa. 5 .POIDS = .364416;
  161. TabFa. 6 .POIDS = .290527;
  162. TabFa. 7 .POIDS = .098867;
  163. TabFa. 8 .POIDS = .013724;
  164. TabFa. 9 .POIDS = .000682;
  165. TabFa. 10 .POIDS = 9.080232e-06;
  166. TabFa. 11 .POIDS = 1.490409e-08;
  167. *
  168. *
  169. Pf = 0.;
  170. REPE BOUC (DIME TabFA);
  171.   p = PROB MU SIGMA RB1 B2 (TabFa. &BOUC .POINT);
  172.   Pf = Pf + ((1-p)*(TabFa. &BOUC .POIDS));
  173. FIN BOUC;
  174. *
  175. * Calcul de l'indice Beta
  176. *
  177. *
  178. BetaFORM = 3.055;
  179. BetaSORM = 3.003;
  180. BetaSRQ  = 3.053;
  181. BetaQuad = INDIBETA 0. 7. Pf;
  182. ErFORM =100 * (ABS ((BetaQuad - BetaFORM) / BetaFORM));
  183. ErSORM =100 * (ABS ((BetaQuad - BetaSORM) / BetaSORM));
  184. ErSRQ  =100 * (ABS ((BetaQuad - BetaSRQ) / BetaSRQ));
  185. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%';
  186. MESS '                       RESULTATS';
  187. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%';
  188. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%';
  189. MESS 'Propabilite de defaillance par quadrature' Pf;
  190. MESS 'Indice de fiabilite par quadrature       ' BetaQuad;
  191. MESS '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%';
  192. MESS 'Soit :';
  193. MESS '        ERREUR par rapport a FORM' ErFORM '%';
  194. MESS '        ERREUR par rapport a SORM' ErSORM '%';
  195. MESS '        ERREUR par rapport a SRQ ' ErSRQ '%';
  196. *==================================================================*            
  197. *                  code fonctionnement                             *            
  198. *==================================================================*            
  199. *                                                                               
  200. *     L'ecart maximum entre valeur theorique et calculee doit etre              
  201. * inferieure a 2 %.                                                              
  202. *
  203. SI (ErFORM <EG 2);                                                              
  204.     ERRE 0;                                                                     
  205. SINON;                                                                          
  206.     ERRE 5;                                                                     
  207. FINSI;                                                                          
  208. *
  209. SI (ErSORM <EG 2);                                                              
  210.     ERRE 0;                                                                     
  211. SINON;                                                                          
  212.     ERRE 5;                                                                     
  213. FINSI;                                                                          
  214. *
  215. SI (ErSRQ <EG 2);                                                              
  216.     ERRE 0;                                                                     
  217. SINON;                                                                          
  218.     ERRE 5;                                                                     
  219. FINSI;                                                                          
  220. *
  221. *==================================================================*            
  222. *                 Temps de calcul et fin                           *            
  223. *==================================================================*            
  224. *                                                                               
  226. TEMPS;                                                                          
  228. OPTI ECHO 1;
  229. *
  230. FIN;                                                                            
  231.  
  232.  
  233.  
  234.  
  235.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales