Télécharger mato-2d3.dgibi

Retour à la liste

* fichier : mato-2d3.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-2D3
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un carré de
*               avec une métrique anisotrope constante en espace
*               dans le but d'obtenir 10x20 mailles, puis 20x10 mailles
*               en autorisant le mailleur à modifier les noeuds du bord
*               dans ce dernier cas.
*
*               On teste la qualité des éléments obtenus.
*               On améliore un peu la qualité du dernier maillage obtenu
*               avec une boucle entre r-adaptation (DEDU ADAP) et
*               remaillage.
*
*               Issu de 2d_3.dgibi+tests
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 07/04/2020, version initiale
* HISTORIQUE : v1, 07/04/2020, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
* Mini, mediane et maxi d'un LISTREEL
'DEBP' MIMEMA ;
'ARGU' lr ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI3' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0.5 'PAS' 0.025 1. ;
*
* Création du contour
*
d1 = 0.1 ; d2 = 0.05 ;
pA = 0. 0. ; pB = 1. 0. ; pC = 1. 1. ; pD = 0. 1. ;
lAB = 'DROI' pA pB 'DINI' d1 'DFIN' d1 ;
lBC = 'DROI' pB pC 'DINI' d2 'DFIN' d2 ;
lCD = 'DROI' pC pD 'DINI' d1 'DFIN' d1 ;
lDA = 'DROI' pD pA 'DINI' d2 'DFIN' d2 ;
*
cnt = lAB 'ET' lBC 'ET' lCD 'ET' lDA ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit 'NOEU' ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
   mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
   'SI' graph ;
      tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
      'TRAC' mail1 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cnt ;
nno2 = 'NBNO' mail1 ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2  Création d'un maillage en ajoutant des noeuds interieurs
*
   mail2 = 'TRIA' 'TOPO' cnt ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs' ;
      'TRAC' mail2 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 2 : on vérifie que les qualités mini, mediane et maxi des éléments sont bonnes
qmail2o = 'INDI' 'TOPO' mail2 ;
miqo meqo maqo = MIMEMA ('EXTR' (CHGRAV qmail2o) 'VALE' 'TOPO') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
qmail2a = 'INDI' 'ALIG' mail2 ;
miqa meqa maqa = MIMEMA ('EXTR' (CHGRAV qmail2a) 'VALE' 'ALIG') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 2 : Qalimin=' miqa ' Qalimed=' meqa ' Qalimax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite alignement maillage avec noeuds interieurs' ;
      'TRAC' qmail2a momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 :  Qmin= 0.66E+00 Qmed= 0.87E+00 Qmax= 0.10E+01
*miqref = 0.65 ; meqref = 0.86 ; maqref = 0.99 ;
*
* 2025/11/24
miqaref = 0.58 ; meqaref = 0.82 ; maqaref = 0.99 ;
'SI' ('<EG' miqa miqaref) ;
   'MESS' '!!! TEST 2 : miqa=' miqa ' < miqaref=' miqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqa meqaref) ;
   'MESS' '!!! TEST 2 : meqa=' meqa ' < meqaref=' meqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqa maqaref) ;
   'MESS' '!!! TEST 2 : maqa=' maqa ' < maqaref=' maqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 3  Remaillage du précédent avec une métrique anisotrope constante
*         en espace compatible avec le maillage du bord 10x20
*
   cmet = 'MANU' 'CHPO' mail2 3 'G11' ('**' d1 -2)
                                'G22' ('**' d2 -2)
                                'G21' 0. ;
* Facultatif : mettre tout ça dans la notice de ALGOMAIL
*              ainsi que les valeurs par défaut
*   tparam3 . 'debug' = 2 ;
   mail3 = 'REMA' mail2 ('CONT' mail2) cmet ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage avec metrique 10x20' ;
      'TRAC' mail3 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 3 : on vérifie que les qualités des éléments sont bonnes
   cmet = 'MANU' 'CHPO' mail3 3 'G11' ('**' d1 -2)
                                'G22' ('**' d2 -2)
                                'G21' 0. ;
qmail3o = 'INDI' 'TOPO' mail3 cmet ;
miq meq maq = MIMEMA ('EXTR' (CHGRAV qmail3o) 'VALE' 'TOPO') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
qmail3a = 'INDI' 'ALIG' mail3 cmet ;
miqa meqa maqa = MIMEMA ('EXTR' (CHGRAV qmail3a) 'VALE' 'ALIG') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qalimin=' miqa ' Qalimed=' meqa ' Qalimax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite alignement maillage avec noeuds interieurs' ;
      'TRAC' qmail3a momail3 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.66E+00 Qmoy= 0.84E+00 Qmax= 0.10E+01
*!!!!!!! Mieux miqref = 0.65 ; meqref = 0.83 ; maqref = 0.99 ;
*miqref = 0.60 ; meqref = 0.83 ; maqref = 0.99 ;
* 2025/11/24
*!!!!! Mieuxmiqaref = 0.67 ; meqaref = 0.91 ; maqaref = 0.99 ;
* 2025/11/24 new
miqaref = 0.58 ; meqaref = 0.91 ; maqaref = 0.99 ;
'SI' ('&lt;EG' miqa miqaref) ;
   'MESS' '!!! TEST 3 : miqa=' miqa ' < miqaref=' miqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqa meqaref) ;
   'MESS' '!!! TEST 3 : meqa=' meqa ' < meqaref=' meqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqa maqaref) ;
   'MESS' '!!! TEST 3 : maqa=' maqa ' < maqaref=' maqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail3e = 'INDI' 'EQUI' mail3 cmet ;
miqe meqe maqe = MIMEMA ('EXTR' (CHGRAV qmail3e) 'VALE' 'EQUI') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 3 : Qequmin=' miqe ' Qequmed=' meqe ' Qequmax=' maqe ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equidistribution maillage avec noeuds interieurs' ;
      'TRAC' qmail3e momail3 lqual 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
miqeref = 0.55 ; meqeref = 0.85 ; maqeref = 0.99 ;
'SI' ('&lt;EG' miqe miqeref) ;
   'MESS' '!!! TEST 3 : miqe=' miqe ' < miqeref=' miqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqe meqeref) ;
   'MESS' '!!! TEST 3 : meqe=' meqe ' < meqeref=' meqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqe maqeref) ;
   'MESS' '!!! TEST 3 : maqe=' maqe ' < maqeref=' maqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  Remaillage du précédent avec une métrique anisotrope constante
*         en espace différente visant à obtenir un maillage 20x10
*         On demande au remailleur de modifier les noeuds du bord.
*
   cmet = 'MANU' 'CHPO' mail3 3 'G11' ('**' d2 -2)
                                'G22' ('**' d1 -2)
                                'G21' 0. ;
 
   mail4 = 'REMA' mail3 cmet ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage avec metrique anisotrope 20x10' ;
      'TRAC' mail4 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 4 : on vérifie que les qualités des éléments sont bonnes
   cmet = 'MANU' 'CHPO' mail4 3 'G11' ('**' d2 -2)
                                'G22' ('**' d1 -2)
                                'G21' 0. ;
qmail4o = 'INDI' 'TOPO' mail4 cmet ;
miq meq maq = MIMEMA ('EXTR' (CHGRAV qmail4o) 'VALE' 'TOPO') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
qmail4a = 'INDI' 'ALIG' mail4 cmet ;
miqa meqa maqa = MIMEMA ('EXTR' (CHGRAV qmail4a) 'VALE' 'ALIG') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qalimin=' miqa ' Qalimed=' meqa ' Qalimax=' maqa ;
   'SI' graph ;
      momail4 = 'MODE' mail4 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite alignement maillage avec noeuds interieurs' ;
      'TRAC' qmail4a momail4 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.67E+00 Qmoy= 0.85E+00 Qmax= 0.10E+01
*!!!! Mieux miqref = 0.65 ; meqref = 0.83 ; maqref = 0.99 ;
*miqref = 0.42 ; meqref = 0.83 ; maqref = 0.99 ;
* 2025/11/24
*!!!! Mieux miqaref = 0.68 ; meqaref = 0.92 ; maqaref = 0.99 ;
* 2025/11/24 new
miqaref = 0.62 ; meqaref = 0.90 ; maqaref = 0.99 ;
'SI' ('&lt;EG' miqa miqaref) ;
   'MESS' '!!! TEST 4 : miqa=' miqa ' < miqaref=' miqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqa meqaref) ;
   'MESS' '!!! TEST 4 : meqa=' meqa ' < meqaref=' meqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqa maqaref) ;
   'MESS' '!!! TEST 4 : maqa=' maqa ' < maqaref=' maqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail4e = 'INDI' 'EQUI' mail4 cmet ;
miqe meqe maqe = MIMEMA ('EXTR' (CHGRAV qmail4e) 'VALE' 'EQUI') ;
'MESS'  'FORMAT' '(E9.2)' 'TEST 4 : Qequmin=' miqe ' Qequmed=' meqe ' Qequmax=' maqe ;
   'SI' graph ;
      momail4 = 'MODE' mail4 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equidistribution maillage avec noeuds interieurs' ;
      'TRAC' qmail4e momail4 lqual 'TITR' tit ;
   'FINSI' ;
* 2025/11/24
*!!!!! Mieux miqeref = 0.55 ; meqeref = 0.86 ; maqeref = 0.99 ;
* 2025/11/24
miqeref = 0.55 ; meqeref = 0.85 ; maqeref = 0.99 ;
'SI' ('&lt;EG' miqe miqeref) ;
   'MESS' '!!! TEST 4 : miqe=' miqe ' < miqeref=' miqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqe meqeref) ;
   'MESS' '!!! TEST 4 : meqe=' meqe ' < meqeref=' meqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqe maqeref) ;
   'MESS' '!!! TEST 4 : maqe=' maqe ' < maqeref=' maqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  Une petite boucle avec de la r-adaptation (DEDU ADAP) pour voir si on peut
* améliorer la qualité du maillage mail3.
*
* La réponse est oui, on peut effectivement avoir une amélioration mais
* après quelque itérations la qualité oscille sans s'alméliorer entre
* r-adaptation et remaillage car les critères optimisés ne sont pas les
* mêmes aux deux étapes.
*
nopt = 2 ; iopt = 0 ;
* Paramètres de DEDUADAP
thdedu = 0.2 ; rdepa = 1. ; nitm = 1 ;
maili = mail4 ;
ldep = 'PROG' ; lqmin = 'PROG' ; lqmed = 'PROG' ;
'REPE' bclopt nopt ;
   iopt = iopt '+' 1 ;
   tit = 'CHAI' 'i=' iopt ;
* Partie DEDUADAP
   maili1 = maili ;
   modi1 = 'MODE' maili1 'MECANIQUE' ;
   cmet = 'MANU' 'CHPO' maili1 3 'G11' ('**' d2 -2)
                                 'G22' ('**' d1 -2)
                                 'G21' 0. ;
   ccmet = 'CHAN' 'CHAM' cmet modi1 ;
   depa = 'DEDU' 'ADAP' maili1 'METR' ccmet modi1 'THET' thdedu 'NITM' nitm ;
   depa = '*' depa rdepa ;
   mcdep = 'MAXI' depa 'ABS' ; ldep = ldep 'ET' mcdep ;
   'MESS' tit ' dedu max. dep=' mcdep ;
   'FORM' depa ;
   qmaili1o = 'INDI' 'TOPO' maili1 cmet ;
   miq meq maq = MIMEMA ('EXTR' (CHGRAV qmaili1o) 'VALE' 'TOPO') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' deduadap : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   qmaili1a = 'INDI' 'ALIG' maili1 cmet ;
   miq meq maq = MIMEMA ('EXTR' (CHGRAV qmaili1a) 'VALE' 'ALIG') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' deduadap : Qalimin=' miq ' Qalimed=' meq ' Qalimax=' maq ;
   qmaili1e = 'INDI' 'EQUI' maili1 cmet ;
   miq meq maq = MIMEMA ('EXTR' (CHGRAV qmaili1e) 'VALE' 'EQUI') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' deduadap : Qequmin=' miq ' Qequmed=' meq ' Qequmax=' maq ;
   'SI' graph ;
      momaili1 = 'MODE' maili1 'THERMIQUE' ;
      vdep = 'VECT' depa -1. 'UX' 'UY' 'NOIR' ;
      titg = 'CHAI' tit ' deduadap' ;
      'TRAC' qmaili1o momaili1 vdep maili1 lqual 'TITR' titg ;
   'FINS' ;
