Télécharger la plaquette Cast3M


fr en

Télécharger precont4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  precont4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ************************************************************************
  5. *  Calcul de la perte de précontrainte d'un cable circulaire tendu a   *
  6. *                    une seule de ses extremités.                      *
  7. ************************************************************************
  8. *  
  9. opti dime 3 elem seg2 echo 1 ;
  10. *
  11. graph='n';
  12. oeilz = 0. 0. 1.E8 ;
  13. rayc = 25. ;
  14. *
  15. dtailf = 0.1 ;
  16. dens dtailf ;
  17. p0 = 0. 0. 0. ;
  18. pcent = 0. rayc 0. ;
  19. angpi = 179.99 ;
  20. *
  21. p1 = p0 tour angpi pcent (pcent plus (0. 0. 1.)) ;
  22. p2 = p1 tour angpi pcent (pcent plus (0. 0. 1.)) ;
  23. *
  24. lc1 = cerc p0 pcent p1 ;
  25. lc2 = cerc p1 pcent p2 ;
  26. *
  27. lcerc = lc1 et lc2 ;
  28. *
  29. titre 'Cable circulaire' ;
  30. si(neg graph 'n');
  31. trac oeilz lcerc qual ;
  32. finsi;
  33. *
  34. mo = mode lcerc mecanique elastique  barr ;
  35. ma = mate mo YOUN 1.9E11 SECT 5.55e-3  ;
  36. *
  37. vsect = extr ma sect 1 1 1 ;
  38. *
  39. sp0 = 1.4E9 ;
  40. ftens = sp0 * vsect ;
  41. *
  42. TA = TABLE;
  43. TA.'FF  '=0.18;
  44. TA.'GANC' = 8.E-3 ;
  45. TA.'PHIF' = 0.002 ;
  46. TA.'RMU0' = 0.43  ;
  47. TA.'FPRG' = 1.7E9 ;
  48. TA.'RH10' = 2.5E-2;
  49.  
  50. pre01 = prec mo ma ftens TA p0 ;
  51. pre01p = (chan chpo pre01 mo) / vsect ;
  52. *
  53. titre 'Evolution de la précontrainte donnée par PREC' ;
  54. ev01 = evol roug chpo pre01p effx lcerc ;
  55. si(neg graph 'n');
  56. dess ev01 mima titx 'Absc. curviligne (m)'
  57.                tity 'Précontrainte (Pa)' ;
  58. finsi;
  59. *
  60. ************************************************************************
  61. *            Solution théorique pour un cable circulaire               *
  62. *               Prise en compte des pertes par courbure                *
  63. *                et par frottement linéaire uniquement                 *
  64. ************************************************************************
  65. *
  66. lrabsc = extr ev01 absc ;
  67. ndlis  = dime lrabsc ;
  68. *
  69. vyoun = extr ma youn 1 1 1 ;
  70. vff   = ta.'FF  ';
  71. vphif = ta.'PHIF';
  72. vganc = ta.'GANC';
  73. *
  74. lginflu = 
  75.  (-1.)*(log (1. - ((vganc*vyoun*((vff/rayc)+vphif)/sp0)**0.5)))/
  76.  ((vff/rayc)+vphif) ;
  77. *
  78. lrprec = prog ;
  79. i = 0 ;
  80. repeter bcl1 ndlis ;
  81.   i = i + 1 ;
  82.   xcour = extr i lrabsc ;
  83.   si (xcour < lginflu) ;
  84.     preccour = sp0*(exp (((vff/rayc)+vphif)*(xcour - (2.*lginflu)))) ;
  85.   sinon ;
  86.     preccour = sp0*(exp ((-1.)*((vff/rayc)+vphif)*xcour)) ;
  87.   finsi ;
  88.   lrprec = lrprec et (prog preccour) ;
  89. fin bcl1 ;
  90. *
  91. chtit = chai 'Précontrainte théorique ; influence d ancrage sur'
  92.              lginflu 'm' ;
  93. titre chtit ;
  94. evtheo = evol bleu manu lrabsc lrprec ;
  95. si(neg graph 'n');
  96. dess evtheo mima titx 'Absc. curviligne (m)'
  97.                  tity 'Précontrainte (Pa)';
  98. finsi ;
  99. *
  100. titre 
  101.  'Comparaison : Opérateur PREC (rouge) / résultat théorique (bleu)' ;
  102. *
  103. si(neg graph 'n');
  104. dess (ev01 et evtheo) mima titx 'Absc. curviligne (m)' 
  105.                            tity 'Précontrainte (Pa)' ;
  106. finsi ;
  107.  
  108. orca= extr ev01 ORDO;
  109.  
  110. err1 = ( maxi abs ( orca - lrprec) ) / ( maxi abs lrprec ) ;
  111. mess ' erreur relative maximale sur les ordonnees ' err1;
  112. si ( err1 <  5.E-3  ) ;
  113.   erre 0 ;
  114. sinon ;
  115.   erre 5 ;
  116. finsi ;
  117.  
  118. *
  119. fin ;
  120.  
  121.  
  122.  
  123.  
  124.  
  125.  
  126.  
  127.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales