Télécharger la plaquette Cast3M


fr en

Télécharger mfil.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier mfil.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Filtering of a field using a rigidity matrix genrated by MFIL.
  7. **
  8. ** Author:
  9. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  10. **
  11. ** Version:
  12. ** 1.0 2021/01/04 Original version compatible with MFIL V1.0
  13. ** 1.1 2021/01/07 Version compatible with MFIL V1.1
  14. ************************************************************************
  15.  
  16. * General options
  17. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4' ;
  18. graph0 = FAUX ;
  19.  
  20. * Filtering radius
  21. r0 = 5.0 ;
  22.  
  23. * Mesh
  24. p0 = 0.0 0.0 ;
  25. p1 = 0.0 100.0 ;
  26. p2 = 100.0 0.0 ;
  27. lgn0 = DROI 100 p1 p0 ;
  28. msh0 = TRAN lgn0 100 p2 ;
  29.  
  30. * Model
  31. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  32. * Material
  33. mat0 = MATE mod0 'YOUN' 200.0e9 'NU' 0.3 'RHO' 1.0 ;
  34.  
  35. * Volume node field (as rho = 1)
  36. vol0 = EXCO 'FX' ((MASS mod0 mat0) * (MANU 'CHPO' msh0 1 'UX' 1.0)) ;
  37. * Filtering matrix
  38. H  = MFIL vol0 r0 ;
  39. * Normalized matrix (by the sum of the weights of each row)
  40. un = MANU 'CHPO' msh0 1 'SCAL' 1. ;
  41. Hs = H * un ;
  42. Hn = NFIL H Hs ;
  43.  
  44. * Create a node field to be filtered
  45. pnt0 = ((msh0 POIN 'DROI' (100.0 0.0) (60.0 100.0) 10.0) 
  46.               POIN 'DROI' (0.0  60.0) (100.0 60.0) 30.0)
  47.      ET (msh0 POIN 'SPHE' (40.0 30.0) (40.0 50.0) 5.0)
  48.      ET (msh0 POIN 'SPHE' (-50.0 150.0) (50.0 150.0) 15.0) ;
  49. field0 = (MANU 'CHPO' msh0 1 'SCAL' 0.0 'NATURE' 'DIFFUS')
  50.        + (MANU 'CHPO' pnt0 1 'SCAL' 1.0 'NATURE' 'DIFFUS') ;
  51.  
  52. * Filter the node field
  53. field1 = Hn * field0 ;
  54.  
  55. * Plot the field to screen before filtering
  56. SI graph0 ;
  57.     TRAC field0 (msh0 CHAN 'POI1') ;
  58.     TRAC field0 msh0 ;
  59. FINS ;
  60.  
  61. * Plot the field to screen after filtering
  62. SI graph0 ;
  63.     TRAC field1 (msh0 CHAN 'POI1') ;
  64.     TRAC field1 msh0 ;
  65. FINS ;
  66.  
  67. FIN ;
  68.  
  69.  
  70.  
  71.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales