Télécharger la plaquette Cast3M


fr en

Télécharger poudre1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  poudre1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. complet = faux ;
  5. *
  6. *************************************************
  7. *  pour calcul complet mettre complet à : vrai;
  8. ***************************************************
  9. *
  10. ************************************************************
  11. *                                                          *
  12. *    Cas test pour la loi poudre_A                         *
  13. *                                                          *
  14. *    par Christophe DELLIS   (CEREM)                       *
  15. *                                                          *
  16. ************************************************************
  17. *  cas isotrope
  18. *  un cylindre est densifié par mise en pression
  19. *  la densite initial est uniforme la densite finale
  20. *  est connue analytiquement
  21. *
  22. *opti echo 0 ;
  23. *
  24. option dime 2 elem qua8 mode axis ;
  25. *
  26. *    parametres du maillage
  27. *
  28. rayon_1 = 10.0 ;
  29. *
  30. haute_1 = 15.0 ;
  31. *
  32. * definition des coordonnees des points
  33. *
  34. xa0 = 0.0 ;
  35. ya0 = 0.0 ;
  36. *
  37. xa1 = rayon_1 ;
  38. ya1 = ya0 ;
  39. *
  40. xa2 = xa1 ;
  41. ya2 = ya1 + haute_1 ;
  42. *
  43. xa3 = 0.0 ;
  44. ya3 = ya2 ;
  45. *
  46. * definition des densites
  47. *
  48. dena0 = 10.0 ;
  49. dena1 = 10.0 ;
  50. dena2 = 10.0 ;
  51. dena3 = 10.0 ;
  52. *
  53. * definition des points
  54. *
  55. densite dena0 ;
  56. a0 = xa0 ya0 ;
  57. *
  58. densite dena1 ;
  59. a1 = xa1 ya1 ;
  60. *
  61. densite dena2 ;
  62. a2 = xa2 ya2 ;
  63. *
  64. densite dena3 ;
  65. a3 = xa3 ya3 ;
  66. *
  67. * definition des lignes
  68. *
  69. la0a1 = a0 droi 2 a1 ;
  70. la1a2 = a1 droi 2 a2 ;
  71. la2a3 = a2 droi 2 a3 ;
  72. la3a0 = a3 droi 2 a0 ;
  73. *
  74. la3a2 = inve la2a3 ;
  75. la2a1 = inve la1a2 ;
  76. *
  77. * lignes pour les conditions limites
  78. *
  79. l_symz = la0a1 ;
  80. l_symx = la3a0 ;
  81. l_ext1 = la1a2 ;
  82. l_ext2 = la2a3 ;
  83. *
  84. * definition des surfaces
  85. *
  86. elmat1 = surf ( la0a1 et la1a2 et la2a3 et la3a0 ) plan ;
  87. *
  88. piece_1 = coul elmat1 bleu ;
  89. *
  90. tot = piece_1 ;
  91. elim (tot et a2) 0.001 ;
  92. *
  93. *
  94. ************************************************************
  95. *                                                          *
  96. *       calcul                                             *
  97. *                                                          *
  98. ************************************************************
  99. *
  100. T0TEMPE = 925.0 ;
  101. T1TEMPE = 925.0 ;
  102. T0TEMPS = 0.0 ;
  103. T1TEMPS = 1200.0 ;
  104. T2TEMPS = 2400.0 ;
  105. T3TEMPS = 3600.0 ;
  106. *
  107. *******************************************
  108. * Champ-point de temperature
  109. *******************************************
  110. *
  111. clth0001 = BLOQ 'T' (l_ext1 et l_ext2) ;
  112. p_bloth1 = DEPI clth0001 1. ;
  113. p_temps1 = prog T0TEMPS T1TEMPS T2TEMPS T3TEMPS ;
  114. p_theta1 = prog T0TEMPE T1TEMPE T1TEMPE T0TEMPE ;
  115. ev_ther1 = EVOL MANU TEMPS p_temps1 'T' p_theta1 ;
  116. ch_ther1 = CHAR TIMP p_bloth1 ev_ther1 ;
  117. *
  118. ************************************************************
  119. *                                                          *
  120. *       materiau                                           *
  121. *                                                          *
  122. ************************************************************
  123. P1MODEL = MODE piece_1 MECANIQUE ELASTIQUE
  124. VISCOPLASTIQUE POUDRE_A CONS DEUX;
  125. *
  126. V1YOUNG = 118.0E+03 ;
  127. V1NU = 0.33 ;
  128. V1ALPHA = 10.0E-10 ;
  129. V1A = 7.76E-15 ;
  130. V1N = 4.55 ;
  131. V1QSRT = 0.0 ;
  132. V1RHOR = 0.68 ;
  133. V1F0 = 0.1098 ;
  134. V1F1 = 1.0168 ;
  135. V1F2 = -0.2591 ;
  136. V1F3 = 0.0 ;
  137. V1F4 = 0.0 ;
  138. V1F5 = 0.66 ;
  139. V1C0 = 2.10851 ;
  140. V1C1 = 1.21767 ;
  141. V1C2 = -0.43081 ;
  142. V1C3 = 0.0 ;
  143. V1C4 = 0.0 ;
  144. V1C5 = 50.0 ;
  145. *
  146. P1MATER = MATER P1MODEL YOUNG V1YOUNG NU V1NU ALPH V1ALPHA TALP 20. TREF 0.
  147.  A V1A N V1N QSRT V1QSRT F0 V1F0 F1 V1F1 F2 V1F2 F3 V1F3
  148.  F4 V1F4 F5 V1F5 C0 V1C0 C1 V1C1 C2 V1C2 C3 V1C3 C4 V1C4
  149.  C5 V1C5 RHOR V1RHOR ;
  150. *
  151. P2MODEL = MODE piece_1 THERMIQUE ISOTROPE CONS UN ;
  152. *
  153. P2MATER = MATER P2MODEL 'C' 460 'K' 14.6 'RHO' 4.54 ;
  154. *
  155. ************************************************************
  156. *                                                          *
  157. *          chargement                                      *
  158. *                                                          *
  159. ************************************************************
  160. *
  161. p0bloca = bloque uz l_symz ;
  162. p1bloca = bloque ur l_symx ;
  163. *
  164. p_bloca = p0bloca et p1bloca ;
  165. *
  166. t0pres = 0.0 ;
  167. t1pres = 100.0 ;
  168. *
  169. li_tps = prog t0temps t1temps t2temps t3temps ;
  170. li_pres = prog t0pres t1pres t1pres t0pres ;
  171. ev_pres = evol manu temps li_tps pression li_pres ;
  172. *dess ev_pres titr 'Evolution du chargement en pression' nclk ;
  173. *
  174. p2force = pres mass p1model 1.0 l_ext1 ;
  175. p3force = pres mass p1model 1.0 l_ext2 ;
  176. titr 'Force appliquees' ;
  177. vec1 = vect (p2force et p3force) 'FR' 'FZ' 0.1;
  178. *trac vec1 piece_1 nclk ;
  179. *
  180. p2charg = char p2force ev_pres 'MECA';
  181. p3charg = char p3force ev_pres 'MECA';
  182. *
  183. p_charg = p2charg et p3charg ;
  184. *
  185. ************************************************************
  186. *                                                          *
  187. *        calcul                                            *
  188. *                                                          *
  189. ************************************************************
  190. *
  191. p_model = p1model et p2model ;
  192. p_mater = p1mater et p2mater ;
  193. *p_model = p1model ;
  194. *p_mater = p1mater ;
  195. *
  196. * Initialisation de la table pour la procedure PASAPAS
  197. *
  198. TAB1 = TABLE ;
  199. TAB1 . 'CHARGEMENT' = (p_charg et ch_ther1) ;
  200. TAB1 . 'MODELE' = p_model ;
  201. TAB1 . 'CARACTERISTIQUES' = p_mater ;
  202. TAB1 . 'BLOCAGES_MECANIQUES' = p_bloca ;
  203. TAB1 . 'BLOCAGES_THERMIQUES' = clth0001 ;
  204. si complet;
  205. tfin = 2400.;
  206. sinon;
  207. tfin = 400.;
  208. finsi;
  209.  
  210. TAB1 . 'TEMPS_CALCULES' = PROG 0.0
  211.         PAS 50.0 tfin ;
  212. TAB1 . 'TEMPS_SAUVES' = PROG tfin ;
  213. TAB1 . 'MAXITERATION' = 49 ;
  214. TAB1 . 'MAXISOUSPAS' = 500 ;
  215. TAB1 . 'MOVA' = 'MOT' 'VHOR' ;
  216. TAB1 . 'PRECISION' = 1.0E-4 ;
  217. TAB1 . 'PROCEDURE_THERMIQUE' = 'MOT' 'LINEAIRE' ;
  218. *
  219. PASAPAS TAB1 ;
  220. *
  221. ************************************************************
  222. *                                                          *
  223. *        Test de validation                                *
  224. *                                                          *
  225. ************************************************************
  226. *
  227. ind1 = index (TAB1 . 'VARIABLES_INTERNES') ;
  228. nb1 = dime ind1 ;
  229. *
  230. *   densite finale
  231. *
  232. vm1 = TAB1 . 'VARIABLES_INTERNES' .(ind1.nb1) ;
  233. vm2 = exco VHOR vm1 ;
  234. vm3 = redu vm2 piece_1 ;
  235. rhof1 = maxi vm3 ;
  236. *
  237. * Calcul theorique analytique de la densite finale :
  238. *
  239. si complet;
  240. rhof2 = 0.7418622 ;
  241. sinon;
  242. rhof2 = 0.68006 ;
  243. finsi;
  244. *
  245. * Lecture des deplacements du noeud au coin de l'echantillon :
  246. *
  247. ind2 = index (TAB1 . 'DEPLACEMENTS' ) ;
  248. nb2 = dime ind2 ;
  249. ur1 = (extr TAB1 .'DEPLACEMENTS'.(ind2.nb2) ur a2) ;
  250. uz1 = (extr TAB1 .'DEPLACEMENTS'.(ind2.nb2) uz a2) ;
  251. *
  252. * Calcul analytique des deplacements pour une densification isotrope :
  253. *
  254. si complet;
  255. ur2 = rayon_1 * ((v1rhor/rhof1)**(1./3.) - 1.) ;
  256. uz2 = haute_1 * ((v1rhor/rhof1)**(1./3.) - 1.) ;
  257. sinon;
  258. ur2 = -1.25297E-03  ;
  259. uz2 = -1.88229E-03  ;
  260. finsi;
  261. list ur2 ;list ur1;
  262. list uz2 ; list uz1;
  263. *
  264. * Calcul des erreurs sur les deplacements et la densite :
  265. *
  266. erho1 = abs ((rhof1 - rhof2 )/rhof2);
  267. eur1 = abs ((ur1 - ur2) / ur2) ;
  268. euz1 = abs ((uz1 - uz2) / uz2) ;
  269. *
  270. * Ecriture des erreurs a l'ecran :
  271. *
  272. opti echo 0 ;
  273. sauter 3 lignes ;
  274. mess 'Calcul en isotrope :' ;
  275. mess 'Erreur sur le deplacement radial :    '  eur1 ;
  276. mess 'Erreur sur le deplacement vertical :  '  euz1 ;
  277. mess 'Erreur sur la densite finale:         '  erho1 ;
  278. sauter 3 lignes ;
  279.  
  280. *
  281. si ( (eur1 + euz1 + erho1 ) >eg 0.05 ) ;
  282.    mess '---------RESULTATS INCORRECTS-------------' ;
  283.    sauter 3 lignes ;
  284.    erreur 5;
  285. sinon ;
  286.    mess '---------RESULTATS CORRECTS-------------' ;
  287.    sauter 3 lignes ;
  288. finsi ;
  289. *
  290. fin ;
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales