Télécharger la plaquette Cast3M


fr en

Télécharger rupt1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rupt1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *           Test Rupt1.dgibi: Jeux de données         *
  5. *           ---------------------------------         *
  6. *                                                     *
  7. OPTION echo 1;
  8. GRAPH = 'N';
  9. SAUT PAGE;
  10. *******************************************************
  11. *
  12. *              QUALIFICATION DU CALCUL DE K EN
  13. *          ELASTICITE LINEAIRE SUR UN CYLINDRE AVEC
  14. *          UNE FISSURE DEBOUCHANTE CIRCONFERENTIELLE
  15. *       
  16. * Le calcul est compare a celui obtenu par A ZAHOOR
  17. *******************************************************
  18. * R = rayon interne de la tuyauterie (M)
  19. * B = épaisseur de la tuyauterie (M)
  20. * L = longueur de la tuyauterie (M)
  21. * A = longueur de la fissure (M)
  22. * MYOU = module d'Young (Pa)
  23. * TA = chargement appliqué (N) 
  24. ***
  25. TA = 1.E6;
  26. R = 1.;
  27. B = 0.1;
  28. A = B / 2.;
  29. L = R * 4.;
  30. MYOU = 2.0E11;
  31. ***
  32. *** Maillage
  33. ***
  34. OPTION DIME 2 ELEM QUA8 MODE AXIS;
  35. t = a / 100.; densite t ; pf = (a 0.);
  36. c1 = (c ( pf moin (t 0.)) pf ( pf plus (0. t)))
  37.       c pf ( pf plus (t 0.));
  38. sf = cout pf c1;
  39. r1 = t ; rr1 = t;
  40. repeter bhomo 7;
  41.    ri = r1 + ( 0.3 * r1 );
  42.    rri = rr1 + ri; dens ri;
  43.    ci = (c (pf moin (rri 0.)) pf ( pf plus (0. rri)))  
  44.          c pf (pf plus (rri 0.));
  45.    sf = sf et (cout c1 ci);
  46.    c1 = ci ; r1 = ri ; rr1 = rri;
  47. fin bhomo;
  48. dens (a / 3.);
  49. p0  = (0. 0.) ; p1 = (b 0.);
  50. p2  = p0 plus (0. a) ; p3 = p1 plus (0. a);
  51. pi1 = ci poin 1 ; l1 = pi1 d p0 ; n = (nbel l1) * -1;
  52. pi2 = ci poin 4 ; l2 = pi2 d n p2;
  53. pi3 = ci poin 10 ; l3 = pi3 d n p3;
  54. pi4 = ci poin 13 ; l4 = pi4 d p1;
  55. ci  = inve ci ; ligh = p2 d p3;
  56. sc1 = dall l1 (p0 d p2) (inve l2) (ci ELEM comp pi2 pi1);
  57. sc2 = dall l2 ligh (inve l3) (ci ELEM comp pi3 pi2);
  58. sc3 = dall l3 (p3 d p1) (inve l4) (ci ELEM comp pi4 pi3);
  59. sc  = sc1 et sc2 et sc3;
  60. dens (a / 2.);
  61. mrest1 = ligh tran (0. (2.*a)) dini (40*t) dfin (50*t);
  62. l1 = mrest1 cote 3;
  63. YY1 = coor 2 (point l1 init);
  64. l2 = D 3 (B (YY1 + (0.7*a))) (0. (yy1 + (0.7*a)));
  65. S1 = COUT L1 L2; 
  66. YY1 = COOR 2 (l2 point init);
  67. mrest2 = l2 tran (0. (L - YY1)) dini (80*t) 
  68.                                 dfin (150*t); 
  69. sut = sf et sc et mrest1 et S1 et mrest2;
  70. ELIM 1.E-8 SUT;
  71. DEPL PLUS SUT (R 0.);
  72. L1 = (CONT SUT) ELEM APPU (SUT POIN
  73.      DROI (R 0.) ((B + R) 0.) 1.E-8);
  74. L2 = (CONT SUT) ELEM APPU (SUT POIN
  75.      DROI ((B + R) 0.) ((B + R) L) 1.E-8);
  76. L3 = (CONT SUT) ELEM APPU (SUT POIN
  77.      DROI ((B + R) L) (R L) 1.E-8);
  78. L4 = (CONT SUT) ELEM APPU (SUT POIN
  79.      DROI (R L) (R 0.) 1.E-8);
  80. L5 = (CONT SUT) ELEM COMP P1 PF;
  81. SI ( NEG GRAPH 'N' );
  82.    TITR 'MAILLAGE DU CYLINDRE';
  83.    TRAC sut;
  84. FINSI;
  85. ******
  86. ****** RESOLUTION EN ELASTICITE LINEAIRE
  87. ******
  88. MO1 = MODELE SUT MECANIQUE ELASTIQUE ;
  89. MA1 = MATER MO1 YOUNG MYOU NU 0.3 ;
  90. RI = (BLOQ UZ L5) ET (RIGI MA1 MO1);
  91. AIR1 = PI*(((R + B)**2.) - (R*R));
  92. FOR1 = PRES 'MASS' MO1 (0. - (TA/AIR1)) L3;
  93. DEP1 = RESO FOR1 RI;
  94. SIG1 = SIGMA MO1 MA1 DEP1;
  95. SI ( NEG GRAPH 'N' );
  96.  TITR 'DEFORMATION DU CYLINDRE SOUS TRACTION UNIFORME';
  97.  TRAC (DEFO SUT DEP1);
  98. FINSI;
  99. ***
  100. *** Solution COD (MM) et K (MPA M^0.5) de castem
  101. ***
  102. COD_CAL = (EXTR DEP1 'UZ' P1)*2000.;            
  103. SUPTAB = TABLE ;
  104. SUPTAB.'OBJECTIF' = MOT 'J';
  105. SUPTAB.'LEVRE_SUPERIEURE' = l1 diff l5;;
  106. SUPTAB.'FRONT_FISSURE' = PF ; 
  107. SUPTAB.'MODELE' = MO1;
  108. SUPTAB.'CARACTERISTIQUES' = ma1;
  109. SUPTAB.'SOLUTION_RESO' = dep1;
  110. SUPTAB.'CHARGEMENTS_MECANIQUES' = for1;
  111. SUPTAB.'COUCHE' = 5;
  112. G_THETA SUPTAB;                                   
  113. K_CAL = (MYOU*(SUPTAB.'RESULTATS')/(1 - (0.3**2)))**0.5;
  114. K_CAL = K_CAL*1.E-6; 
  115. ***
  116. *** Solution Analytique Zahoor
  117. ***
  118. RAP1 = R / B; 
  119. SI (RAP1 < 10.); GRANDA = ((0.125*RAP1) - 0.25)**0.25; 
  120. FINSI;
  121. SI (RAP1 >EG 10.); GRANDA = ((0.4*RAP1) - 3.00)**0.25; 
  122. FINSI;
  123. F = (1.9480*((A/B)**1.5)) + (0.3342*((A/B)**4.2));
  124. F = 1.1 + (GRANDA*F);
  125. SIGT = TA / AIR1;
  126. K_ZAH = SIGT*((PI*A)**0.5)*F;
  127. K_ZAH = K_ZAH*1.E-6; 
  128. ERR1 = abs ((K_CAL - K_ZAH)/K_ZAH);
  129. MESS '  Facteur K CASTEM =' K_CAL '(Mpa.M^0.5)';
  130. MESS '  Facteur K ZAHOOR =' K_ZAH '(Mpa.M^0.5)';
  131. MESS '  Erreur relative =' ERR1; 
  132. SI (ERR1 <  1.E-2);
  133.     ERRE 0;
  134. SINO;
  135.     ERRE 5;
  136. FINSI;
  137. FIN;
  138.  
  139.  
  140.  
  141.  
  142.  
  143.  
  144.  
  145.  
  146.  
  147.  
  148.  
  149.  
  150.  
  151.  
  152.  
  153.  
  154.  
  155.  
  156.  
  157.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales