Télécharger la plaquette Cast3M


fr en

Télécharger rupt7.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rupt7.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *opti echo 0;
  5. *******************************************************
  6. *                                                     *
  7. *           Test Rupt7.dgibi: Jeux de données         *
  8. *           ---------------------------------         *
  9. *                                                     *
  10. *******************************************************
  11. *****   CALCUL DU FACTEUR D'INTENSITE DE          *****
  12. *****   CONTRAINTES D'UNE PLAQUE AVEC FISSURE     *****
  13. *****   RECTILIGNE INCLINEE                       *****
  14. *****   CHARGEE EN TRACTION UNIFORME              *****
  15. *****   PAR SIF (interpolation des deplacements)  *****
  16. *****   ET PAR G_THETA (methode integrale)        *****
  17. *******************************************************
  18. *****   SOLUTION DE REFERENCE DONNE PAR :         *****
  19. *****   [TADA, STRESS ANALYSIS HANDBOOK,1973]     *****
  20. *****  +[ISIDA,IJF(7),301-316,1971] facteur de forme **
  21. *******************************************************
  22. *****   demi-LARGEUR DE LA PLAQUE : b=125 mm ;    *****
  23. *****   LONGUEUR   : 2*h=250 mm                   *****
  24. *****   LONGUEUR DE FISSURE : 50 mm   ;           *****
  25. *****   ANGLE / OX : 45°                          *****
  26. *****   CONTRAINTE UNIFORME : 10 N/m2             *****
  27. *******************************************************
  28. *
  29. opti dime 2 elem qua8 mode plan defo echo 1;
  30. *graph=faux;
  31. graph=vrai;
  32. opti trac psc eptr 5;
  33. *
  34. *--------------DEFINITION DU MAILLAGE-----------------;
  35. *
  36. *geometrie
  37. b = 0.125;
  38. h = 0.125;
  39. alpha1 = 45.;
  40. *alpha1 = 30.;
  41. *alpha1 = 20.;
  42. a = 0.050;
  43. ax = 0.050 * (sin alpha1);
  44. ay = 0.050 * (cos alpha1);
  45. *points
  46. p0=0. 0.;
  47. p11=h 0.;
  48. p12=p11 plus (0. 0.);
  49. p2=(2.*h) 0.;
  50. p3=0. b;
  51. pf=p11 plus (ax ay);
  52. p4=(p11 plus (ax 0.)) plus (0. b);p5=(2.*h) b;
  53. *zone pointe de fissure
  54. i=0;
  55. pd = (prog 1. 2.5 5. 9. 13. 19. 25.) *1.E-3 ;
  56. cim1=pf;cim2=pf;cim3=pf;cim41=pf;cim42=pf;
  57. plfim1=pf;plfim2=pf;pim2=pf;
  58. repeter bbbb 7;
  59.    i= i + 1;
  60.    v=extr pd i;
  61.    pi1=pf moin (v 0.);pi2=pf plus (0. v);
  62.    pi3=pf plus (v 0.);pi4=pf moin (0. v);
  63. *   ci4=cerc  2 pi4 pf pi1;
  64. *   plfi1=ci4 poin 2;
  65.    plfi1 = pf moin ((v * (sin alpha1)) (v * (cos alpha1)));
  66.    plfi2=plfi1 plus (0. 0.);
  67.    n=2;si ((i ega 6 ) ou (i ega 7));n=4;finsi;
  68.    si(alpha1 < 40.); m = n ;
  69.    sinon;            m = n / 2;
  70.    fins;
  71.    ci1=cerc  n pi1 pf pi2;
  72.    ci2=cerc  n pi2 pf pi3;
  73.    ci3=cerc  n pi3 pf pi4;
  74.    ci41=cerc  m pi4 pf plfi1;
  75.    ci42=cerc  m plfi2 pf pi1;
  76.    sui1=cout cim1 ci1;
  77.    sui2=cout cim2 ci2;
  78.    sui3=cout cim3 ci3;
  79.    sui41=cout cim41 ci41;
  80.    sui42=cout cim42 ci42;
  81.    elim 1.E-6 (sui42 et sui1);
  82.    elim 1.E-6 (sui1 et sui2 et sui3 et sui41);
  83.    lfi1=(cont sui41) ELEM comp plfim1 plfi1;
  84.    lfi2=(cont sui42) ELEM comp plfim2 plfi2;
  85.    lhi=pim2 d 1 pi2;
  86.    cim1=ci1;cim2=ci2;cim3=ci3;cim41=ci41;cim42=ci42;
  87.    plfim1=plfi1;plfim2=plfi2;pim2=pi2;
  88.    sut1=sui42 et sui1;
  89.    sut2=sui2 et sui3 et sui41;
  90.    si (i ega 1);
  91.      sutt1=sut1;sutt2=sut2;lf1=lfi1;lf2=lfi2;lh=lhi;
  92.    sinon;
  93.      sutt1=sutt1 et sut1;
  94.      sutt2=sutt2 et sut2;
  95.      lf1=lf1 et lfi1;lf2=lf2 et lfi2;lh=lh et lhi;
  96.    finsi;
  97. *   trac (sutt1 et (coul sutt2 vert));
  98. fin bbbb;
  99. *zone exterieure gauche
  100. lg=p0 d 5 p3;
  101. lhc= p4 d 3 pi2;
  102. lig1=lg et (p3 d 8 p4) et lhc;
  103. lig1=lig1 et (inve ci1) et ci42;
  104. lig1=lig1 et (plfi2 d 2 p12);
  105. nbh = 6;
  106. lig1=lig1 et (p12 d nbh p0);
  107. su1=surf lig1 plan;
  108. obj1=su1 et sutt1;
  109. elim 1.E-6 obj1;
  110. *zone exterieure droite
  111. ld=p2 d 5 p5;
  112. lig2=ld et (p5 d 8 p4) et lhc;
  113. lig2=lig2 et ci2 et ci3 et ci41;
  114. lig2=lig2 et (plfi1 d 2 p11);
  115. lig2=lig2 et (p11 d nbh p2);
  116. su2=surf lig2 plan;
  117. obj2=su2 et sutt2;
  118. elim 1.E-6 obj2;
  119. *recup des levres de fissures
  120. perobj1 = inve ( cont sutt1);
  121. lifis1 = (perobj1 ELEM comp pf plfi2) coul rose;
  122. elfis1 = lifis1 elem 'APPU' 'LARG' pf;
  123. elfis1 = lifis1 elem 'APPU' 'LARG' elfis1;
  124. elfis1 = ordo elfis1;
  125. ptfis1 = poin elfis1 2;
  126. vfis1 = pf moin ptfis1;
  127. vfis1 = vfis1 / (norm vfis1);
  128. vfis1ok = pf moin plfi2;
  129. vfis1ok=vfis1ok / (norm vfis1ok);
  130. psc1 = abs (psca vfis1 vfis1ok);
  131. si (psc1 < 0.99);
  132.     lifis1 = (perobj1 ELEM comp plfi2 pf) coul rose;
  133. fins;
  134. *recup des levres de fissures
  135. perobj2 = inve ( cont sutt2);
  136. lifis2 = (perobj2 ELEM comp pf plfi1) coul vert;
  137. elfis2 = lifis2 elem 'APPU' 'LARG' pf;
  138. elfis2 = lifis2 elem 'APPU' 'LARG' elfis2;
  139. elfis2 = ordo elfis2;
  140. ptfis2 = poin elfis2 2;
  141. vfis2 = pf moin ptfis2;
  142. vfis2 = vfis2 / (norm vfis2);
  143. vfis2ok = pf moin plfi2;
  144. vfis2ok=vfis2ok / (norm vfis2ok);
  145. psc2 = abs (psca vfis2 vfis2ok);
  146. si (psc2 < 0.99);
  147.     lifis2 = (perobj2 ELEM comp plfi1 pf) coul rose;
  148. fins;
  149. *symetrie
  150. obj1tmp obj2tmp lgtmp ldtmp
  151.   = syme obj1 obj2 lg ld 'DROIT' p0 p2;
  152. obj2s obj1s lds lgs
  153.   = syme obj1tmp obj2tmp lgtmp ldtmp 'DROIT' p11 (p11 moin (0. b));
  154. ELIM 1.E-6 obj1s obj1;
  155. ELIM 1.E-6 obj2s obj2;
  156. ELIM 1.E-6 lgs obj1s;
  157. ELIM 1.E-6 lds obj2s;
  158. ELIM 1.E-6 lgs lg;
  159. ELIM 1.E-6 lds ld;
  160. *assemblage
  161. obj = (obj1 et obj2 et obj1s et obj2s);
  162. ld= (ld et lds) coul roug;
  163. lg= (lg et lgs) coul bleu;
  164.  
  165. *-----------DEFINITION DU MATERIAU-------------------;
  166. *
  167. * objaf = modl obj MECANIQUE ELASTIQUE ISOTROPE;
  168. phi0 = PSIP obj lifis1 ;
  169. phi0 = CHAN 'CHAM' phi0 obj;
  170. obj1tot = phi0 ELEM 'SUPERIEUR' 1.E-4;
  171. obj2tot = (obj DIFF obj1tot) coul BLEU;
  172. trac (obj1tot et obj2tot);
  173. mess (nbel obj) ((nbel obj1tot) + (nbel obj2tot));
  174. mod1tot = mode obj1tot MECANIQUE ELASTIQUE ISOTROPE;
  175. mod2tot = mode obj2tot MECANIQUE ELASTIQUE ISOTROPE;
  176. objaf =mod1tot et mod2tot;
  177. *
  178. mat = mate objaf youn 20000 nu 0.3;
  179. *
  180. *-----------MATRICE DE RIGIDITE----------------------;
  181. *
  182. rig=rigi mat objaf;
  183. *
  184. *-----------DEFINITION DU CHARGEMENT-----------------;
  185. *
  186. cdl=(bloq ux uy p0) et (bloq uy p2);
  187. sxx1 = 10.;
  188. f1=pres mass objaf lg (-1.*sxx1);
  189. f2=pres mass objaf ld (-1.*sxx1);
  190. *
  191. *-----------RESOLUTION ET CONTRAINTES----------------;
  192. *
  193. u=reso (rig et cdl) (f1 et f2);
  194. sig=sigm mat objaf u;
  195.  
  196. si(graph);
  197.   vf12 = vect (f1 et f2) 'FORC';
  198.   trac vf12 obj ;
  199.   trac sig objaf (defo u obj 20) ;
  200.   trac (obj et lifis1 et lifis2) (defo u obj 20);
  201. fins;
  202.  
  203. *opti trac x;
  204. *----CALCUL DU FACTEUR D'INTENSITE DE CONTRAINTES----;
  205. *----APPEL DE LA PROCEDURE SIF  ---------------------;
  206. SIFTAB = TABL;
  207. SIFTAB.'MODMIXTE' = VRAI;
  208. SIFTAB.'LEVRE_1' = lifis2;
  209. SIFTAB.'LEVRE_2' = lifis1;
  210. SIFTAB.'FRTFISS' = pf;
  211. SIF SIFTAB MAT U;
  212. K1MOY = SIFTAB.K1;
  213. K2MOY = SIFTAB.K2;
  214.  
  215. *----APPEL DE LA PROCEDURE G_THETA  ---------------------;
  216. GTAB = TABL;
  217. GTAB . 'OBJECTIF' = MOT 'DECOUPLAGE';
  218. GTAB . 'FRONT_FISSURE'  = pf;
  219. GTAB . 'LEVRE_SUPERIEURE' = lifis1;
  220. GTAB . 'LEVRE_INFERIEURE' = lifis2;
  221. GTAB . 'COUCHE' = 4;
  222. GTAB . 'SOLUTION_RESO'  = u;
  223. GTAB . 'CARACTERISTIQUES' = mat;
  224. GTAB . 'MODELE' = objaf;
  225. GTAB . 'CHARGEMENTS_MECANIQUES' = (f1 et f2) ;
  226. G_THETA GTAB;
  227. K1G = GTAB . 'RESULTATS' . 'I';
  228. K2G = GTAB . 'RESULTATS' . 'II';
  229.  
  230. *-----DEPOUILLEMENT  ---------------------------------;
  231. *pour a/b=0.4 et b/h=1, on a:
  232. Fac1 = 1.216;
  233. *solution infinie:
  234. K0inf = sxx1 * ((a*pi)**0.5 ) * (cos alpha1);
  235. *solution de reference
  236. K1ref = K0inf * (cos alpha1) * Fac1;
  237. K2ref = K0inf * (sin alpha1) * Fac1;
  238.  
  239. *ecarts relatif (%)
  240. EC1 = (abs (1. - (abs (K1MOY / K1REF)))) * 100;
  241. EC2 = (abs (1. - (abs (K2MOY / K2REF)))) * 100;
  242. EC3 = (abs (1. - (abs (K1G / K1REF)))) * 100;
  243. EC4 = (abs (1. - (abs (K2G / K2REF)))) * 100;
  244.  
  245. *messages
  246. mess '------------------------------------------------';
  247. mess (chai '                   K1           K2   ');
  248. mess (chai 'reference     ' K1ref '  ' K2ref );
  249. mess (chai '   SIF        ' K1MOY '  ' K2MOY );
  250. mess (chai '   G_THETA    ' K1G   '  ' K2G   );
  251. mess '------------------------------------------------';
  252. mess (chai 'erreur relative (%)  K1        K2   ');
  253. mess (chai '   SIF        ' EC1 '  ' EC2 );
  254. mess (chai '   G_THETA    ' EC3 '  ' EC4 );
  255. mess '------------------------------------------------';
  256.  
  257. *opti donn 5;
  258. GTAB . 'MODELES_COMPOSITES' = TABL;
  259. GTAB . 'MODELES_COMPOSITES' . 1 = mod1tot;
  260. GTAB . 'MODELES_COMPOSITES' . 2 = mod2tot;
  261. G_THETA GTAB;
  262. K1Gc = GTAB . 'RESULTATS' . 'I';
  263. K2Gc = GTAB . 'RESULTATS' . 'II';
  264. mess (chai '   G_THETA composite    ' K1Gc   '  ' K2Gc   );
  265.  
  266. *OPTI DONN 5 trac X;
  267. *-----------------------------------------------------;
  268. *------------------MESSAGE D'ERREUR-------------------*
  269. SI ((EC1 < 3.) ET (EC2 < 9.) et (EC3 < 1.) et (EC4 < 6.));
  270.   MESS 'ERR   0';
  271.   ERRE  0;
  272. SINON;
  273.   MESS 'ERR   5';
  274.   ERRE  5;
  275. FINSI;
  276. *-----------------------------------------------------*
  277. fin ;
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales