Télécharger la plaquette Cast3M


fr en

Télécharger orth6.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  orth6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  5. SAUT PAGE;
  6.  
  7. *****************************************************************
  8. *   TEST ORTH6                                                  *
  9. *   PLAQUE CARREE ORTHOTROPE ENCASTREE                          *
  10. *                                                               *
  11. *   Test V.P.C.S. numero SSLS33/90                              *
  12. *                 Groupe : Statique lineaire                    *
  13. *                          Structure assemblee                  *
  14. *                                                               *
  15. *****************************************************************
  16. *
  17. OPTION  ECHO 0;
  18. *
  19. OPTION DIME 2 ELEM QUA4;
  20. OPTION MODE PLAN CONT;
  21. *
  22. GRAPH = 'N';
  23. * GRAPH = 'O';
  24.  
  25. SAUT PAGE;
  26. SI (NEG GRAPH 'N') ;
  27.   OPTI ECHO 1   ;
  28.   OPTI TRAC PSC   ;
  29. SINO ;
  30.   OPTI ECHO 0   ;
  31. FINSI ;
  32.  
  33. *----------------------------------------------------------------*
  34. *                geometrie : maillage                            *
  35. *----------------------------------------------------------------*
  36. *
  37. PA =  0.5  0.5;
  38. PB = -0.5  0.5;
  39. PC = -0.5 -0.5;
  40. PD =  0.5 -0.5;
  41. PE =  0.   0.;
  42. *
  43. D1 = PA DROIT 10 PB;
  44. D2 = PB DROIT 10 PC;
  45. D3 = PC DROIT 10 PD;
  46. D4 = PD DROIT 10 PA;
  47. *
  48. SUR1 = DALLAGE D1 D2 D3 D4 PLAN;
  49. SUR = SUR1 ET PE;
  50. *
  51. ELIM SUR 0.001;
  52. *
  53. SI (NEG GRAPH 'N');
  54.   TITRE 'ORTH6 : PLAQUE CARREE ORTHOTROPE';
  55.   TRACE SUR 'QUAL';
  56. FINSI ;
  57. *
  58. NBNOSUR = NBNO SUR1;
  59. NBELSUR = NBEL SUR1;
  60. *
  61. *----------------------------------------------------------------*
  62. *                 calcul de la rigidite                          *
  63. *----------------------------------------------------------------*
  64. *
  65. MOD = MODE SUR1 MECANIQUE ELASTIQUE ORTHOTROPE QUA4;
  66. *
  67. DIR1 = (COS 30.) (SIN 30.);
  68. MAT = MATE MOD DIRE DIR1 YG1 2.5737E10 YG2 7.377E9 YG3 7.377E9
  69. NU12 0.31 NU13 0.31 NU23 0.31 G12 2.319E9;
  70.  
  71. * verification graphique de l'orientation :
  72. * 2D massif => 2 vecteurs : V1 et V2
  73. v12 = VLOC MOD MAT;
  74. ve12 = VECT v12 MOD (mots 'V1X' 'V1Y' 'V2X' 'V2Y') 0.02 
  75.                     (mots 'AZUR' 'BRON');
  76. SI (NEG GRAPH 'N');
  77.   TITRE 'ORTH6 : V1(AZUR) V2 (JAUNE)';
  78.   TRACE ve12 SUR ;
  79. FINSI ;
  80.  
  81. RI = RIGI MOD MAT ;
  82. *
  83. *----------------------------------------------------------------*
  84. *                   conditions aux limites                       *
  85. *----------------------------------------------------------------*
  86. *
  87. CL = BLOQUE DEPL ROTA D2;
  88. RIG = RI ET CL;
  89. *
  90. *----------------------------------------------------------------*
  91. *                     chargement                                 *
  92. *----------------------------------------------------------------*
  93. *
  94. FTOT = 1.E6;
  95. NBNOD4 = NBNO D4;
  96. F5 = FTOT / ((2 * NBNOD4) - 2);
  97. F50 = F5 0.;
  98. I = 1;
  99. NBI = NBNOD4 - 1;
  100. CHA = FORC (0. 0.) (D4 POIN 1);
  101. REPETER BLOC1 NBI;
  102.   CHA1 = FORC F50 (D4 POIN I);
  103.   CHA2 = FORC F50 (D4 POIN (I+1));
  104.   CHA = CHA ET CHA1 ET CHA2;
  105.   I = I + 1;
  106. FIN BLOC1;
  107. *
  108. *----------------------------------------------------------------*
  109. *              resolution : calcul elastique                     *
  110. *----------------------------------------------------------------*
  111. *
  112. * Champs de deplacements
  113. *
  114. DE = RESO RIG CHA;
  115. *
  116. * Contraintes : interpolation aux noeuds du maillage
  117. *
  118. CHAM1 = SIGM MOD MAT DE;
  119. CHAM2 = CHAN NOEUD MOD CHAM1;
  120. CHPO1 = CHAN CHPO MOD CHAM2;
  121. *
  122. * Trace facultatif du champ de déplacement.
  123. *
  124. SI (NEG GRAPH 'N');
  125.    TITR 'ORTH6 : Deplacements UX';
  126.    TRAC CACH SUR1 (EXCO DE UX);
  127.    TITR 'ORTH6 : Deplacements UY';
  128.    TRAC CACH SUR1 (EXCO DE UY);
  129. FINSI;
  130. *
  131. *----------------------------------------------------------------*
  132. *                  extraction des resultats                      *
  133. *----------------------------------------------------------------*
  134. *
  135. UA = EXTR DE UX PA; UA1 = 1.10E-4;
  136. ERGUA = 100 * (ABS ((UA1 - UA) / UA1));
  137. *
  138. UD = EXTR DE UX PD; UD1 = 9.95E-5;
  139. ERGUD = 100 * (ABS ((UD1 - UD) / UD1));
  140. *
  141. UE = EXTR DE UX PE; UE1 = 4.77E-5;
  142. ERGUE = 100 * (ABS ((UE1 - UE) / UE1));
  143. *
  144. VA = EXTR DE UY PA; VA1 = -1.31E-4;
  145. ERGVA = 100 * (ABS ((VA1 - VA) / VA1));
  146. *
  147. VD = EXTR DE UY PD; VD1 = -7.17E-5;
  148. ERGVD = 100 * (ABS ((VD1 - VD) / VD1));
  149. *
  150. VE = EXTR DE UY PE; VE1 = -4.98E-5;
  151. ERGVE = 100 * (ABS ((VE1 - VE) / VE1));
  152. *
  153. SMXXE = EXTR CHPO1 SMXX PE;
  154. SMXXE = SMXXE / 1.E6;
  155. SMXXE1 = 1.02;
  156. ERGXX = 100 * (ABS ((SMXXE1 - SMXXE) / SMXXE1));
  157. *
  158. SMYYE = EXTR CHPO1 SMYY PE;
  159. SMYYE = SMYYE / 1.E6;
  160. SMXYE = EXTR CHPO1 SMXY PE;
  161. SMXYE = SMXYE / 1.E6;
  162. *
  163. *----------------------------------------------------------------*
  164. *                 affichage des resultats                        *
  165. *----------------------------------------------------------------*
  166. *
  167. * Trace facultatif de la deformees
  168. *
  169. SI (NEG GRAPH 'N');
  170.   TITR ' PLAQUE CARREE ORTHOTROPE : DEFORMEE .';
  171.   AMPVEC = 1E-6;
  172.   VECT1= VECT CHA AMPVEC FX FY ROUGE;
  173.   REA2 = REAC DE RIG;
  174.   VECT2= VECT REA2 1e-6 FX FY BLEU;
  175.   DEF0 = DEFO SUR  DE 0.;
  176.   DEF1 = DEFO SUR  DE 30. (VECT1 ET VECT2) VERT;
  177.   TRAC (DEF0 ET DEF1);
  178. FINSI;
  179. *
  181. MESS 'Resultats : test orth6.dgibi';
  182. MESS '----------------------------';
  184. MESS ' Deplacements';
  185. MESS ' ------------';
  187. *
  188. MESS '   Point A :';
  189. MESS '   ---------';
  191. MESS '     Deplacement theorique horizontal : ' UA1 'm';
  192. MESS '     Deplacement calcule horizontal   : ' UA 'm';
  193. MESS '                     Soit un ecart de : ' ERGUA '%';
  195. MESS '     Deplacement theorique vertical   : ' VA1 'm';
  196. MESS '     Deplacement calcule vertical     : ' VA 'm';
  197. MESS '                     Soit un ecart de : ' ERGVA '%';
  199. *
  200. MESS '   Point D :';
  201. MESS '   ---------';
  203. MESS '     Deplacement theorique horizontal : ' UD1 'm';
  204. MESS '     Deplacement calcule horizontal   : ' UD 'm';
  205. MESS '                     Soit un ecart de : ' ERGUD '%';
  207. MESS '     Deplacement theorique vertical   : ' VD1 'm';
  208. MESS '     Deplacement calcule vertical     : ' VD 'm';
  209. MESS '                     Soit un ecart de : ' ERGVD '%';
  211. *
  212. MESS '   Point E :';
  213. MESS '   ---------';
  215. MESS '     Deplacement theorique horizontal : ' UE1 'm';
  216. MESS '     Deplacement calcule horizontal   : ' UE 'm';
  217. MESS '                     Soit un ecart de : ' ERGUE '%';
  219. MESS '     Deplacement theorique vertical   : ' VE1 'm';
  220. MESS '     Deplacement calcule vertical     : ' VE 'm';
  221. MESS '                     Soit un ecart de : ' ERGVE '%';
  223. *
  224. MESS ' Contraintes au point E';
  225. MESS ' ----------------------';
  227. *
  228. MESS '     Contrainte theorique horizontale : ' SMXXE1 'MPa';
  229. MESS '     Contrainte calculee horizontale  : ' SMXXE 'MPa';
  230. MESS '                     Soit un ecart de : ' ERGXX '%';
  232. MESS '     Contrainte calculee verticale    : ' SMYYE 'MPa';
  234. MESS '  Contrainte calculee de cisaillement : ' SMXYE 'MPa';
  236. *
  237. MESS ' Maillage : ';
  238. MESS ' ---------- ';
  240. MESS '    Nombre de noeuds  : ' NBNOSUR;
  241. MESS '    Nombre d elements : ' NBELSUR 'QUA4';
  243. *----------------------------------------------------------------*
  244. *                  code fonctionnement                           *
  245. *----------------------------------------------------------------*
  246. *
  247. ERGMAX = MAXI ( PROG ERGUA ERGUD ERGUE ERGVA ERGVD ERGVD ERGXX);
  248. *
  249. * Il y a erreur si un des pourcentages ERG* est suprieur  1.%
  250. *
  252. SI (ERGMAX <EG 1.0);
  253.     ERRE  0 ;
  254. SINO;
  255.     ERRE  5 ;
  256. FINSI;
  257. *
  259. TEMPS;
  261.  
  262. FIN;
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales