Exemples de jeux de données Cast3M

* fichier : mato-2d6.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-2D6
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un simple
*               cercle de manière régulière en quadratique.
*
*               On teste la qualité des éléments obtenus.
*
*               Issu de mato-2d1.dgibi
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 04/10/2020, version initiale
* HISTORIQUE : v1, 04/10/2020, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
*
* Mini, mediane et maxi d'un LISTREEL
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI6' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0. 'PAS' 0.05 1. ;
ldens1 = 'PROG' 0.5 'PAS' 0.05  1. ;
ldens2 = 'PROG' 0.9 'PAS' -0.05  0.5 ;
ldens  = ldens1 'ET' (ldens2 '**' -1.) ;
*
for = '(E11.3)' ;
*
tol= ('VALE' prec) '*' 10. ;
*
* Création du contour
*
*vden = 1.4 ;
vden = 0.28 ;
'OPTI' 'DENS' vden ;
pC = 1.1 0.707 ; pA = 3.14 3.41 ;
cnt = 'CERC' 'ROTA' 360. pA pC 'ELIM' ;
cntl = 'CHAN' 'LINE' cnt ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
*   tparam = 'TABL' ;
*   tparam . 'debug' = 0  ;
*   tparam . 'graph' = vrai  ;
*   mail1 = MAILTOPO 'TRIA' cnt 'NOAJ' tparam ;
   mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
   mail1l = 'CHAN' 'LINE' mail1 ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cntl ;
nno2 = 'NBNO' mail1l ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Création d'un maillage en ajoutant des noeuds interieurs
*
   mail2 = 'TRIA' 'TOPO' cnt 'AJNO' ;
   mail2l = 'CHAN' 'LINE' mail2 ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs' ;
      'TRAC' mail2l 'TITR' tit 'NOEU' ;
*      'TRAC' mail2l 'TITR' tit ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' 'EQLT' mail2l ;
miqo meqo maqo = MIMEMA qmail2 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail2 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2l 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'EQLT' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 04/10/2024 : qmin=0.10 qmoy=0.10 qmax=0.10
*miqr = 0.09 ; meqr = 0.09 ; maqr = 0.09 ;
* 2025/11/21
miqar = 0.13 ; meqar = 0.13 ; maqar = 0.13 ;
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 2 failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
* Partie REMA
mail2b = 'REMA' mail2 ('CONT' mail2) ;
mail2bl = 'CHAN' 'LINE' mail2b ;
* Qualités
qmail2b = 'INDI' 'TOPO' mail2bl ;
miq meq maq = MIMEMA qmail2b 'TOPO' ;
'MESS'  'FORMAT' for ' REMA : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
'SI' graph ;
   momail2b = 'MODE' mail2bl 'THERMIQUE' ;
   tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs apres REMA'
      ' sans metrique';
   'TRAC' qmail2b momail2b lqual 'TITR' tit ;
'FINSI' ;
*
* TEST 3  Remaillage du précédent avec une métrique uniforme constante
*         en espace
*
metva = vden ;
mail3 = 'REMA' mail2 ('CONT' mail2) metva  ;
mail3l = 'CHAN' 'LINE' mail3 ;
'SI' graph ;
   tit = 'CHAI' 'Maillage avec metrique constante uniforme' ;
   'TRAC' mail3 'TITR' tit ;
'FINSI' ;
* Test 3 : on vérifie que les qualités mini et mediane des éléments sont
* bonnes
qmail3 = 'INDI' 'TOPO' 'COHE' 'DENS' mail3l metva ;
miq meq maq = MIMEMA qmail3 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail3 'COHE' ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3l 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 02/04/2020 : qmin=0.624 qmoy=0.847 qmax=1.00
*miqr = 0.61 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/21
* miqar = 0.61 ; meqar = 0.92 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.13 ; meqar = 0.13 ; maqar = 0.13 ;
* 2026/06/05
miqar = 0.69 ; meqar = 0.92 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail3 'DENS' ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail3) momail3 ldens 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 02/04/2020 : qmin=0.624 qmoy=0.847 qmax=1.00
*miqr = 0.61 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/21
* miqer = 0.55 ; meqer = 0.86 ; maqer = 0.99 ;
* 2026/01/08
*miqer = 0.26 ; meqer = 0.26 ; maqer = 0.26 ;
* 2026/06/05
miqer = 0.59 ; meqer = 0.86 ; maqer = 1.14 ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('&lt;EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 3 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ isotrope
* constant, on ne modifie pas le maillage
*
vcnx = '**' vden -2 ;
cmet = 'MANU' 'CHPO' mail3 1 'G' vcnx ;
tparam = 'TABL' ; tparam . 'nbpasses_rema' = 1 ;
mail4 = 'REMA' mail3 ('CONT' mail3) cmet tparam ;
mail4l = 'CHAN' 'LINE' mail4 ;
* Test 4 : on vérifie que mail4 et mail3 sont identiques ainsi que les
* qualités
dn34= 'NBEL' ('DIFF' mail3 mail4) ;
'SI' ('NEG' dn34 0) ;
   'MESS' '!!! TEST 4 : mail3 .NE. mail4' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail4 = 'INDI' 'TOPO' 'COHE' 'DENS' mail4l cmet ;
qmail4 = 'REDU' qmail4 mail3l ;
dq34 = 'MAXI' ('-' qmail4 qmail3) 'ABS' ;
'SI' ('>' dq34 tol) ;
   'MESS' '!!! TEST 4 : qmail3 .NE. qmail4' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ anisotrope
* constant, on ne modifie pas le maillage
*
vcnx = '**' vden -2 ;
cmet = 'MANU' 'CHPO' mail3 3 'G11' vcnx 'G22' vcnx
       'G21' 0. ;
tparam = 'TABL' ; tparam . 'nbpasses_rema' = 1 ;
mail5 = 'REMA' mail3 ('CONT' mail3) cmet tparam ;
mail5l = 'CHAN' 'LINE' mail5 ;
* Test 5 : on vérifie que mail5 et mail3 sont identiques ainsi que les
* qualités
dn35= 'NBEL' ('DIFF' mail3 mail5) ;
'SI' ('NEG' dn35 0) ;
   'MESS' '!!! TEST 5 : mail3 .NE. mail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail5 = 'INDI' 'TOPO' 'COHE' 'DENS' mail5l cmet ;
qmail5 = 'REDU' qmail5 mail3l ;
dq35 = 'MAXI' ('-' qmail5 qmail3) 'ABS' ;
* VALE prec un peu trop serré pour semt2
'SI' ('>' dq35 tol) ;
   'MESS' '!!! TEST 5 : qmail3 .NE. qmail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D6
*
'FIN' ;