Télécharger la plaquette Cast3M


fr en

Télécharger soret_13.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  soret_13.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. *                        CAS TEST soret_13.dgibi                       *
  7. ************************************************************************
  8. *   Test effet Soret
  9. * - 3D TRID
  10. * - ELEMENTS FINIS TESTES : 'PR15'
  11. * - Regime permanent
  12. * - C(Z0) = C0
  13. * - C(Z1) = C1
  14. * - GRAD(T) choisi lineaire (T=A*(Z**2) / 2.D0   ==> GRAD(T)= A*Z)
  15. * - CONDUCTION et SORET sont en concurrence
  16. ************************************************************************
  17.  
  18.  
  19. ************************************************************************
  20. * OPTIONS & REGLAGES
  21. ************************************************************************
  22.   GRAPH = 'N' ;
  23.  'OPTI' 'DIME' 3 ;
  24.  'OPTI' 'ELEM' 'TRI6'  ;
  25.  
  26.  'SI' ('NEG' GRAPH 'N');
  27.    'OPTI' 'TRAC' 'X';
  28.  'SINO';
  29.    'OPTI' 'TRAC' 'PSC';
  30.  'FINS';
  31.  
  32.   NBE1 =  5   ;
  33.   NBE2 =  5   ;
  34.   NBE3 = 15   ;
  35.  
  36.   K    = -7.D0;
  37.   A    =  1.D0;
  38.  
  39.   Z0   = -0.5 ;
  40.   Z1   =  1.  ;
  41.  
  42.   C0   = 1.   ;
  43.   C1   = 2.   ;
  44.  
  45. ************************************************************************
  46. * MAILLAGE
  47. ************************************************************************
  48.   P1 = 0. 0. Z0;
  49.   P2 = 0. 1. Z0;
  50.   P3 = 1. 1. Z0;
  51.   P4 = 1. 0. Z0;
  52.  
  53.   L1 ='DROI' NBE1 P1 P2;
  54.   L2 ='DROI' NBE1 P4 P3;
  55.  
  56.   S1 ='REGL' NBE2 L1 L2;
  57.   S2 = S1 'PLUS' (0. 0. (Z1 - Z0));
  58.   L4 ='COTE' 4 S2;
  59.   P5 ='POIN' L4 'FINAL';
  60.  
  61.  'OPTI' 'ELEM' 'PR15';
  62.   V1  ='VOLU' NBE3 S1 S2 ;
  63.   ENV1='ENVE' V1;
  64.   ARE1='ARET' ENV1;
  65.   PAR1='CHAN' 'POI1' ARE1 ;
  66.   M1  ='POIN' PAR1 'DROIT' P1 P5 1.D-5;
  67.  
  68.   L6  = 'ELEM' ARE1 'APPU' 'STRI' M1;
  69.  'TRAC' 'QUAL' ENV1;
  70.  'TRAC' 'QUAL' ARE1;
  71.  
  72. ************************************************************************
  73. * MODELE & MATERIAU
  74. ************************************************************************
  75.   MOD1 ='MODE'  V1   'DIFFUSION' 'FICK' 'INCO' 'HI  ' 'QHI ';
  76.   MAT1 ='MATE'  MOD1 'KD  ' 1.D0 ;
  77.   MAT2 ='MANU' 'CHML' MOD1 'SCAL' K 'RIGIDITE' ;
  78.  
  79. ************************************************************************
  80. * Champ de temperature pour que le GRAD(T) soit constant
  81. ************************************************************************
  82.   COO3  ='COOR' 3 V1 ;
  83.   EVO1  ='EVOL' 'BLEU' 'CHPO' COO3 'SCAL' L6  ;
  84.   LRZ   ='EXTR'  EVO1  'ORDO' 1 ;
  85.   TEMP1 ='CHAN' 'COMP' (A / 2.D0 * (COO3 ** 2)) 'T' ;
  86.  'TITR' 'Evolution de la TEMPERATURE avec (abscisse curviligne)';
  87.   EVOT  ='EVOL' 'BLEU' 'CHPO' TEMP1 'T' L6  ;
  88.  'DESS' EVOT ;
  89.  
  90. ************************************************************************
  91. * RIGIDITE
  92. ************************************************************************
  93.   RIG1 ='COND' MOD1 MAT1;
  94.   RIG2 ='SORE' MOD1 MAT1 MAT2 TEMP1;
  95.  
  96. ************************************************************************
  97. * CONDITIONS AUX LIMITES
  98. ************************************************************************
  99.   CLIM1 ='BLOQ' 'HI'  S1   ;
  100.   CLIM2 ='BLOQ' 'HI'  S2   ;
  101.  
  102.  
  103.   CIMP1 ='DEPI' CLIM1 C0   ;
  104.   CIMP2 ='DEPI' CLIM2 C1   ;
  105.  
  106. ************************************************************************
  107. * RESOLUTION
  108. ************************************************************************
  109.   SOL1  ='RESO' (RIG1 ET RIG2 ET CLIM1 ET CLIM2) (CIMP1 ET CIMP2);
  110.  'TITR' 'Isovaleurs de concentration en HI';
  111.  'TRAC' SOL1 V1;
  112.  
  113. ************************************************************************
  114. * POST-TRAITEMENT
  115. ************************************************************************
  116. * Solution NUMERIQUE
  117.   EVONUM ='EVOL' 'ROUG' 'CHPO' SOL1 'HI  ' L6  ;
  118.   LCNUM  ='EXTR' EVONUM 'ORDO' 1 ;
  119.   EVONUM ='EVOL' 'ROUG' 'MANU' 'X' LRZ 'HI' LCNUM;
  120.  
  121. * Solution ANALYTIQUE
  122.   EVO2   ='EVOL' 'CHPO' TEMP1 'T' L6  ;
  123.   FLO1 = ((-2*K*A)**0.5)/2. ;
  124.   XDENO= ( 'EXP'(K/2.*A*(LRZ**2))            ) *
  125.          (('ERF'(FLO1*Z1)) - ('ERF'(FLO1*Z0)));
  126.   LNUME= (('ERF'(FLO1*LRZ))*C1*('EXP'(K/2.*A*(Z1**2))))-
  127.          (('ERF'(FLO1*LRZ))*C0*('EXP'(K/2.*A*(Z0**2))))+
  128.          (('ERF'(FLO1*Z1 ))*C0*('EXP'(K/2.*A*(Z0**2))))-
  129.          (('ERF'(FLO1*Z0 ))*C1*('EXP'(K/2.*A*(Z1**2))));
  130.  
  131.   LCANA  =  LNUME / XDENO;
  132.  
  133.   EVOANA ='EVOL' 'BLEU' 'MANU' 'X' LRZ 'HICA' LCANA;
  134.  'DESS' (EVONUM ET EVOANA);
  135.  
  136. * Comparaison
  137.   LCDIFF = LCNUM - LCANA ;
  138.  'TITR' 'Difference entre la Solutions NUMERIQUE et ANALYTIQUE';
  139.   EVODIF ='EVOL' 'VERT' 'MANU' 'X' LRZ 'HICA' LCDIFF;
  140.  'DESS' EVODIF;
  141.  
  142.  
  143. * Critere d'erreur
  144.  'OPTI' 'ECHO' 0;
  145.   ERRABS ='MAXI' 'ABS' LCDIFF;
  146.   ERRREL = ERRABS / (('MAXI' LCANA) - ('MINI' LCANA))      ;
  147.  'MESS' '*********************************************' ;
  148.  'MESS' '* Erreur MAXIMALE absolue  :' ERRABS '*';
  149.  'MESS' '* Erreur MAXIMALE relative :' ERRREL '*';
  150.  'MESS' '*********************************************' ;
  151.  'SI' (ERRREL >EG 5.59D-4);
  152.    'ERRE' 5;
  153.  'FINS';
  154.  
  155.  'FIN';
  156.  
  157.  
  158.  
  159.  
  160.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales