Accueil | Cast3M

* fichier : mato-2d5.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 1 ;
************************************************************************
* NOM         : MATO-2D5
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un simple
*               cercle de manière régulière en quadratique.
*
*               On teste la qualité des éléments obtenus.
*
*               Issu de mato-2d1.dgibi
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 04/10/2020, version initiale
* HISTORIQUE : v1, 04/10/2020, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
complet  = FAUX ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI6' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0.5 'PAS' 0.025 1. ;
*
* Création du contour
*
*vden = 1.4 ;
vden = 0.28 ;
'OPTI' 'DENS' vden ;
pC = 1.1 0.707 ; pA = 3.14 3.41 ;
cnt = 'CERC' 'ROTA' 360. pA pC 'ELIM' ;
cntl = 'CHAN' 'LINE' cnt ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit 'NOEU' ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
*   tparam = 'TABL' ;
*   tparam . 'debug' = 0  ;
*   tparam . 'graph' = vrai  ;
*   mail1 = MAILTOPO 'TRIA' cnt 'NOAJ' tparam ;
   mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
   mail1l = 'CHAN' 'LINE' mail1 ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cntl ;
nno2 = 'NBNO' mail1l ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Création d'un maillage en ajoutant des noeuds interieurs
*
   mail2 = 'TRIA' 'TOPO' cnt 'AJNO' ;
   mail2l = 'CHAN' 'LINE' mail2 ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs' ;
      'TRAC' mail2 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, moyenne et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' mail2l ;
miq = 'MINI' qmail2 ; moq = MATOUTIL 'MOYECHAM' qmail2 ;
maq = 'MAXI' qmail2 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qmin=' miq ' Qmoy=' moq ' Qmax=' maq ;
   'SI' graph ;
      momail2 = 'MODE' mail2l 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite maillage avec noeuds interieurs' ;
      'TRAC' qmail2 momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 04/10/2024 : qmin=0.10 qmoy=0.10 qmax=0.10
miqref = 0.09 ; moqref = 0.09 ; maqref = 0.09 ;
'SI' ('&lt;EG' miq miqref) ;
   'MESS' '!!! TEST 2 : miq=' miq ' < miqref=' miqref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' moq moqref) ;
   'MESS' '!!! TEST 2 : moq=' moq ' < moqref=' moqref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maq maqref) ;
   'MESS' '!!! TEST 2 : maq=' maq ' < maqref=' maqref ;
   lok = lok 'ET' faux ;
'FINS' ;
* Partie REMA
mail2b = 'REMA' mail2 ('CONT' mail2) ;
mail2bl = 'CHAN' 'LINE' mail2b ;
* Qualités
qmail2b = 'INDI' 'TOPO' mail2bl ;
miq = 'MINI' qmail2b ; moq = MATOUTIL 'MOYECHAM' qmail2b ;
maq = 'MAXI' qmail2b ;
'MESS'  'FORMAT' '(E9.2)' tit ' mailtopo : Qmin=' miq ' Qmoy=' moq ' Qmax=' maq ;
'SI' graph ;
   momail2b = 'MODE' mail2b 'THERMIQUE' ;
   titg = 'CHAI' tit ' mailtopo' ;
   'TRAC' qmail2b momail2b lqual 'TITR' titg ;
'FINSI' ;
*
* TEST 3  Remaillage du précédent avec une métrique uniforme constante
*         en espace
*
metva = vden ;
mail3 = 'REMA' mail2 ('CONT' mail2) metva  ;
mail3l = 'CHAN' 'LINE' mail3 ;
'SI' graph ;
   tit = 'CHAI' 'Maillage avec metrique constante uniforme' ;
   'TRAC' mail3 'TITR' tit 'NOEU' ;
'FINSI' ;
* Test 3 : on vérifie que les qualités mini et moyenne des éléments sont
* bonnes
qmail3 = 'INDI' 'TOPO' mail3l metva ;
miq = 'MINI' qmail3 ; moq = MATOUTIL 'MOYECHAM' qmail3 ;
maq = 'MAXI' qmail3 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qmin=' miq ' Qmoy=' moq ' Qmax=' maq ;
'SI' graph ;
   momail3 = 'MODE' mail3l 'THERMIQUE' ;
   tit = 'CHAI' 'Qualite maillage avec noeuds interieurs' ;
   'TRAC' qmail3 momail3 lqual 'TITR' tit ;
'FINSI' ;
* Sur mon linux64 au 04/10/2024 : Qmin= 0.63E+00 Qmoy= 0.86E+00 Qmax= 0.99E+00
miqref = 0.62 ; moqref = 0.85 ; maqref = 0.98 ;
'SI' ('&lt;EG' miq miqref) ;
   'MESS' '!!! TEST 3 : miq=' miq ' < miqref=' miqref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' moq moqref) ;
   'MESS' '!!! TEST 3 : moq=' moq ' < moqref=' moqref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maq maqref) ;
   'MESS' '!!! TEST 3 : maq=' maq ' < maqref=' maqref ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ isotrope
* constant, on ne modifie pas le maillage
*
vcnx = '**' vden -2 ;
cmet = 'MANU' 'CHPO' mail3 1 'G' vcnx ;
mail4 = 'REMA' mail3 ('CONT' mail3) cmet ;
mail4l = 'CHAN' 'LINE' mail4 ;
* Test 4 : on vérifie que mail4 et mail3 sont identiques ainsi que les
* qualités
dn34= 'NBEL' ('DIFF' mail3 mail4) ;
'SI' ('NEG' dn34 0) ;
   'MESS' '!!! TEST 4 : mail3 .NE. mail4' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail4 = 'INDI' 'TOPO' mail4l cmet ;
qmail4 = 'REDU' qmail4 mail3l ;
*dq34 = 'MAXI' ('-' ('REDU' qmail4 mail3) qmail3) 'ABS' ;
dq34 = 'MAXI' ('-' qmail4 qmail3) 'ABS' ;
* VALE prec un peu trop serré pour semt2
'SI' ('>' dq34 ('*' ('VALE' 'PREC') 10.)) ;
   'MESS' '!!! TEST 4 : qmail3 .NE. qmail4' ;
   'LIST' 'RESU' dq34 ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ anisotrope
* constant, on ne modifie pas le maillage
*
vcnx = '**' vden -2 ;
cmet = 'MANU' 'CHPO' mail3 3 'G11' vcnx 'G22' vcnx
       'G21' 0. ;
mail5 = 'REMA' mail3 ('CONT' mail3) cmet ;
mail5l = 'CHAN' 'LINE' mail5 ;
* Test 5 : on vérifie que mail5 et mail3 sont identiques ainsi que les
* qualités
dn35= 'NBEL' ('DIFF' mail3 mail5) ;
'SI' ('NEG' dn35 0) ;
   'MESS' '!!! TEST 5 : mail3 .NE. mail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail5 = 'INDI' 'TOPO' mail5l cmet ;
qmail5 = 'REDU' qmail5 mail3l ;
dq35 = 'MAXI' ('-' qmail5 qmail3) 'ABS' ;
* VALE prec un peu trop serré pour semt2
'SI' ('>' dq35 ('*' ('VALE' 'PREC') 10.)) ;
   'MESS' '!!! TEST 5 : qmail3 .NE. qmail5' ;
   'LIST' 'RESU' dq35 ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D5
*
'FIN' ;