Télécharger la plaquette Cast3M


fr en

Télécharger sissi.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  sissi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************
  6. *    Test sissi.dgibi: jeux de données    *
  7. *    ---------------------------------    *
  8. *******************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI ECHO 1   ;
  19.   OPTI TRAC PSC   ;
  20. SINO ;
  21.   OPTI ECHO 0   ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *******************************************
  26. *                                         *
  27. *  Mots-clés : Vibrations, calcul modal,  *
  28. *              poutre, seisme             *
  29. *                                         *
  30. *                  SISSI                  *
  31. *                                         *
  32. * CAS TEST DU 91/06/19  PROVENANCE : PLAF *
  33. * CAS TEST DU 91/06/18  PROVENANCE : PLAF *
  34. *                                         *
  35. *      test de la procedure SISSIB        *
  36. *                                         *
  37. *  1 poutre encastree, 20 elements finis, *
  38. *  IY different de IZ, un spectre         *
  39. *  d'oscillateurs en ACCE direction du    *
  40. *  seisme : X                             *
  41. *                                         *
  42. *******************************************
  43.  
  44. TEMPS ;
  45. OPTI DIME 3 ELEM 'SEG2' ;
  46. *
  47. C1 = 0. 0. 0. ;
  48. C2 = 0. 0. 5. ;
  49. C3 = 0. 0. 10. ;
  50. L1 =  DROITE 10 C1 C2  ;
  51. L2 =  DROITE 10 C2 C3  ;
  52. LI =  L1  ET  L2  ;
  53.  
  54.  
  55. SI (NEG GRAPH 'N');
  56.   TRAC 'QUAL' LI;
  57. FINSI;
  58.  
  59. MOD1 = MODE LI MECANIQUE ELASTIQUE POUT ;
  60.  
  61. CH_MAT = MATE MOD1 YOUNG 2.E11  NU 0.3  RHO 7800. ;
  62. CH_CAR = CARA MOD1 SECT 0.25 INRY 0.006  INRZ 0.004 TORS 0.01 VECT ( 0. 1. 0. ) ;
  63. CH_MAT=CH_MAT et CH_CAR;
  64.  
  65. RIG1 = RIGI CH_MAT  MOD1 ;
  66. ENC1 = BLOQ C1 DEPL ROTA ;
  67. RIGFI= RIG1 ET ENC1 ;
  68.  
  69. MAS1 = MASS CH_MAT MOD1 ;
  70.  
  71. *     Calcul des premiers modes
  72.  
  73. L_FREQ   = PROG  3.58  4.38  24.09  25.15 ;
  74. MODE_POU = VIBR PROCHE L_FREQ RIGFI MAS1 ;
  75.  
  76. *     Calcul des contraintes modales
  77. MODE_POU = SIGSOL MOD1 CH_MAT MODE_POU ;
  78.  
  79. *     Calcul des reactions modales
  80. MODE_POU = REAC ENC1 MODE_POU ;
  81.  
  82. ITAB2 = MODE_POU . 'MODES' ;
  83. NB_MODE = ( DIME ITAB2 ) - 2 ;
  84.  
  85. *     Definition du spectre acceleration
  86. LIS_TEMP = PROG 0. PAS 1.E-2  0.50 ;
  87. LIS_ACCE = PROG  0.  0.5  1.  0.5  0.  -0.5  -1.  -0.5 0.  0.5  1.  0.5  0.  -0.5  -1.  -0.5 0.  0.5  1.  0.5  0.  -0.5  -1.  -0.5 0.  0.5  1.  0.5  0.  -0.5  -1.  -0.5 0.  0.5  1.  0.5  0.  -0.35 -0.7 -0.35 0.  0.25 0.5 0.25 0.  -0.15 -0.3 -0.15 0.  0.1  0.  ;
  88.                   LIS_CHAR = EVOL MANU LIS_TEMP LIS_ACCE ;
  89.  
  90. SI (NEG GRAPH 'N');
  91.   TITR 'Chargement en Acceleration';
  92.   DESS LIS_CHAR;
  93. FINSI;
  94.  
  95. LIS_FREQ = PROG 1.   PAS 2.  400. ;
  96. LIS_AMOR = PROG 2.   5.   10.  15.  ;
  97. LIS_AMOR = LIS_AMOR * 1.e-2 ;
  98. SEISME_X = SPO LIS_CHAR 'AMOR'  LIS_AMOR 'FREQ'  LIS_FREQ 'ACCE' ;
  99.  
  100. BAS_AMOR = PROG 4. 6. 7. 9. ;
  101. BAS_AMOR = BAS_AMOR * 1.e-2 ;
  102.  
  103. TAB1 = TABL ;
  104.  
  105. TAB1 . 'STRUCTURE' = MODE_POU ;
  106. TAB1 . 'AMORTISSEMENT' = BAS_AMOR ;
  107.  
  108. TAB3 = 'TABLE' 'EXCITATION' ;
  109. TAB1 . 'EXCITATION' = TAB3 ;
  110.  
  111. TAB3 . 1 = 'TABLE' ;
  112. TAB3 . 1 . 'DIRECTION' = 'X' ;
  113. TAB3 . 1 . 'SPECTRE' = SEISME_X ;
  114. TAB3 . 1 . 'AMORTISSEMENT' = LIS_AMOR ;
  115.  
  116. TAB1 . 'RECOMBINAISON_MODES' = 'SRSS';
  117. TAB1 . 'RECOMBINAISON_DIRECTIONS' =   'QUADRATIQUE' ;
  118.  
  119. TAB4 = 'TABLE' 'SORTIES' ;
  120. TAB1 . 'SORTIES' = TAB4 ;
  121. TAB4 . 'DOMAINE' = MOD1 ;
  122. TAB4 . 'DEPLACEMENTS'  = VRAI ;
  123. TAB4 . 'CONTRAINTES'   = VRAI ;
  124. TAB4 . 'ACCELERATIONS' = VRAI ;
  125.  
  126. TAB2 = SISSIB TAB1 ;
  127.  
  128. MESS ' Chpoint de deplacement du point  C3 issu de SISSIB :' ;
  129. MESS '  ' ;
  130. CHP_DEP = TAB2 . 'X' . 'DEPLACEMENTS' ;
  131. LIST ( REDU CHP_DEP C3 ) ;
  132. MESS ' Chpoint d acceleration du point  C3 issu de SISSIB :' ;
  133. MESS '  ' ;
  134. CHP_ACC = TAB2 . 'X' . 'ACCELERATIONS' ;
  135. LIST ( REDU CHP_ACC C3 ) ;
  136.  
  137. CHE_CONT = TAB2 . 'X' . 'CONTRAINTES' ;
  138. MAX_CONT = MAXI CHE_CONT ;
  139. MESS ' Valeur maximale des contraintes  issue de SISSIB =' MAX_CONT ;
  140. MESS '  ' ;
  141.  
  142. *-----------------------------------------*
  143. *                                         *
  144. *      Verification de la procedure       *
  145. *                                         *
  146. *-----------------------------------------*
  147. *   Verification du deplacement
  148. *   Verification de l'acceleration
  149. *   Verification de la contrainte maximale
  150.  
  151. *     ----- calcul de S(N,X,B) -----
  152. TSEIS = TABL ;
  153. NB_AMOR = 'DIME' LIS_AMOR ;
  154. I_MODE = 0 ;
  155. REPETER BOUC1 NB_MODE ;
  156.    I_MODE = I_MODE + 1 ;
  157.    ITAB3  = ITAB2 . I_MODE ;
  158.    F_N = ITAB3 . 'FREQUENCE' ;
  159.    LOG_F_N = LOG F_N ;
  160.    B_N = EXTRAIRE BAS_AMOR I_MODE ;
  161.  
  162.    P_SPEC = 'PROG' ;
  163.    I_AMOR = 0 ;
  164.    REPETER BOUC10 NB_AMOR ;
  165.       I_AMOR = I_AMOR '+' 1 ;
  166.       EVOLS1  = 'EXTR' SEISME_X 'COUR'  I_AMOR ;
  167.       LISABS1 = 'EXTR' EVOLS1 'ABSC' ;
  168.       LISORD1 = 'EXTR' EVOLS1 'ORDO' ;
  169.       LOG_ABS1 = 'LOG' LISABS1 ;
  170.       LOG_ORD1 = 'LOG' LISORD1 ;
  171.       S1 = IPOL LOG_F_N LOG_ABS1 LOG_ORD1 ;
  172.       S_1 = 'EXP' S1 ;
  173.  
  174.       P_SPEC = P_SPEC ET ( 'PROG' S_1 ) ;
  175.    FIN BOUC10 ;
  176.  
  177.    S_N = 'IPOL' B_N LIS_AMOR P_SPEC ;
  178.  
  179.   TSEIS . I_MODE = S_N ;
  180. FIN BOUC1 ;
  181.  
  182. I_MODE = 0 ;
  183. ZTRON = 'MANU' 'CHPO' LI 1 'UX' 1. ;
  184. *
  185. REPETER BOUC2 NB_MODE ;
  186.    I_MODE = I_MODE + 1 ;
  187.    S_I = TSEIS . I_MODE ;
  188.    ITAB3  = ITAB2 . I_MODE ;
  189.    F_I = ITAB3 .'FREQUENCE' ;
  190.    D_I = ITAB3 .'DEFORMEE_MODALE' ;
  191.    C_I = ITAB3 .'CONTRAINTE_MODALE' ;
  192.    ITAB4=ITAB3 .'DEPLACEMENTS_GENERALISES';
  193.    Q_I = ITAB4 . 1 ;
  194.    M_I = ITAB3 . 'MASSE_GENERALISEE' ;
  195.    W_I = 2.0 * PI * F_I ;
  196.    QSM = Q_I / M_I ;
  197.    COEF_1 = QSM / ( W_I * W_I ) ;
  198.    DEPL_I = COEF_1 * S_I * D_I ;
  199.    ACCE_I = QSM * S_I * D_I ;
  200.    ZTRON = ZTRON - ( QSM * D_I ) ;
  201.    CONT_I = COEF_1 * S_I * C_I ;
  202.    'SI' ( I_MODE 'EGA' 1 ) ;
  203.       DEPL_T = DEPL_I ** 2 ;
  204.       ACCE_T = ACCE_I ** 2 ;
  205.       CONT_T = CONT_I ** 2 ;
  206.    'SINON' ;
  207.       DEPL_T = DEPL_T + ( DEPL_I ** 2 ) ;
  208.       ACCE_T = ACCE_T + ( ACCE_I ** 2 ) ;
  209.       CONT_T = CONT_T + ( CONT_I ** 2 ) ;
  210.    'FINSI' ;
  211. FIN BOUC2 ;
  212.  
  213. LISORD1 = 'EXTR' SEISME_X 'ORDO' 1 ;
  214. NVAL_1  = 'DIME' LISORD1 ;
  215. GAMMA0 = 'EXTR' LISORD1 NVAL_1 ;
  216. ACCE_T = ACCE_T + ( ( GAMMA0 * GAMMA0 ) *  ( ZTRON ** 2 ) );
  217.  
  218. DEPL_T = DEPL_T ** 0.5 ;
  219. ACCE_T = ACCE_T ** 0.5 ;
  220. CONT_T = CONT_T ** 0.5 ;
  221.  
  222. D_SOM_X = 'EXTR' DEPL_T C3 'UX' ;
  223. A_SOM_X = 'EXTR' ACCE_T C3 'UX' ;
  224. C_MAX   = 'MAXI' CONT_T ;
  225.  
  226.  
  227. DEP = EXTR CHP_DEP C3 'UX' ;
  228. ACC = EXTR CHP_ACC C3 'UX' ;
  229.  
  230.  
  231. MESS '    deplacement du point C3 :' ;
  232. LIST ( 'REDU' DEPL_T C3 ) ;
  233. SAUTER 2 LIGNES ;
  234. MESS '   acceleration du point C3 :' ;
  235. LIST ( 'REDU' ACCE_T C3 ) ;
  236. SAUTER 2 LIGNES ;
  237. MESS '   contrainte maximale  =' C_MAX ;
  238. SAUTER 2 LIGNES ;
  239.  
  240. TEMPS ;
  241.  
  242. *     Code de bon fonctionnement
  243. REF_DEP = D_SOM_X ;
  244. REF_ACC = A_SOM_X ;
  245. REF_CON = C_MAX   ;
  246. RES1 = 100 * (ABS ( ( DEP - REF_DEP ) / REF_DEP ));
  247. RES2 = 100 *  (ABS ( ( ACC - REF_ACC ) / REF_ACC ));
  248. RES3 = 100 *  (ABS ( ( MAX_CONT - REF_CON ) / REF_CON ));
  249.  
  250. SAUTER 2 LIGNES ;
  251.  
  252. MESS 'deplacement theorique :' D_SOM_X 'm';
  253. MESS 'deplacement calculee  :' DEP     'm';
  254. MESS '    Soit un ecart de : ' RES1 '%';
  255. SAUTER 1 LIGNES ;
  256.  
  257. MESS 'acceleration theorique:' A_SOM_X 'm';
  258. MESS 'acceleration calculee :' ACC     'm';
  259. MESS '    Soit un ecart de : ' RES2 '%';
  260. SAUTER 1 LIGNES ;
  261.     SI ( RES1 <EG 1. ) ;
  262.    ERRE 0 ;
  263. SINON ;
  264.    ERRE 5 ;
  265. FINSI ;
  266. SI ( RES2 <EG 1. ) ;
  267.    ERRE 0 ;
  268. SINON ;
  269.    ERRE 5 ;
  270. FINSI ;
  271. SI ( RES3 <EG 1. ) ;
  272.    ERRE 0 ;
  273. SINON ;
  274.    ERRE 5 ;
  275. FINSI ;
  276.  
  277. FIN ;
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales