Télécharger la plaquette Cast3M


fr en

Télécharger mistral_D3r.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  mistral_D3r.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test mistral_D3r.dgibi: Jeux de donnees         *
  6. *     ---------------------------------------         *
  7. *                                                     *
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11.   opti echo 0 ;
  12.   opti dime 3 mode tridim elem cu20 ;
  13.  
  14. *
  15. *******************************************************
  16. *                TEST DE VALIDATION                   *
  17. *                ------------------                   *
  18. *                                                     *
  19. *  MODELE MISTRAL                                     *
  20. *    DILATATION THERMIQUE, ELASTICITE ET CROISSANCE   *
  21. *                                                     *
  22. *  MAILLAGE :                                         *
  23. *    SECTEUR DE TUBE CYLINDRIQUE                      *
  24. *                                                     *
  25. *  CHARGEMENT :                                       *
  26. *    CONTRAINTE AXIALE,                               *
  27. *    TEMPERATURE ET FLUX NEUTRONIQUE                  *
  28. *******************************************************
  29. *
  30. * Geometrie
  31. *
  32. * ------------------------------------------------------
  33.   RI = 49.5E-3 ; RE = 50.5E-3 ; H = 0.010 ;
  34.   TETA = 30. ; NMAILT = 2 ;
  35. * ------------------------------------------------------
  36.    RM = (RI+RE)/2. ;
  37.    P11 = COS(TETA) ;         P12 = SIN(TETA) ; P13 = 0. ;
  38.    P21 = (-1.)*(SIN(TETA)) ; P22 = COS(TETA) ; P23 = 0. ;
  39.    P31 = 0.  ;               P32 = 0. ;        P33 = 1. ;
  40. *
  41. * Maillage
  42. *
  43.    PIB = RI 0. 0. ;  PEB = RE 0. 0. ;
  44.    PIH = RI 0. H  ;  PEH = RE 0. H ;
  45.    LB = droi 2 PIB PEB ;
  46.    LE = droi 1 PEB PEH ;
  47.    LH = droi 2 PEH PIH ;
  48.    LI = droi 1 PIH PIB ;
  49.    PLR0Z = dall LB LE LH LI plan ;
  50. *
  51.    POMB = RM 0. 0. ; POMH = RM 0. H ;
  52.    PMB = PLR0Z poin proc POMB ;
  53.    PMH = PLR0Z poin proc POMH ;
  54. *
  55. *   trac PLR0Z ;
  56. *
  57. * ------------------
  58.   CRITELIM = 1.E-5 ;
  59. * ------------------
  60.    PAXB = 0. 0. 0. ; PAXH = 0. 0. H ;
  61.    EPROU = PLR0Z volu NMAILT rota TETA PAXB PAXH ;
  62. *
  63.    PLR1Z = face 2 EPROU ;
  64.    VECT1 = P21 P22 P23 ;
  65.    FACE3 = face 3 EPROU ;
  66.    POMB1 = (RM*P11) (RM*P12) 0. ;
  67.    PMB1 = EPROU poin proc POMB1 ;
  68.    POMH1 = (RM*P11) (RM*P12) H ;
  69.    PMH1 = EPROU poin proc POMH1 ;
  70.    PLRT0 = EPROU poin plan PIB PEB PMB1 CRITELIM ;
  71.    PLRTHH = EPROU poin plan PIH PEH PMH1 CRITELIM ;
  72.    PLRTH = FACE3 elem appu stri PLRTHH ;
  73. *
  74. *   trac EPROU ;
  75. *
  76. * Modele et materiau
  77. *
  78.    MOD3 = mode EPROU mecanique elastique orthotrope
  79.                                viscoplastique mistral ;
  80. * ------------------------------------------------------------
  81.   SENSIP1 = -2 ; SENSIP2 = -3 ; ICBASE = 0 ;
  82.   fichier = 'CHAINE' DIVERS '/mimatD3r_par' ;
  83.   PDILT    E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  84.   PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  85.     = @mistpar fichier SENSIP1 SENSIP2 ;
  86. * ------------------------------------------------------------
  87.    MAT3 = mate MOD3 'YG1 ' E1    'YG2 ' E2    'YG3 ' E3
  88.                     'NU12' NU12  'NU23' NU23  'NU13' NU13
  89.                     'G12 ' MU12  'G23 ' MU23  'G13 ' MU13
  90.                     'ALP1' 0.     'ALP2' 0.     'ALP3' 0. 'TALP' 0. 'TREF' 300.
  91.                     'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  92.                     'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  93.                     'SIP1' SENSIP1  'SIP2' SENSIP2  'IBAS' ICBASE
  94.                     'RADIAL' PAXB PAXH ;
  95. *
  96. * Conditions aux limites
  97. *
  98. *   CLORT = bloq ortho PAXB PAXH EPROU ;
  99.    CL0 = bloq uy PLR0Z ;
  100.    CL1 = rela depl dire VECT1 PLR1Z ;
  101.    CLB = bloq uz PLRT0 ;
  102.    CLH = rela ense uz PLRTH ;
  103. *
  104.    CL = CL0 et CL1 et CLB et CLH ;
  105. *
  106. * Chargement
  107. *
  108. * -------------------------------------------------------
  109.    T1 = 1.E8 ;
  110.    TEMPSCAL = prog 0. 0.01 0.02 0.05 0.1 0.2
  111.                       0.3  0.4  0.5  0.7 1. ;
  112.    TT0 = 300. ; TT1 = 600. ;
  113.    PHI0 = 1.E18 ;
  114.    SZ0 = 0. ; SZ1 = 100.E6 ;
  115. * -------------------------------------------------------
  116. *
  117.    TEMPS = prog 0. T1 ;
  118.    TEMPSCAL = T1*TEMPSCAL ;
  119. *
  120.    TT = manu chpo EPROU 1 'T' 1. ;
  121.    EVTT = evol manu TEMPS (prog TT0 TT1) ;
  122.    CHTT = char 'T' TT EVTT ;
  123. *
  124.    PHI = manu chpo EPROU 1 'FI' 1. ;
  125.    EVFI = evol manu TEMPS (prog PHI0 PHI0) ;
  126.    CHFI = char 'FI' PHI EVFI ;
  127. *
  128.    PRESH = pres mass MOD3 (-1.) PLRTH ;
  129.    EVSZ = evol manu TEMPS (prog SZ0 SZ1) ;
  130.    CHSZ = char meca PRESH EVSZ ;
  131. *
  132.    CHA = CHTT et CHFI et CHSZ ;
  133. *
  134. * Valeurs initiales
  135. *
  136.    VINT0 = zero MOD3 'VARINTER' ;
  137. *
  138. * Calcul
  139. *
  140.    TAB = TABLE ;
  141.    TAB.'VARIABLES_INTERNES' = TABLE ;
  142.    TAB.'BLOCAGES_MECANIQUES' = CL ;
  143.    TAB.'CARACTERISTIQUES' = MAT3 ;
  144.    TAB.'MODELE' = MOD3 ;
  145.    TAB.'CHARGEMENT' = CHA ;
  146.    TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  147. *   TAB.'GRANDS_DEPLACEMENTS' = VRAI ;
  148.    TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  149.    TAB.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  150.    PASAPAS TAB ;
  151. *
  152. * Traitement des resultats
  153. *
  154.    TEM = TAB.'TEMPS' ;
  155.    SIG = TAB.'CONTRAINTES' ;
  156.    DEP = TAB.'DEPLACEMENTS' ;
  157.    VI  = TAB.'VARIABLES_INTERNES' ;
  158.    NT = dime TEMPSCAL-1 ;
  159. * ---------------
  160.    ERMAX = 0.005 ;
  161. * ---------------
  162.    T = TEM.NT ;
  163.    SIGT = SIG.NT ;
  164.    SIGT_PO = chang chpo MOD3 SIGT ;
  165.    SIGXX = extr SIGT_PO SMXX PMH1 ;
  166.    SIGYY = extr SIGT_PO SMYY PMH1 ;
  167.    SIGZZ = extr SIGT_PO SMZZ PMH1 ;
  168.    SIGXY = extr SIGT_PO SMXY PMH1 ;
  169.    SIGXZ = extr SIGT_PO SMXZ PMH1 ;
  170.    SIGYZ = extr SIGT_PO SMYZ PMH1 ;
  171.    SIGRR = ((P11*P11)*SIGXX)+((P12*P12)*SIGYY)
  172.           +(2.*(P11*P12)*SIGXY) ;
  173.    SIGTT = ((P21*P21)*SIGXX)+((P22*P22)*SIGYY)
  174.           +(2.*(P21*P22)*SIGXY) ;
  175.    SIGRT = ((P11*P21)*SIGXX)+((P12*P22)*SIGYY)
  176.           +(((P11*P22)+(P12*P21))*SIGXY) ;
  177.    SIGRZ = ((P11*P33)*SIGXZ)+((P12*P33)*SIGYZ) ;
  178.    SIGTZ = ((P21*P33)*SIGXZ)+((P22*P33)*SIGYZ) ;
  179. *
  180.    DEPT = DEP.NT ;
  181. *
  182.    UXT = extr DEPT UX PMH1 ;
  183.    UYT = extr DEPT UY PMH1 ;
  184.    URT = (UXT*(COS(TETA)))+(UYT*(SIN(TETA))) ;
  185.    UTT = (UXT*(-1.)*(SIN(TETA)))+(UYT*(COS(TETA))) ;
  186.    EPST = URT/RM ;
  187. *
  188.    EPSIT = epsi DEPT MOD3 'LINE' ;
  189.    EPSIT_PO = chang chpo MOD3 EPSIT ;
  190.    EPSXX = extr EPSIT_PO EPXX PMH1 ;
  191.    EPSYY = extr EPSIT_PO EPYY PMH1 ;
  192.    EPSZZ = extr EPSIT_PO EPZZ PMH1 ;
  193.    EPSXY = (extr EPSIT_PO GAXY PMH1)/2. ;
  194.    EPSXZ = (extr EPSIT_PO GAXZ PMH1)/2. ;
  195.    EPSYZ = (extr EPSIT_PO GAYZ PMH1)/2. ;
  196.    EPSRR = ((P11*P11)*EPSXX)+((P12*P12)*EPSYY)
  197.           +(2.*(P11*P12)*EPSXY) ;
  198.    EPSTT = ((P21*P21)*EPSXX)+((P22*P22)*EPSYY)
  199.           +(2.*(P21*P22)*EPSXY) ;
  200.    EPSRT = ((P11*P21)*EPSXX)+((P12*P22)*EPSYY)
  201.           +(((P11*P22)+(P12*P21))*EPSXY) ;
  202.    EPSRZ = ((P11*P33)*EPSXZ)+((P12*P33)*EPSYZ) ;
  203.    EPSTZ = ((P21*P33)*EPSXZ)+((P22*P33)*EPSYZ) ;
  204. *
  205.    VIT = VI.NT ;
  206.    VIT_PO = chang chpo MOD3 VIT ;
  207.    EPSTHRR = extr VIT_PO ETH1 PMH1 ;
  208.    EPSTHTT = extr VIT_PO ETH2 PMH1 ;
  209.    EPSTHZZ = extr VIT_PO ETH3 PMH1 ;
  210.    EPSTHRZ = extr VIT_PO ETH4 PMH1 ;
  211.    EPSTHRT = extr VIT_PO ETH5 PMH1 ;
  212.    EPSTHTZ = extr VIT_PO ETH6 PMH1 ;
  213.    EPSCRR = extr VIT_PO ECR1 PMH1 ;
  214.    EPSCTT = extr VIT_PO ECR2 PMH1 ;
  215.    EPSCZZ = extr VIT_PO ECR3 PMH1 ;
  216.    EPSCRT = extr VIT_PO ECR4 PMH1 ;
  217.    EPSCRZ = extr VIT_PO ECR5 PMH1 ;
  218.    EPSCTZ = extr VIT_PO ECR6 PMH1 ;
  219. *
  220.    mess ;
  221.    mess 'T :                          ' T ;
  222.    mess ;
  223.    mess 'SIGRR  SIGTT  SIGZZ :    ' SIGRR SIGTT SIGZZ ;
  224.    mess 'SIGRT  SIGRZ  SIGTZ :    ' SIGRT SIGRZ SIGTZ ;
  225.    mess ;
  226.    mess 'UR EPST UT :             ' URT EPST UTT ;
  227.    mess ;
  228.    mess 'EPSRR  EPSTT  EPSZZ :    ' EPSRR EPSTT EPSZZ ;
  229.    mess 'EPSRT  EPSRZ  EPSTZ :    ' EPSRT EPSRZ EPSTZ ;
  230.    mess ;
  231.    mess 'EPSTHRR EPSTHTT EPSTHZZ :' EPSTHRR EPSTHTT EPSTHZZ ;
  232.    mess 'EPSTHRT EPSTHRZ EPSTHTZ :' EPSTHRT EPSTHRZ EPSTHTZ ;
  233.    mess ;
  234.    mess 'EPSCRR EPSCTT EPSCZZ :   ' EPSCRR EPSCTT EPSCZZ ;
  235.    mess 'EPSCRT EPSCRZ EPSCTZ :   ' EPSCRT EPSCRZ EPSCTZ ;
  236.    mess ;
  237. *
  238. *   SIGT_XX = exco SIGT 'SMXX' ;
  239. *   trac SIGT_XX MOD3 ;
  240. *   SIGT_YY = exco SIGT 'SMYY' ;
  241. *   trac SIGT_YY MOD3 ;
  242. *   SIGT_ZZ = exco SIGT 'SMZZ' ;
  243. *   trac SIGT_ZZ MOD3 ;
  244. *   EPST_XX = exco EPSIT 'EPXX' ;
  245. *   trac EPST_XX MOD3 ;
  246. *   EPST_YY = exco EPSIT 'EPYY' ;
  247. *   trac EPST_YY MOD3 ;
  248. *   EPST_ZZ = exco EPSIT 'EPZZ' ;
  249. *   trac EPST_ZZ MOD3 ;
  250. *
  251. * ------------------------------------------------------------
  252.    YOUNGZ = 1.E11 ;
  253.    POISZR = 0.2 ;  POISZT = 0.4 ;
  254. * ------------------------------------------------------------
  255.    EPSTHRR0 = (2.E-5)*(TT1-TT0) ;
  256.    EPSTHTT0 = (1.E-5)*(TT1-TT0) ;
  257.    EPSTHZZ0 = (5.E-6)*(TT1-TT0) ;
  258.    EPSEZZ0 = (SZ1-SZ0)/YOUNGZ ;
  259.    EPSERR0 = (-1.)*POISZR*EPSEZZ0 ;
  260.    EPSETT0 = (-1.)*POISZT*EPSEZZ0 ;
  261.    FITC0 = 1.E18 ;
  262.    T00 = (FITC0/PHI0)**0.5 ;
  263.    T01 = (T1+(FITC0/PHI0))**0.5 ;
  264.    EPSCRR0 = (-1.5E-15)*(PHI0**0.5)*(T01-T00) ;
  265.    EPSCTT0 = (-0.5E-15)*(PHI0**0.5)*(T01-T00) ;
  266.    EPSCZZ0 = (2.E-15)*(PHI0**0.5)*(T01-T00) ;
  267.    EPSRR0 = EPSTHRR0+EPSERR0+EPSCRR0 ;
  268.    EPSTT0 = EPSTHTT0+EPSETT0+EPSCTT0 ;
  269.    EPSZZ0 = EPSTHZZ0+EPSEZZ0+EPSCZZ0 ;
  270. *
  271.    EREPSRR = (EPSRR/EPSRR0) - 1. ;
  272.    EREPSTT = (EPSTT/EPSTT0) - 1. ;
  273.    EREPSZZ = (EPSZZ/EPSZZ0) - 1. ;
  274.    P_ER = prog EREPSRR EREPSTT EREPSZZ ;
  275.    EREPSMA = maxi P_ER 'ABS' ;
  276. *
  277.    EREPSTRR = (EPSTHRR/EPSTHRR0) - 1. ;
  278.    EREPSTTT = (EPSTHTT/EPSTHTT0) - 1. ;
  279.    EREPSTZZ = (EPSTHZZ/EPSTHZZ0) - 1. ;
  280.    P_ER = prog EREPSTRR EREPSTTT EREPSTZZ ;
  281.    EREPSTMA = maxi P_ER 'ABS' ;
  282. *
  283.    EREPSCRR = (EPSCRR/EPSCRR0) - 1. ;
  284.    EREPSCTT = (EPSCTT/EPSCTT0) - 1. ;
  285.    EREPSCZZ = (EPSCZZ/EPSCZZ0) - 1. ;
  286.    P_ER = prog EREPSCRR EREPSCTT EREPSCZZ ;
  287.    EREPSCMA = maxi P_ER 'ABS' ;
  288. *
  289.    si (EREPSMA > ERMAX) ;
  290.     mess ;
  291.     mess 'ABS(erreur rel.) sur EPSRR, EPSTT ou EPSZZ > ' ERMAX ;
  292.     mess EREPSRR EREPSTT EREPSZZ ;
  293.    finsi ;
  294.    si (EREPSTMA > ERMAX) ;
  295.     mess ;
  296.     mess 'ABS(erreur rel.) sur EPSTHRR, EPSTHTT ou EPSTHZZ > ' ERMAX ;
  297.     mess EREPSTRR EREPSTTT EREPSTZZ ;
  298.    finsi ;
  299.    si (EREPSCMA > ERMAX) ;
  300.     mess ;
  301.     mess 'ABS(erreur rel.) sur EPSCRR, EPSCTT ou EPSCZZ > ' ERMAX ;
  302.     mess EREPSCRR EREPSCTT EREPSCZZ ;
  303.     mess ;
  304.    finsi ;
  305.    P_ER = prog EREPSMA EREPSTMA EREPSCMA ;
  306.    ERMA = maxi P_ER ;
  307.    si (ERMA > ERMAX) ;
  308.     ERRE 5 ;
  309.    finsi ;
  310.  
  311.    fin ;
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales