Télécharger la plaquette Cast3M


fr en

Télécharger rupt31.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  test_sif_2d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas test pour la procedure SIF
  5. * 2D, plaque semi-infinie de taille l1 avec fissure interne de taille l2
  6. * Soumise a une contrainte sig, dans la direction orthogonale a la fissure
  7. * Test sur le calcul du KI
  8. * Valeur theorique KI = sig * (pi*l2/(cos(pi*l2/(2*l1))))**0.5
  9.  
  10.  
  11. * Options generales
  12. OPTI 'DIME' 2 'MODE' 'PLAN' 'ELEM' 'TRI6' ;
  13.  
  14. * Parametres
  15. l1 = 10. ;
  16. l2 = 1. ;
  17. sig = 42. ;
  18.  
  19. * Maillage
  20. p1 = 0. 0. ;
  21. p2 = (l1 - l2) 0. ;
  22. p3 = (l1 + l2) 0. ;
  23. p4 = (2. * l1) 0. ;
  24. p5 = (2. * l1) (5. * l1) ;
  25. p6 = 0. (5. * l1) ;
  26. p7 = p5 SYME 'DROIT' p1 p4 ;
  27. p8 = p6 SYME 'DROIT' p1 p4 ;
  28. * --densites (loin et pres de la fissure)
  29. den1 = l1 / 4. ;
  30. den2 = l2 / 20. ;
  31. l12  = DROI p1 p2 'DINI' den1 'DFIN' den2 ;
  32. l23s = DROI p2 p3 'DINI' den2 'DFIN' den2 ;
  33. l34  = DROI p3 p4 'DINI' den2 'DFIN' den1 ;
  34. l45  = DROI p4 p5 'DINI' den1 'DFIN' den1 ;
  35. l56  = DROI p5 p6 'DINI' den1 'DFIN' den1 ;
  36. l61  = DROI p6 p1 'DINI' den1 'DFIN' den1 ;
  37. con1 = l12 ET l23s ET l34 ET l45 ET l56 ET l61 ;
  38. s1 = SURF con1 ;
  39. l23i = DROI p2 p3 'DINI' den2 'DFIN' den2 ;
  40. l47  = DROI p4 p7 'DINI' den1 'DFIN' den1 ;
  41. l78  = DROI p7 p8 'DINI' den1 'DFIN' den1 ;
  42. l81  = DROI p8 p1 'DINI' den1 'DFIN' den1 ;
  43. con2 = l12 ET l23i ET l34 ET l47 ET l78 ET l81 ;
  44. s2 = SURF con2 ;
  45. stot = s1 ET s2 ;
  46.  
  47. * Modele et materiau
  48. mo = MODE stot 'MECANIQUE' ;
  49. ma = MATE mo 'YOUN' 200.E9 'NU' 0.3 ;
  50.  
  51. * Blocages
  52. bl1 = BLOQ 'DEPL' p1 ;
  53. bl2 = BLOQ 'UY' p4 ;
  54.  
  55. * Chargement
  56. f1 = PRES 'MASS' mo l56 (-1. * sig) ;
  57. f2 = PRES 'MASS' mo l78 (-1. * sig) ;
  58. f = f1 ET f2 ;
  59.  
  60. * Resolution
  61. r0 = RIGI mo ma ;
  62. rig = r0 ET bl1 ET bl2 ;
  63. u = RESO rig f ;
  64.  
  65. * Solution de reference
  66. k1ref = sig * ((pi * l2 / (COS (pi * l2 / (2. * l1)))) ** 0.5) ;
  67.  
  68. * Solution par SIF
  69. t1 = TABL ;
  70. t1 . 'FRTFISS' = p2 ;
  71. t1 . 'LEVRE_1' = l23s ;
  72. t1 . 'MODMIXTE' = VRAI ;
  73. t1 . 'LEVRE_2' = l23s ;
  74. SIF ma u t1 ;
  75. k1sif = t1 . 'K1' ;
  76. errsif = 100. * (k1sif - k1ref) / k1ref ;
  77.  
  78. * Affichage
  79. OPTI 'ECHO' 0 ;
  80. SAUT 3 'LIGNE' ;
  81. MESS 'BILAN, CALCUL DE KI' ;
  83. MESS 'Solution de reference ' k1ref ;
  84. MESS 'Calcul avec SIF       ' k1sif ;
  85. MESS 'Ecart relatif (%)     ' errsif ;
  86.  
  87. * Test d'erreur
  89. SI ((ABS errsif) > 1.) ;
  90.   ERRE 'ERREUR DANS LE CALCUL DU KI' ;
  91. SINON ;
  92.   MESS 'CAS TEST PASSE AVEC SUCCES !' ;
  93. FINSI ;
  94.  
  95. FIN ;
  96.  
  97.  
  98.  
  99.  
  100.  
  101.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales