Télécharger la plaquette Cast3M


fr en

Télécharger rotor1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rotor1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * 
  5. ************************************************************************      
  6. *                                                                      *
  7. *  Mots-clés : Vibrations, calcul modal, machines tournantes,          *
  8. *              poutre, modes complexes, reponse frequentielle          *
  9. *                                                                      *
  10. * Test de GYROSCOPIQUE et CAMPBELL pour les elements de poutre         *
  11. * Etude d'une machine tournante dans le repere inertiel (ou fixe)      *
  12. * Elements: POUT, TIMO et TUYAU                                        *
  13. *                                                                      **
  14. * Volant d'inertie sur 2 appuis isotropes et anisotropes               *
  15. * Exemple Axisa Tome 4 P.92                                            *
  16. *                                                                      *
  17. * Auteur: Didier Combescure Août 2003                                  *
  18. *                                                                      *    
  19. ************************************************************************ 
  20. * GRAPH = 'Y'; OPTI 'TRAC' 'PSC' 'EPTR' 6 'POTR' 'HELVETICA_16';
  21. GRAPH = 'N';
  22. *
  23. *-------------------------------------------------------
  24. * Donnees, Maillage
  25. *-------------------------------------------------------
  26.  
  27. * Caractéristiques de l'arbre et du volant d'inertie
  28. *
  29. L1 = 1.5 ;  
  30. L2 = L1;    
  31. *                                                        
  32. Re1 = 0.5 ;
  33. Lvol = 0.20 ;                                                             
  34. E1 = 2.e+11 ;                                                           
  35. Nu1 = 0.3 ;                                                             
  36. Rho1 = 7800. ;
  37. *
  38. S0 = pi*(Re1**2);
  39. Mtot = rho1 * S0 * Lvol; 
  40. Inx = pi*(Re1**4)/2.;
  41. Iny = pi*(Re1**4)/4.;
  42. *
  43. InXtot = Inx*Lvol*Rho1; 
  44. *
  45. * Raideur et amortissement des supports
  46. *
  47. Ky = 100000.;
  48. Kz = 1.00*Ky;
  49. Cy = 100.;
  50. Cz = Cy;
  51. *                                                                       
  52. OPTI 'DIME' 3 'ELEM' SEG2;                                                                     
  53. *
  54. * Volant et arbre avec même section mais masse différente
  55. *                                                         
  56. *
  57. P0 = 0. 0. 0.;
  58. P1 = (L1-(0.5*Lvol))  0.  0. ;
  59. P2 = (L1+(0.5*Lvol))  0.  0. ;
  60. P3 = (L1+L2)  0.  0. ;
  61. GeoArbre = (D 1 P0 P1) et  (D 1 P2 P3); 
  62. GeoVolan = (D 1 P1 P2);
  63. *
  64. Geotot = GeoArbre et GeoVolan;
  65. *
  66. *-------------------------------------------------------
  67. * Modele (element POUT de Bernoulli) , materiau
  68. *-------------------------------------------------------
  69. *        
  70. Mod1a = MODELI GeoArbre 'MECANIQUE' POUT;                                          
  71. Mat1a = MATE Mod1a 'YOUNG' E1 'NU  ' Nu1 'RHO' 0.01
  72.         'SECT' S0 'INRY' Iny 'INRZ' Iny 'TORS' Inx
  73.         'OMEG'  (2.*pi);
  74. Mod1b = MODELI GeoVolan 'MECANIQUE' POUT;                                          
  75. Mat1b = MATE Mod1b 'YOUNG' E1 'NU  ' Nu1 'RHO' Rho1
  76.         'SECT' S0 'INRY' Iny 'INRZ' Iny 'TORS' Inx
  77.         'OMEG'  (2.*pi);
  78. *
  79. mod1 = mod1a et mod1b;
  80. mat1 = mat1a et mat1b;
  81. *                                                                      
  82. *-------------------------------------------------------
  83. * Matrices
  84. *-------------------------------------------------------
  85.  
  86. * Cond. limites : 2 appuis 
  87. *
  88. Blo2 = (BLOQ 'UX' P0);   
  89. Blo3 = (BLOQ 'UX' P3);                             
  90. Blo1 = BLOQ 'RX' Geotot;  
  91. *
  92. Kxp= (APPUI UY KY p0) et (APPUI UY KY p3);
  93. Kyp= (APPUI UZ KZ p0) et (APPUI UZ KZ p3);
  94. Cxp= (APPUI UY CY p0) et (APPUI UY CY p3);
  95. Cyp= (APPUI UZ CZ p0) et (APPUI UZ CZ p3);
  96. *
  97. Kappui = Kxp et Kyp;     
  98. Cappui = Cxp et Cyp;                       
  99. *                                                                      
  100. MMass1 = MASS Mod1 (Mat1) ;                                   
  101. MRigi1 = RIGI Mod1 (Mat1) ;   
  102. *
  103. * Matrice de couplage gyroscopique
  104. *
  105.  CG1 = GYROSCOPIQUE Mod1 Mat1;
  106. * 
  107. * Si on voulait créer une matrice de couplage gyroscopique 
  108. * d'un volant d'inertie, on ferait :
  109. *
  110. * GeoVolan= MANU POI1 Pvol;
  111. * CG1 = MANU RIGI 'TYPE' AMORTISSEMENT  GeoVolan
  112. *        (MOTS 'RX  '  'RY  '  'RZ  ')
  113. *        (prog 0. 0.  0. 
  114. *              0. 0. (2.*pi*InxTot) 
  115. *              0.  ((-2.)*pi.*InxTot) 0.);    
  116.  
  117. * assemblage de matrices
  118. *
  119. RIGT = (MRigi1 ET Kappui ET Blo1 ET Blo2 ET Blo3);
  120. MAST = MMass1;
  121.  
  122. *-------------------------------------------------------
  123. * calcul des modes reels 
  124. *-------------------------------------------------------
  125. *
  126. TBasR1 = VIBR 'PROCHE' (prog 12.) (lect 4)  RIGT MAST  ;
  127. *
  128. TMod1 = TBasR1 . 'MODES' ;
  129. NbMod1 = (DIME TMod1) - 2 ;
  130. TInd1 = INDEX (TMod1 . 1) ;
  131. *
  132. SI (EGA GRAPH 'Y');
  133.  oeil = 1. 10. 0. ;
  134.  REPETER bbb1 NbMod1 ;
  135.   i = &bbb1 ;
  136.   Frq1 = TMod1 . i . 'FREQUENCE' ;
  137.   Def1 = TMod1 . i . 'DEFORMEE_MODALE' ;
  138.   MESS 'Mode ' i ':' Frq1 'Hz' ;
  139.   TITRE Frq1 ;
  140.   trac oeil ((defo geotot def1) et (defo geotot def1 0.));
  141.  FIN bbb1 ;
  142. *
  143.  TABR = TABLE;
  144.  TABR. 'POUTRE' = TABLE;
  145.  (TABR. 'POUTRE'). 'CIRCULAIRE' = VRAI;
  146.  (TABR. 'POUTRE'). 'NCIRC' = 20;
  147.   TABR. 'TUYAU' = TABLE;
  148.  (TABR. 'TUYAU'). 'NCIRC' = 20;
  149.  (TABR. 'TUYAU'). 'NEPAI' = 1;
  150.  TABR.'DEPLACEMENTS' = TABLE;
  151.  (TABR.'DEPLACEMENTS'). 1 = (TMod1 . 1) . 'DEFORMEE_MODALE' ;
  152. *
  153. MESHVOL = POUT2MAS mod1 mat1 GAUSS TABR;
  154. trac (defo MESHVOL ((TABR.'DEPLACEMENTS'). 1)) cach;
  155. *
  156. FINSI;
  157. *
  158. *-Projection des matrices assemblées sur la base réelle
  159. *
  160.   MMasP1 = PJBA TBasR1 MMass1 ;
  161.   MRigP1 = PJBA TBasR1 MRigi1 ;
  162.   Cg1P = PJBA TBasR1 Cg1 ;
  163.   KApp1p =  PJBA TBasR1 (Kappui et Blo1 ET Blo2 et Blo3);
  164.   CApp1p =  PJBA TBasR1 Cappui;
  165.  
  166. *-------------------------------------------------------
  167. * Calcul du diagramme de Campbell via CAMPBELL
  168. *--------------------------------------------------------
  169. TAB1 = TABLE;
  170. TAB1.'BASE_MODALE' = TBasR1 ;
  171. TAB1.'MASS_PROJ' = MMasP1;
  172. TAB1.'RIGI_PROJ' = MRigP1 et KApp1p;
  173. TAB1.'AMOR_PROJ' = CApp1p;
  174. TAB1.'GYRO_PROJ' = Cg1P;
  175. *TAB1.'AFFICHAGE' = VRAI;
  176. PRFREQ = ((prog 0. pas 1. 100.)**2)*(0.01);
  177. CAMPBELL TAB1 PRFREQ;
  178. *
  179. TMod1 = (TAB1.'BASE_MODALE') . 'MODES' ;
  180. NbModR = (DIME ((TAB1.'BASE_MODALE').'MODES')) - 2 ;
  181. NbModC = 2*NbModR;
  182. repeter lab1 NbModC;
  183.   i1= &lab1;
  184.    si (i1 ega 1);
  185.       EVTOT = (TAB1. i1). 'FREQUENCE_REELLE' ;
  186.       EVAMOT = (TAB1. i1). 'AMORTISSEMENT';
  187.    sinon;
  188.       EVTOT = EVTOT et 
  189.                ((TAB1. i1). 'FREQUENCE_REELLE' );
  190.       EVAMOT = EVAMOT et
  191.                ((TAB1. i1). 'AMORTISSEMENT');
  192.    finsi;
  193. FIN lab1;
  194. *
  195. *
  196. SI (EGA GRAPH 'Y');
  197.   dess (evtot et (evol rouge manu (prog 0. 25.)  (prog 0. 25.) ))
  198.       xbord 0. 25. ybord 0. 60.
  199.       TITRE 'Diagramme de Campbell';
  200.   dess  EVAMOT xbord 0. 100. ;
  201. FINSI;
  202.  
  203. *-------------------------------------------------------
  204. * Calcul du diagramme de Campbell via VIBR IRAM
  205. *--------------------------------------------------------
  206.  
  207. * preparation de objets resultats
  208. TIRAM = tabl;
  209. TIRAM . 'FR' = tabl;
  210. TIRAM . 'FI' = tabl;
  211. Tdess = tabl;
  212. Tdess . 'TITRE' = tabl;
  213. ic = 0;
  214. REPE BMODC NbModC; ic = ic + 1;
  215.   TIRAM . 'FR' . ic = prog;
  216.   TIRAM . 'FI' . ic = prog;
  217.   Tdess . 'TITRE' . ic            = MOT 'PAS DE LEGENDE';
  218.   Tdess . 'TITRE' . (NbModC + ic) = MOT 'PAS DE LEGENDE';
  219.   Tdess . (NbModC + ic) = mot 'NOLI MARQ PLUS';
  220. FIN BMODC;
  221.   Tdess . 'TITRE' . 1            = MOT 'VIBC';
  222.   Tdess . 'TITRE' . (NbModC + 1) = MOT 'VIBR IRAM';
  223.  
  224. * on fait le calcul sur quelques frequences 
  225. * sans projeter sur base modale reelle (contrairement a VIBC)
  226. PRFREQ2 = prog 0. pas 25. 100.;
  227. NFREQ2 = DIME PRFREQ2;
  228. I=0;
  229. REPE BOU2 NFREQ2; I = I + 1;
  230.  
  231.     OMEGA = EXTR PRFREQ2 I;
  232.     AMOT = Cappui et (OMEGA * Cg1);
  233.  
  234.   optio impi 0;
  235.     RES1 = VIBR 'IRAM' 0.01 NbModC RIGT MAST AMOT ;
  236.   optio impi 0;
  237.  
  238.     ic = 0;
  239.     REPE BMODC NbModC; ic = ic + 1;
  240.         TIRAM . 'FR' . ic = TIRAM . 'FR' . ic 
  241.           et (RES1 . 'MODES' . ic . 'FREQUENCE_REELLE');
  242.         TIRAM . 'FI' . ic = TIRAM . 'FI' . ic 
  243.           et (RES1 . 'MODES' . ic . 'FREQUENCE_IMAGINAIRE');
  244.     FIN BMODC;
  245.  
  246. FIN  BOU2;
  247.  
  248. * trace pour comparaison graphique
  249. Xevtot  = VIDE 'EVOLUTIO';
  250. Xevtoti = VIDE 'EVOLUTIO';
  251. Xamotot = VIDE 'EVOLUTIO';
  252. ic = 0;
  253. REPE BMODC NbModC; ic = ic + 1;
  254.   Xevtot  = Xevtot  et (EVOL 'ORAN' MANU PRFREQ2 TIRAM . 'FR' . ic);
  255.   Xevtoti = Xevtoti et (EVOL 'ORAN' MANU PRFREQ2 TIRAM . 'FI' . ic);
  256.   Xmod = ((TIRAM . 'FR' . ic ** 2) + (TIRAM . 'FI' . ic ** 2))**0.5;
  257.   Xamotot = Xamotot 
  258.   et (EVOL 'ORAN' MANU PRFREQ2 (TIRAM . 'FI' . ic / Xmod));
  259. FIN BMODC;
  260.  
  261. SI (EGA GRAPH 'Y');
  262.   dess (evtot et Xevtot)
  263.   TITRE 'Diagramme de Campbell' Tdess;
  264.   dess  (EVAMOT et Xamotot) Tdess;
  265. FINSI;
  266.  
  267.  
  268. *-------------------------------------------------------
  269. * Test de bon fonctionnement
  270. *-------------------------------------------------------
  271.  
  272. * VIBC (via Campbell)
  273. EVTOT1  = extr evtot cour 8; 
  274. EVAMOT1 = extr evamot cour 8; 
  275. FR1et2 = IPOL  (prog 0. 25.) (extr EVTOT1 absc) (extr EVTOT1 ordo);
  276. AM1et2 = IPOL  (prog 0. 25.) (extr EVTOT1 absc) (extr EVAMOT1 ordo);
  277. FR1 = extr FR1et2 1;
  278. FR2 = extr FR1et2 2;
  279. AM1 = extr AM1et2 1;
  280. AM2 = extr AM1et2 2;
  281.  
  282. * VIBR IRAM
  283. freq8R = TIRAM . 'FR' . 8;
  284. freq8I = TIRAM . 'FI' . 8;
  285. freq8A = freq8I / (((freq8R**2) + (freq8I**2))**0.5);
  286. XFR1 = extr freq8R 1;
  287. XFR2 = extr freq8R 2;
  288. XAM1 = extr freq8A 1;
  289. XAM2 = extr freq8A 2;
  290.  
  291. * valeurs de reference
  292. FR1Th = 11.879;
  293. FR2Th = 50.278;
  294. AM1Th = 3.73456E-02;
  295. AM2Th = 1.67227E-02;
  296. Errfrq = 0.01*FR1Th;
  297. Erramo = 0.01*AM1Th;
  298. *
  299. opti echo 0;
  300. MESS '   Theorie    |   Campbell    |    VIBR IRAM ';
  301. MESS FR1Th FR1 XFR1;
  302. MESS FR2Th FR2 XFR2;
  303. MESS AM1Th AM1 XAM1;
  304. MESS AM2Th AM2 XAM2;
  305. opti echo 1;
  306.  
  307. SI ((ABS(FR1 - FR1Th) > Errfrq ) OU (ABS(FR2 - FR2Th) > Errfrq ) OU
  308.     (ABS(AM1 - AM1Th) > Erramo ) OU (ABS(AM2 - AM2Th) > Erramo ) OU 
  309.     (ABS(XFR1 - FR1Th) > Errfrq ) OU (ABS(XFR2 - FR2Th) > Errfrq ) OU
  310.     (ABS(XAM1 - AM1Th) > Erramo ) OU (ABS(XAM2 - AM2Th) > Erramo ));
  311.    ERRE 5
  312. SINON;
  313.    ERRE 0; 
  314. FINSI;
  315. *
  316. FIN;
  317. * 
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales