Exemples de jeux de données Cast3M

** Test du trace de champ avec plusieurs palettes de couleurs
 
** Options de trace (doit fonctionner en OPTI 'TRAC' 'X' et OPTI 'TRAC' 'OPEN')
OPTI 'TRAC' 'PSC' ;
 
** Un champ
OPTI 'DIME' 2 'ELEM' 'QUA4' ;
mail = DROI 11 (0. 0.) (1. 0.) TRAN 11 (0. 1.) ;
x y  = COOR mail ;
 
** Trace avec toutes les palettes disponibles
lis1 = MOTS 'DEFA' 'FRAN' 'ARC1' 'ARC2' 'ARC3' 'JET'  'SPEC'
            'PLAS' 'VIRI' 'GNUP' 'CUIV' 'CHAU' 'PIYG' 'PRGN'
            'MANA' 'GRIS' 'VIOL' 'BLEU' 'VERT' 'ORAN' 'ROUG' ;
REPE b1 (DIME lis1) ;
  mot1 = EXTR lis1 &b1 ;
  pal1 = PALE mot1 ;
  OPTI 'PALE' pal1 ;
  tit1 = CHAI 'Palette' ' ' mot1 ;
  TRAC x mail 'TITR' tit1 ;
  TRAC x mail 'TITR' tit1 10 ;
FIN b1 ;
 
** Trace avec une palette perso
la   =  PROG 0.00 0.25 0.50 0.75 1.00 ;
lr   = (PROG  38.  42. 233. 244. 231.) / 255. ;
lv   = (PROG  70. 157. 196. 162. 111.) / 255. ;
lb   = (PROG  83. 143. 106.  97.  81.) / 255. ;
pal1 = (EVOL 'ROUG' 'MANU' 'MARQ' 'ROND' la lr) ET
       (EVOL 'VERT' 'MANU' 'MARQ' 'ROND' la lv) ET
       (EVOL 'BLEU' 'MANU' 'MARQ' 'ROND' la lb) ;
OPTI 'PALE' pal1 ;
tit1 = MOT 'Palette utilisateur' ;
DESS pal1 'TITR' tit1 ;
TRAC x mail 'TITR' tit1 ;
TRAC x mail 'TITR' tit1 10 ;
 
FIN ;