* Partie MAILTOPO
   maili2 = 'REMA' maili1 cmet ;
* Qualités
   cmet = 'MANU' 'CHPO' maili2 3 'G11' ('**' d2 -2)
                                 'G22' ('**' d1 -2)
                                 'G21' 0. ;
   qmaili2o = 'INDI' 'TOPO' maili2 cmet ;
   miq meq maq = MIMEMA ('EXTR' (CHGRAV qmaili2o) 'VALE' 'TOPO') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' mailtopo : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   qmaili2a = 'INDI' 'ALIG' maili2 cmet ;
   miqa meqa maqa = MIMEMA ('EXTR' (CHGRAV qmaili2a) 'VALE' 'ALIG') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' mailtopo : Qalimin=' miqa ' Qalimed=' meqa ' Qalimax=' maqa ;
   qmaili2e = 'INDI' 'EQUI' maili2 cmet ;
   miqe meqe maqe = MIMEMA ('EXTR' (CHGRAV qmaili2e) 'VALE' 'EQUI') ;
   'MESS'  'FORMAT' '(E9.2)' tit ' mailtopo : Qequmin=' miqe ' Qequmed=' meqe ' Qequmax=' maqe ;
   'SI' graph ;
      momaili2 = 'MODE' maili2 'THERMIQUE' ;
      titg = 'CHAI' tit ' mailtopo' ;
      'TRAC' qmaili2o momaili2 lqual 'TITR' titg ;
   'FINSI' ;
   maili = maili2 ;
'FIN' bclopt ;
* Sur mon linux64 au 07/04/2020 : Qmin= 0.68E+00 Qmoy= 0.89E+00 Qmax= 0.10E+01
*!!!!! Mieux miqref = 0.67 ; meqref = 0.88 ; maqref = 0.99 ;
*miqref = 0.43 ; meqref = 0.88 ; maqref = 0.99 ;
* 2025/11/24
miqaref = 0.73 ; meqaref = 0.93 ; maqaref = 0.99 ;
'SI' ('&lt;EG' miqa miqaref) ;
   'MESS' '!!! TEST 5 : miqa=' miqa ' < miqaref=' miqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqa meqaref) ;
   'MESS' '!!! TEST 5 : meqa=' meqa ' < meqaref=' meqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqa maqaref) ;
   'MESS' '!!! TEST 5 : maqa=' maqa ' < maqaref=' maqaref ;
   lok = lok 'ET' faux ;
'FINS' ;
* 2025/11/24
miqeref = 0.54 ; meqeref = 0.92 ; maqeref = 0.99 ;
'SI' ('&lt;EG' miqe miqeref) ;
   'MESS' '!!! TEST 5 : miqe=' miqe ' < miqeref=' miqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' meqe meqeref) ;
   'MESS' '!!! TEST 5 : meqe=' meqe ' < meqeref=' meqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' ('&lt;EG' maqe maqeref) ;
   'MESS' '!!! TEST 5 : maqe=' maqe ' < maqeref=' maqeref ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D3
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales