Télécharger la plaquette Cast3M


fr en

Télécharger source4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : source4.dgibi
  2. * section : thermique
  3. *----------------------------------------------------------------------*
  4. *                       S O U R C E 4 . D G I B I                      *
  5. *----------------------------------------------------------------------*
  6. *
  7. * Objet :
  8. * -------
  9. *
  10. * Verfication / validation d'un modele de source de chaleur.
  11. * Cas d'une SOURCE GAUSSIENNE ELARGIE
  12. *
  13. * Description :
  14. * -------------
  15. * Comparaison des flux nodaux equivalents obtenus avec le modele a
  16. * ceux obtenus en construisant le champ "a la main", puis en l'integrant
  17. * avec l'operateur SOURCE.
  18. *
  19. * Type de calcul : Aucun
  20. * Mode de calcul : 3D
  21. * Type d'element : CUB8
  22. * Objectifs      : Ecart relatif entre flux integres < 1.e-12
  23. *                  Ecart relatif entre la chaleur totale fournie (QTOT)
  24. *                  et la resultante sur le champ integre < 1.e-4
  25. *
  26. *----------------------------------------------------------------------*
  27. *
  28. * IG1 vrai : traces actives
  29. IG1      = faux ;
  30. *
  31. * Parametres du maillage :
  32. lo1      = 30.e-3 ;
  33. la1      = 30.e-3 ;
  34. ep1      = 20.e-3 ;
  35. de1      = 0.5e-3 ;
  36.  
  37. * Parametres de la source :
  38. QT1      = 1.e3 * pi ;
  39. RG1      = 5.e-3 ;
  40. ZG1      = 9.e-3 ;
  41. LG1      = 3.e-3 ;
  42.  
  43. *------------------------ 3D ELEMENTS LINEAIRES -----------------------*
  44. *
  45. opti dime 3 elem cub8 ;
  46.  
  47. * Maillage :
  48. li1      = (0 0 0) droi (0 la1 0) dini de1 dfin de1 ;
  49. Su1      = li1     tran (lo1 0 0) dini de1 dfin de1 ;
  50. Vo1       = Su1 volu tran (0 0 ep1) dini de1 dfin de1 ;
  51.  
  52. si IG1 ;
  53.   ltyp1    = Vo1 elem type ;
  54.   mot1     = mot 'ELEM =' ;
  55.   repe bm1 (dime ltyp1) ;
  56.     mot1     = chai mot1 ' ' (ltyp1 extr &bm1) ;
  57.   fin bm1 ;
  58.   mot1     = chai ' Maillage test en 3D (' mot1 ')' ;
  59.   trac cach Vo1 titr mot1 ;
  60. fins;
  61.  
  62. * Parametres de la source :
  63. OR1      = ((0.5 0.5 0.) * (la1 * pi / 3.)) plus (0 0 ep1) ;
  64. DR1      = 0. 0. +2. ;
  65. DL1      = 0. 2. -2. ;
  66.  
  67. * Modeles :
  68. moq1     = mode Vo1 thermique source gaussienne elargie ;
  69. maq1     = mate moq1 'QTOT' QT1 'ORIG' OR1 'RGAU' RG1 'DIRE' DR1 'ZGAU' ZG1 'DIRL' DL1 'LGAU' LG1 ;
  70. sq1      = sour moq1 maq1 ;
  71. qtmoq1   = sq1 resu maxi ;
  72.  
  73. * Repere local :
  74. DL1      = DL1 moin ((psca DL1 DR1) * DR1 / (psca DR1 DR1)) ;
  75. w1       = DR1 / (norm DR1) ;
  76. v1       = DL1 / (norm DL1) ;
  77. u1       = pvec v1 w1 ;
  78.  
  79. * Solution "analytique" : Construction du champ "Gaussien"
  80. mo1      = mode Vo1 thermique ;
  81. x1 y1 z1 = Vo1 coor ;
  82. x1 y1 z1 = (x1 - (or1 coor 1)) (y1 - (or1 coor 2)) (z1 - (or1 coor 3)) ;
  83. x1 y1 z1 = (chan cham x1 mo1 stresses) (chan cham y1 mo1 stresses) (chan cham z1 mo1 stresses) ;
  84. xu1      = (x1 * (u1 coor 1)) + (y1 * (u1 coor 2)) + (z1 * (u1 coor 3)) ;
  85. yv1      = (x1 * (v1 coor 1)) + (y1 * (v1 coor 2)) + (z1 * (v1 coor 3)) ;
  86. zw1      = (x1 * (w1 coor 1)) + (y1 * (w1 coor 2)) + (z1 * (w1 coor 3)) ;
  87. masql0   = (abs yv1) masq egin LG1 ;
  88. masql1   = (abs yv1) masq supe LG1 ;
  89. sqref0   = (((xu1 ** 2 / RG1 / RG1) + (zw1 ** 2 / ZG1 / ZG1) * -2.) exp) * masql0 ;
  90. yl1      = (yv1 abs) born mini LG1 ;
  91. yl1      = yl1 - LG1 ;
  92. sqref1   = (((xu1 ** 2 / RG1 / RG1) + (yl1 ** 2 / RG1 / RG1) + (zw1 ** 2 / ZG1 / ZG1) * -2.) exp) * masql1 ;
  93. chref1   = sqref0 + sqref1 ;
  94.  
  95. * Facteur de normalisation q0 :
  96. xqx2     = ((pi ** 3 / 32.) ** 0.5 * RG1 * RG1 * ZG1) + (0.5 * pi * RG1 * ZG1 * LG1) ;
  97. q0ref    = QT1 / xqx2 ;
  98.  
  99. * Champ de la source de chaleur :
  100. chref1   = chref1 * q0ref ;
  101.  
  102. * Puissance totale qtref1 :
  103. qtref1   = intg chref1 mo1 ;
  104.  
  105. * Affichage distribution :
  106. si ig1 ;
  107.   trac chref1 mo1 titr 'Distribution Gaussienne "elargie"' ;
  108.   titr 'Distribution Gaussienne "elargie"' ;
  109.   trac chref1 mo1 coup or1 (or1 plus v1) (or1 plus w1) ;
  110. fins ;
  111.  
  112. * Flux nodaux equivalents sol. ref.
  113. sqref1   = sour mo1 chref1 ;
  114. si IG1 ;
  115.   trac sq1 Vo1 titr ' Flux nodaux du champ de source Gaussienne du MODELE ' coup or1 (0 1 0) (0 0 1) ;
  116.   trac sqref1 Vo1 titr ' Flux nodaux du champ de source Gaussienne REFERENCE' coup or1 (0 1 0) (0 0 1) ;
  117.   trac (sq1 - sqref1) Vo1 titr ' Difference des 2 champs' coup or1 (0 1 0) (0 0 1) ;
  118. fins ;
  119.  
  120. err1     = (maxi abs (sq1 - sqref1)) / (maxi abs sqref1) ;
  121. list err1 ;
  122. err2     = (abs (qtmoq1 - qt1)) / (abs qt1) ;
  123. list err2 ;
  124. si ((err1 > 1.e-12) ou (err2 > 1.e-4)) ;
  125.   ERRE ' Probleme MODE SOURCE' ;
  126. fins ;
  127.  
  128.  
  129. *----------------- F I N    S O U R C E 4 . D G I B I -----------------*
  130. fin ;
  131.  
  132.  
  133.  
  134.  
  135.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales