Accueil | Cast3M

* fichier : mato-2d3.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-2D3
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un carré de
*               avec une métrique anisotrope constante en espace
*               dans le but d'obtenir 10x20 mailles, puis 20x10 mailles
*               en autorisant le mailleur à modifier les noeuds du bord
*               dans ce dernier cas.
*
*               On teste la qualité des éléments obtenus.
*               On améliore un peu la qualité du dernier maillage obtenu
*               avec une boucle entre r-adaptation (DEDU ADAP) et
*               remaillage.
*
*               Issu de 2d_3.dgibi+tests
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 07/04/2020, version initiale
* HISTORIQUE : v1, 07/04/2020, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
* Mini, mediane et maxi d'un LISTREEL
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI3' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0. 'PAS' 0.05 1. ;
ldens1 = 'PROG' 0.5 'PAS' 0.05  1. ;
ldens2 = 'PROG' 0.9 'PAS' -0.05  0.5 ;
ldens  = ldens1 'ET' (ldens2 '**' -1.) ;
*
for = '(E11.3)' ;
*
* Création du contour
*
d1 = 0.1 ; d2 = 0.05 ;
pA = 0. 0. ; pB = 1. 0. ; pC = 1. 1. ; pD = 0. 1. ;
lAB = 'DROI' pA pB 'DINI' d1 'DFIN' d1 ;
lBC = 'DROI' pB pC 'DINI' d2 'DFIN' d2 ;
lCD = 'DROI' pC pD 'DINI' d1 'DFIN' d1 ;
lDA = 'DROI' pD pA 'DINI' d2 'DFIN' d2 ;
*
cnt = lAB 'ET' lBC 'ET' lCD 'ET' lDA ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit 'NOEU' ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
   mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cnt ;
nno2 = 'NBNO' mail1 ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Création d'un maillage en ajoutant des noeuds interieurs
*
   mail2 = 'TRIA' 'TOPO' cnt ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs' ;
      'TRAC' mail2 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' 'EQLT' mail2 ;
miqo meqo maqo = MIMEMA qmail2 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail2 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'EQLT' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 :  Qmin= 0.66E+00 Qmed= 0.87E+00 Qmax= 0.10E+01
*miqr = 0.65 ; meqr = 0.86 ; maqr = 0.99 ;
*
* 2025/11/24
*miqar = 0.58 ; meqar = 0.82 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.62 ; meqar = 0.85 ; maqar = 0.99 ;
* 2026/06/04
miqar = 0.67 ; meqar = 0.85 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 2 failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2b  Création d'un maillage en ajoutant/retirant des noeuds interieurs et de bord
*
mail2b = 'TRIA' 'TOPO' cnt ('VIDE' 'MAILLAGE'/'SEG2') 'AJNO' ;
'SI' graph ;
   tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs et de bord' ;
   'TRAC' mail2b 'TITR' tit 'NOEU' ;
'FINSI' ;
* Test 2 : on vérifie que les qualités mini, moyenne et maxi des éléments sont bonnes
qmail2b = 'INDI' 'EQLT' mail2b ;
miqa meqa maqa = MIMEMA qmail2b 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 2b : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail2b = 'MODE' mail2b 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs et de bord' ;
      'TRAC' qmail2b momail2b lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 16/12/2025 : qmin=0.86 qmoy=0.86 qmax=0.86
* Il ne reste que deux elements dans le carre
miqar = 0.86 ; meqar = 0.86 ; maqar = 0.86 ;
'MESS'  'FORMAT' for 'TEST 2b : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 2b failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 3  Remaillage du précédent avec une métrique anisotrope constante
*         en espace compatible avec le maillage du bord 10x20
*
   cmet = 'MANU' 'CHPO' mail2 3 'G11' ('**' d1 -2)
                                'G22' ('**' d2 -2)
                                'G21' 0. ;
* Facultatif : mettre tout ça dans la notice de ALGOMAIL
*              ainsi que les valeurs par défaut
*   tparam3 . 'debug' = 2 ;
   mail3 = 'REMA' mail2 ('CONT' mail2) cmet ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage avec metrique 10x20' ;
      'TRAC' mail3 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 3 : on vérifie que les qualités des éléments sont bonnes
   cmet = 'MANU' 'CHPO' mail3 3 'G11' ('**' d1 -2)
                                'G22' ('**' d2 -2)
                                'G21' 0. ;
qmail3 = 'INDI' 'TOPO' 'COHE' 'DENS' mail3 cmet ;
miq meq maq = MIMEMA qmail3 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail3 'COHE' ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.66E+00 Qmoy= 0.84E+00 Qmax= 0.10E+01
*!!!!!!! Mieux miqr = 0.65 ; meqr = 0.83 ; maqr = 0.99 ;
*miqr = 0.60 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/24
*!!!!! Mieuxmiqar = 0.67 ; meqar = 0.91 ; maqar = 0.99 ;
* 2025/11/24 new
* miqar = 0.58 ; meqar = 0.91 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.69 ; meqar = 0.94 ; maqar = 0.99 ;
* 2026/06/04
miqar = 0.64 ; meqar = 0.93 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail3 'DENS' ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail3) momail3 ldens 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
*miqer = 0.55 ; meqer = 0.85 ; maqer = 0.99 ;
* 2026/01/08
*miqer = 0.49 ; meqer = 0.71 ; maqer = 0.97 ;
* 2026/06/04
miqer = 0.60 ; meqer = 0.86 ; maqer = 1.13 ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('&lt;EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 3 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  Remaillage du précédent avec une métrique anisotrope constante
*         en espace différente visant à obtenir un maillage 20x10
*         On demande au remailleur de modifier les noeuds du bord.
*
   cmet = 'MANU' 'CHPO' mail3 3 'G11' ('**' d2 -2)
                                'G22' ('**' d1 -2)
                                'G21' 0. ;
 
   mail4 = 'REMA' mail3 cmet ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage avec metrique anisotrope 20x10' ;
      'TRAC' mail4 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 4 : on vérifie que les qualités des éléments sont bonnes
   cmet = 'MANU' 'CHPO' mail4 3 'G11' ('**' d2 -2)
                                'G22' ('**' d1 -2)
                                'G21' 0. ;
qmail4 = 'INDI' 'TOPO' 'COHE' 'DENS' mail4 cmet ;
miq meq maq = MIMEMA qmail4 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 4 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail4 'COHE' ;
'MESS'  'FORMAT' for 'TEST 4 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail4 = 'MODE' mail4 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail4) momail4 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.67E+00 Qmoy= 0.85E+00 Qmax= 0.10E+01
*!!!! Mieux miqr = 0.65 ; meqr = 0.83 ; maqr = 0.99 ;
*miqr = 0.42 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/24
*!!!! Mieux miqar = 0.68 ; meqar = 0.92 ; maqar = 0.99 ;
* 2025/11/24 new
*miqar = 0.62 ; meqar = 0.90 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.75 ; meqar = 0.93 ; maqar = 0.99 ;
* 2026/06/04
miqar = 0.62 ; meqar = 0.94 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 4 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 4 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail4 'DENS' ;
'MESS'  'FORMAT' for 'TEST 4 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail4) momail4 ldens 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
*!!!!! Mieux miqer = 0.55 ; meqer = 0.86 ; maqer = 0.99 ;
* 2025/11/24
*miqer = 0.55 ; meqer = 0.85 ; maqer = 0.99 ;
* 2026/01/08
*miqer = 0.47 ; meqer = 0.68 ; maqer = 0.99 ;
* 2026/06/04
miqer = 0.61 ; meqer = 0.87 ; maqer = 1.12 ;
'MESS'  'FORMAT' for 'TEST 4 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('&lt;EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 4 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  Une petite boucle avec de la r-adaptation (DEDU ADAP) pour voir si on peut
* améliorer la qualité du maillage mail3.
*
* La réponse est oui, on peut effectivement avoir une amélioration mais
* après quelque itérations la qualité oscille sans s'alméliorer entre
* r-adaptation et remaillage car les critères optimisés ne sont pas les
* mêmes aux deux étapes.
*
nopt = 2 ; iopt = 0 ;
* Paramètres de DEDUADAP
thdedu = 0.2 ; rdepa = 1. ; nitm = 1 ;
maili = mail4 ;
ldep = 'PROG' ; lqmin = 'PROG' ; lqmed = 'PROG' ;
'REPE' bclopt nopt ;
   iopt = iopt '+' 1 ;
   tit = 'CHAI' 'i=' iopt ;
* Partie DEDUADAP
   maili1 = maili ;
   modi1 = 'MODE' maili1 'MECANIQUE' ;
   cmet = 'MANU' 'CHPO' maili1 3 'G11' ('**' d2 -2)
                                 'G22' ('**' d1 -2)
                                 'G21' 0. ;
   ccmet = 'CHAN' 'CHAM' cmet modi1 ;
   depa = 'DEDU' 'ADAP' maili1 'METR' ccmet modi1 'THET' thdedu 'NITM' nitm ;
   depa = '*' depa rdepa ;
   mcdep = 'MAXI' depa 'ABS' ; ldep = ldep 'ET' mcdep ;
   'MESS' tit ' dedu max. dep=' mcdep ;
   'FORM' depa ;
   qmaili1 = 'INDI' 'TOPO' 'COHE' 'DENS' maili1 cmet ;
   miq meq maq = MIMEMA qmaili1 'TOPO' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   miq meq maq = MIMEMA qmaili1 'COHE' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qcohemin=' miq ' Qcohemed=' meq ' Qcohemax=' maq ;
   miq meq maq = MIMEMA qmaili1 'DENS' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qdensmin=' miq ' Qdensmed=' meq ' Qdensmax=' maq ;
   'SI' graph ;
      momaili1 = 'MODE' maili1 'THERMIQUE' ;
      vdep = 'VECT' depa -1. 'UX' 'UY' 'NOIR' ;
      titg = 'CHAI' tit ' deduadap' ;
      'TRAC' ('EXCO' 'TOPO' qmaili1) momaili1 vdep maili1 lqual 'TITR' titg ;
   'FINS' ;
* Partie MAILTOPO
   maili2 = 'REMA' maili1 cmet ;
* Qualités
   cmet = 'MANU' 'CHPO' maili2 3 'G11' ('**' d2 -2)
                                 'G22' ('**' d1 -2)
                                 'G21' 0. ;
   qmaili2 = 'INDI' 'TOPO' 'COHE' 'DENS' maili2 cmet ;
   miq meq maq = MIMEMA qmaili2 'TOPO' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   miqa meqa maqa = MIMEMA qmaili2 'COHE' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   miqe meqe maqe = MIMEMA qmaili2 'DENS' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      momaili2 = 'MODE' maili2 'THERMIQUE' ;
      titg = 'CHAI' tit ' mailtopo' ;
      'TRAC' ('EXCO' 'TOPO' qmaili2) momaili2 lqual 'TITR' titg ;
   'FINSI' ;
   maili = maili2 ;
'FIN' bclopt ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.68E+00 Qmoy= 0.89E+00 Qmax= 0.10E+01
*!!!!! Mieux miqr = 0.67 ; meqr = 0.88 ; maqr = 0.99 ;
*miqr = 0.43 ; meqr = 0.88 ; maqr = 0.99 ;
* 2025/11/24
*miqar = 0.73 ; meqar = 0.93 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.73 ; meqar = 0.94 ; maqar = 0.99 ;
* 2026/06/04
miqar = 0.68 ; meqar = 0.94 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 5 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('&lt;EG' miqa miqar) 'OU' ('&lt;EG' meqa meqar) 'OU' ('&lt;EG' maqa maqar)) ;
   'MESS' '!!! TEST 5 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
* 2025/11/24
* miqer = 0.54 ; meqer = 0.92 ; maqer = 0.99 ;
* 2026/01/08
*miqer = 0.51 ; meqer = 0.68 ; maqer = 0.99 ;
* 2026/06/04
miqer = 0.68 ; meqer = 0.87 ; maqer = 1.13 ;
'MESS'  'FORMAT' for 'TEST 5 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('&lt;EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 5 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D3
*
'FIN' ;