Télécharger mato-2d4.dgibi

Retour à la liste

* fichier : mato-2d4.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-2D4
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un carré
*               avec une métrique isotrope constante en espace
*               dans le but d'obtenir 10x10 mailles.
*               Au départ, le carré est 1x1. Concernant la frontière,
*               on contraint le mailleur, soit à ne pas la modifier,
*               soit à en modifier une partie, soit la totalité.
*
*               On teste la qualité des éléments obtenus.
*
*               Issu de 2d_9.dgibi+tests
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 07/04/2020, version initiale
* HISTORIQUE : v1, 07/04/2020, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
* Mini, mediane et maxi d'un LISTREEL
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI3' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0. 'PAS' 0.05 1. ;
*
* Création du contour
*
nx = 2 ; nv = 10 ;
pA = 0. 0. ; pB = 1. 0. ; pC = 1. 1. ; pD = 0. 1. ;
lAB = 'DROI' nx pA pB ;
lBC = 'DROI' nx pB pC ;
lCD = 'DROI' nx pC pD ;
lDA = 'DROI' nx pD pA ;
*
cnt = lAB 'ET' lBC 'ET' lCD 'ET' lDA ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit 'NOEU' ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
   mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cnt ;
nno2 = 'NBNO' mail1 ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Remaillage de mail1 avec une taille voulue de 0.1 sans
*         toucher le bord
*
   mail2 = 'REMA' mail1 ('CONT' mail1) ('/' 1. nv) ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher le bord' ;
      'TRAC' mail2 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' 'COHE' 'DENS' mail2 ('/' 1. nv) ;
miqo meqo maqo = MIMEMA qmail2 'TOPO' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail2 'COHE' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.91E-01 Qmoy= 0.82E+00 Qmax= 0.10E+01
*!!!! Mieux    miqr = 0.08 ; meqr = 0.81 ; maqr = 0.99 ;
*miqr = 0.02 ; meqr = 0.79 ; maqr = 0.99 ;
* 2025/11/24
*!!!! Mieux ou different ?? miqar = 0.08 ; meqar = 0.89 ; maqar = 0.99 ;
* 2025/11/24
*miqar = 0.86 ; meqar = 0.86 ; maqar = 0.86 ;
* 2026/01/08
miqar = 0.55 ; meqar = 0.87 ; maqar = 0.99 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 2 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail2 'DENS' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.91E-01 Qmoy= 0.82E+00 Qmax= 0.10E+01
*!!!! Mieux    miqr = 0.08 ; meqr = 0.81 ; maqr = 0.99 ;
*miqr = 0.02 ; meqr = 0.79 ; maqr = 0.99 ;
* 2025/11/24
*miqer = 0.14 ; meqer = 0.80 ; maqer = 0.99 ;
* 2025/11/24
miqer = 0.26 ; meqer = 0.53 ; maqer = 0.88 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('<EG' meqe meqer) 'OU' ('<EG' maqe maqer)) ;
   'MESS' '!!! TEST 2 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 3  Remaillage de mail1 avec une taille voulue de 0.1 en touchant
*         le bord sauf lAB
*
   mail3 = 'REMA' mail1 lAB ('/' 1. nv) ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher lAB' ;
      'TRAC' mail3 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 3 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail3 = 'INDI' 'TOPO' 'COHE' 'DENS' mail3 ('/' 1. nv) ;
miq meq maq = MIMEMA qmail3 'TOPO' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail3 'COHE' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.13E+00 Qmoy= 0.90E+00 Qmax= 0.10E+01
*!!!!!!!Mieux   miqr = 0.12 ; meqr = 0.89 ; maqr = 0.99 ;
*miqr = 0.0076 ; meqr = 0.02 ; maqr = 0.02 ;
* 2025/11/24
*!!!! Mieux ou different ?? miqar = 0.11 ; meqar = 0.89 ; maqar = 0.99 ;
* 2025/11/24 new
*miqar = 0.80 ; meqar = 0.86 ; maqar = 0.97 ;
* 2026/01/08
miqar = 0.76 ; meqar = 0.87 ; maqar = 0.98 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail3 'DENS' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
*!!!!! Mieux miqer = 0.13 ; meqer = 0.82 ; maqer = 0.99 ;
* 2025/11/24 new
*miqer = 0.08 ; meqer = 0.20 ; maqer = 0.89 ;
* 2026/01/08
miqer = 0.27 ; meqer = 0.73 ; maqer = 0.99 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('<EG' meqe meqer) 'OU' ('<EG' maqe maqer)) ;
   'MESS' '!!! TEST 3 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  Remaillage de mail1 avec une taille voulue de 0.1 en touchant
*         tout le bord
*
   mail4 = 'REMA' mail1 ('/' 1. nv) ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en modifiant le bord' ;
      'TRAC' mail4 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 4 : on vérifie que les qualités mini, mediane etmaxi des éléments sont bonnes
qmail4 = 'INDI' 'TOPO' 'COHE' 'DENS' mail4 ('/' 1. nv) ;
miq meq maq = MIMEMA qmail4 'TOPO' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail4 'COHE' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail4 = 'MODE' mail4 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail4) momail4 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.65E+00 Qmoy= 0.91E+00 Qmax= 0.10E+01
*!!!!! Mieux  miqr = 0.64 ; meqr = 0.90 ; maqr = 0.99 ;
* 2025/11/24
* !!!! Pas si mal miqar = 0.57 ; meqar = 0.90 ; maqar = 0.99 ;
* 2025/11/24 new
*miqar = 0.73 ; meqar = 0.88 ; maqar = 0.99 ;
* 2026/01/08
miqar = 0.81 ; meqar = 0.90 ; maqar = 0.99 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail4 'DENS' ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail4) momail4 lqual 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
*miqer = 0.59 ; meqer = 0.86 ; maqer = 0.99 ;
* 2026/01/08
miqer = 0.62 ; meqer = 0.76 ; maqer = 0.99 ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('<EG' meqe meqer) 'OU' ('<EG' maqe maqer)) ;
   'MESS' '!!! TEST 4 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  Remaillage de mail4 avec une taille voulue de 0.1 en ne touchant
*         plus le bord. On s'attend à ne pas changer le maillage mais
*         c'est sans compter avec l'algorithme du noeud fictif qui nous
*         a deja fait des blagues
*
   mail5 = 'REMA' mail4 ('CONT' mail4) ('/' 1. nv) ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere sans toucher le bord' ;
      'TRAC' mail5 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 5 : on vérifie que mail5 et mail4 sont identiques ainsi que les
* qualités
dn45= 'NBEL' ('DIFF' mail4 mail5) ;
'SI' ('NEG' dn45 0) ;
   'MESS' '!!! TEST 5 : mail4 .NE. mail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D4
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales