Télécharger mato-2d1.dgibi

Retour à la liste

* fichier : mato-2d1.dgibi
************************************************************************
************************************************************************
'OPTION' 'ECHO' 0 ;
************************************************************************
* NOM         : MATO-2D1
* DESCRIPTION : Test du MAilleur TOpologique pour mailler un simple
*               carré 10x10 de manière régulière.
*
*               On teste la qualité des éléments obtenus.
*               On améliore un peu la qualité du maillage obtenu
*               avec une boucle entre r-adaptation (DEDU ADAP) et
*               remaillage.
*               Toutefois, après quelque itérations la
*               qualité oscille sans s'améliorer car les critères
*               optimisés ne sont pas les mêmes aux deux étapes.
*
*               Issu de 2d_1.dgibi+tests
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
*               mél : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 02/04/2020, version initiale
* HISTORIQUE : v1, 02/04/2020, création
* HISTORIQUE :
************************************************************************
*
interact = faux ;
graph    = faux ;
complet  = FAUX ;
* Mini, mediane et maxi d'un MCHAML
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI3' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
lqual = 'PROG' 0. 'PAS' 0.05 1. ;
ldens1 = 'PROG' 0.5 'PAS' 0.05  1. ;
ldens2 = 'PROG' 0.9 'PAS' -0.05  0.5 ;
ldens  = ldens1 'ET' (ldens2 '**' -1.) ;
*
for = '(E11.3)' ;
*
tol= ('VALE' prec) '*' 10. ;
*
* Création du contour
*
nx = 10 ;
pA = 0. 0. ; pB = 1. 0. ; pC = 1. 1. ; pD = 0. 1. ;
lAB = 'DROI' nx pA pB ;
lBC = 'DROI' nx pB pC ;
lCD = 'DROI' nx pC pD ;
lDA = 'DROI' nx pD pA ;
*
cnt = lAB 'ET' lBC 'ET' lCD 'ET' lDA ;
*
'SI' graph ;
   tit = 'CHAI'  'Contour ' ;
      'TRACER' 'CACH' cnt 'TITR' tit 'NOEU' ;
'FINSI' ;
*
*  Tests divers (consistance...)
*
lok = VRAI ;
*
* TEST 1  Création d'un maillage sans ajouter de noeuds
*
mail1 = 'TRIA' 'TOPO' cnt 'NOAJ' ;
'SI' graph ;
   tit = 'CHAI'  'Maillage genere sans noeud supplémentaire' ;
   'TRAC' mail1 'TITR' tit 'NOEU' ;
'FINSI' ;
* Test 1 : on vérifie que le nombre de noeuds est conservé
nno1 = 'NBNO' cnt ;
nno2 = 'NBNO' mail1 ;
'SI' ('NEG' nno1 nno2) ;
   'MESS' '!!! TEST 1 : nombre de noeuds non conserve' ;
   lok = lok 'ET' faux ;
'SINO' ;
   'MESS' 'TEST 1 : nombre de noeuds conserve' ;
'FINS' ;
*
* TEST 2  Création d'un maillage en ajoutant des noeuds interieurs
*
mail2 = 'TRIA' 'TOPO' cnt 'AJNO' ;
'SI' graph ;
   tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs' ;
   'TRAC' mail2 'TITR' tit 'NOEU' ;
'FINSI' ;
* Test 2 : on vérifie que les qualités mini, moyenne et maxi des éléments sont bonnes
qmail2 = 'INDI' 'TOPO' 'EQLT' mail2 ;
miqo meqo maqo = MIMEMA qmail2 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 2 : Qmin=' miqo ' Qmed=' meqo ' Qmax=' maqo ;
miqa meqa maqa = MIMEMA qmail2 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail2 = 'MODE' mail2 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'EQLT' qmail2) momail2 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 02/04/2020 : qmin=0.64 qmoy=0.87 qmax=1.00
*miqr = 0.63 ; meqr = 0.86 ; maqr = 0.99 ;
* 2025/11/21
*miqar = 0.54 ; meqar = 0.84 ; maqar = 0.99 ;
* 2026/01/08
miqar = 0.65 ; meqar = 0.86 ; maqar = 0.99 ;
 
'MESS'  'FORMAT' for 'TEST 2 : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 2 failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
'SI' faux ;
   met = DEADMETR mail2 ;
   spe = 'TENS' 'PRIN' met ;
   vp  = 'EXCO' ('MOTS' 'SI11' 'SI22') spe ;
   len = vp '**' 0.5 ;
   el = 'ELEM' qmail2 'MAXI' ;
   tt = 'REDU' (qmail2 'ET' len) el ;
   'LIST' tt ;
   v1 = maxi tt avec (mots si11) ;
   v2 = maxi tt avec (mots si22) ;
   rap = '/' v1 v2 ;
   'LIST' rap ;
   ltr  = '/' ('+' v1 v2) 2 ;
   ldet = '**' ('*' v1 v2) 0.5 ;
   rap2 = '/' ldet ltr ;
   'LIST' rap2 ;
   'OPTI' 'DONN'  5 ;
'FINS' ;
*
* TEST 2b  Création d'un maillage en ajoutant/retirant des noeuds interieurs et de bord
*
mail2b = 'TRIA' 'TOPO' cnt ('VIDE' 'MAILLAGE'/'SEG2') 'AJNO' ;
'SI' graph ;
   tit = 'CHAI' 'Maillage genere en ajoutant des noeuds interieurs et de bord' ;
   'TRAC' mail2b 'TITR' tit 'NOEU' ;
'FINSI' ;
* Test 2 : on vérifie que les qualités mini, moyenne et maxi des éléments sont bonnes
qmail2b = 'INDI' 'EQLT' mail2b ;
miqa meqa maqa = MIMEMA qmail2b 'EQLT' ;
'MESS'  'FORMAT' for 'TEST 2b : Qeqltmin=' miqa ' Qeqltmed=' meqa ' Qeqltmax=' maqa ;
   'SI' graph ;
      momail2b = 'MODE' mail2b 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite equilateralite maillage avec noeuds interieurs et de bord' ;
      'TRAC' qmail2b momail2b lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 16/12/2025 : qmin=0.86 qmoy=0.86 qmax=0.86
* Il ne reste que deux elements dans le carre
miqar = 0.86 ; meqar = 0.86 ; maqar = 0.86 ;
'MESS'  'FORMAT' for 'TEST 2b : Qeqltmir=' miqar ' Qeqltmer=' meqar ' Qeqltmar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 2b failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 2c  Une petite boucle avec de la r-adaptation (DEDU ADAP) permet
* d'améliorer la régularité du maillage mail2 mais ce n'est pas nécessaire
* pour la suite donc on saute.
*
* 2020/04/03 : On arrive à avoir qmin = 0.80
*              avec nopt = 2 ; thdedu = 0.2 ; rdepa =1. ; nitm = 1 ;
*
'SI' complet ;
   nopt = 2 ; iopt = 0 ;
* Paramètres de DEDUADAP
   thdedu = 0.2 ; rdepa = 1. ; nitm = 1 ;
   maili = mail2 ;
   'REPE' bclopt nopt ;
      iopt = iopt '+' 1 ;
      tit = 'CHAI' 'i=' iopt ;
* Partie DEDUADAP
      maili1 = maili ;
      depa = 'DEDU' 'ADAP' maili1 'THET' thdedu 'NITM' nitm ;
      depa = '*' depa rdepa ;
      mcdep = 'MAXI' depa 'ABS' ;
      'MESS' tit ' dedu max. dep=' mcdep ;
      'FORM' depa ;
      qmaili1 = 'INDI' 'TOPO' maili1 ;
      miq meq maq = MIMEMA qmaili1 'TOPO' ;
      'MESS'  'FORMAT' for tit ' deduadap : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
      'SI' graph ;
         momaili1 = 'MODE' maili1 'THERMIQUE' ;
         vdep = 'VECT' depa -1. 'UX' 'UY' 'NOIR' ;
         titg = 'CHAI' tit ' deduadap' ;
         'TRAC' qmaili1 momaili1 vdep maili1 lqual 'TITR' titg ;
      'FINS' ;
* Partie MAILTOPO
      maili2 = 'REMA' maili1 ('CONT' maili1) ;
* Qualités
      qmaili2 = 'INDI' 'TOPO' maili2 ;
      miq meq maq = MIMEMA qmaili2 'TOPO' ;
      'MESS'  'FORMAT' for tit ' mailtopo : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
      'SI' graph ;
         momaili2 = 'MODE' maili2 'THERMIQUE' ;
         titg = 'CHAI' tit ' mailtopo' ;
         'TRAC' qmaili2 momaili2 lqual 'TITR' titg ;
      'FINSI' ;
      maili = maili2 ;
   'FIN' bclopt ;
   mail2 = maili ;
'FINS' ;
*
* TEST 3  Remaillage du précédent avec une métrique uniforme constante
*         en espace
*
   metva = '/' 1. nx ;
   mail3 = 'REMA' mail2 ('CONT' mail2) metva ;
   'SI' graph ;
      tit = 'CHAI' 'Maillage avec metrique constante uniforme' ;
      'TRAC' mail3 'TITR' tit 'NOEU' ;
   'FINSI' ;
* Test 3 : on vérifie que les qualités mini et moyenne des éléments sont bonnes
qmail3 = 'INDI' 'TOPO' 'COHE' 'DENS' mail3 metva ;
miq meq maq = MIMEMA qmail3 'TOPO' ;
'MESS'  'FORMAT' for 'TEST 3 : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
miqa meqa maqa = MIMEMA qmail3 'COHE' ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   'SI' graph ;
      momail3 = 'MODE' mail3 'THERMIQUE' ;
      tit = 'CHAI' 'Qualite coherence maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'COHE' qmail3) momail3 lqual 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 02/04/2020 : qmin=0.624 qmoy=0.847 qmax=1.00
*miqr = 0.61 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/21
*miqar = 0.61 ; meqar = 0.92 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.75 ; meqar = 0.90 ; maqar = 0.99 ;
* 2026/06/03
miqar = 0.67 ; meqar = 0.92 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 3 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 3 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail3b = DEADUTIL 'QALI' mail3 'METR' metva ;
qmail3b = qmail3b '**' -1 ;
dqmail = '-' ('EXCO' 'COHE' qmail3 'SCAL') ('EXCO' 'QALI' qmail3b 'SCAL') ;
ndqmail  = 'MAXI' 'ABS' dqmail ;
*
'SI' ('NEG' ndqmail 0. tol) ;
   'MESS' '!!! TEST 3b failed  : ndqmail=' ndqmail ' .NE. 0' ;
   lok = lok 'ET' faux ;
'FINS' ;
miqe meqe maqe = MIMEMA qmail3 'DENS' ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      tit = 'CHAI' 'Qualite density distribution maillage avec noeuds interieurs' ;
      'TRAC' ('EXCO' 'DENS' qmail3) momail3 ldens 'TITR' tit ;
   'FINSI' ;
* Sur mon linux64 au 02/04/2020 : qmin=0.624 qmoy=0.847 qmax=1.00
*miqr = 0.61 ; meqr = 0.83 ; maqr = 0.99 ;
* 2025/11/21
*miqer = 0.55 ; meqer = 0.86 ; maqer = 0.99 ;
* 2026/01/08
*miqer = 0.52 ; meqer = 0.73 ; maqer = 0.98 ;
* 2026/06/03
miqer = 0.61 ; meqer = 0.87 ; maqer = 1.12 ;
'MESS'  'FORMAT' for 'TEST 3 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 3 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 4  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ isotrope
* constant, on ne modifie pas le maillage
*
   vcnx = '**' ('/' 1. nx) -2 ;
   cmet = 'MANU' 'CHPO' mail3 1 'G' vcnx ;
*
   tparam = 'TABL' ;
   tparam . 'nbpasses_rema' = 1 ;
   mail4 = 'REMA' mail3 ('CONT' mail3) cmet tparam ;
* Test 4 : on vérifie que mail4 et mail3 sont identiques ainsi que les
* qualités
* 2026/06/03 Avec l'algorithme en deux passes, on ne peut plus verifier cela
* donc on repasse en une passe avec le tparam ci-dessus
dn34= 'NBEL' ('DIFF' mail3 mail4) ;
'SI' ('NEG' dn34 0) ;
   'MESS' '!!! TEST 4 : mail3 .NE. mail4' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail4 = 'INDI' 'TOPO' 'COHE' 'DENS' mail4 cmet ;
dq34 = 'MAXI' ('-' qmail4 qmail3) 'ABS' ;
* VALE prec un peu trop serré pour semt2
'SI' ('>' dq34 tol) ;
   'MESS' '!!! TEST 4 : qmail3 .NE. qmail4' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 5  On vérifie qu'en remaillant le maillage précédent avec la même
* métrique uniforme constante donnée sous forme d'un champ anisotrope
* constant, on ne modifie pas le maillage
*
   vcnx = '**' ('/' 1. nx) -2 ;
   cmet = 'MANU' 'CHPO' mail3 3 'G11' vcnx 'G22' vcnx
          'G21' 0. ;
   tparam = 'TABL' ;
   tparam . 'nbpasses_rema' = 1 ;
   mail5 = 'REMA' mail3 ('CONT' mail3) cmet tparam ;
* Test 5 : on vérifie que mail5 et mail3 sont identiques ainsi que les
* qualités
dn35= 'NBEL' ('DIFF' mail3 mail5) ;
'SI' ('NEG' dn35 0) ;
   'MESS' '!!! TEST 5 : mail3 .NE. mail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
qmail5 = 'INDI' 'TOPO' 'COHE' 'DENS' mail5 cmet ;
dq35 = 'MAXI' ('-' qmail5 qmail3) 'ABS' ;
* VALE prec un peu trop serré pour semt2
'SI' ('>' dq35 tol) ;
   'MESS' '!!! TEST 5 : qmail3 .NE. qmail5' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* TEST 6  Une petite boucle avec de la r-adaptation (DEDU ADAP) pour voir si on peut
* améliorer la qualité du maillage mail3.
*
* La réponse est oui, on peut effectivement avoir une amélioration mais
* après quelque itérations la qualité oscille sans s'alméliorer entre
* r-adaptation et remaillage car les critères optimisés ne sont pas les
* mêmes aux deux étapes.
*
* 2020/04/03 : On arrive à avoir qmin = 0.70 avec thdedu = 1. ; rdepa =1. ; nitm = 1 ;
* 2020/04/03 : On arrive à avoir qmin = 0.76 avec thdedu = 0.2 ; rdepa =1. ; nitm = 1 ;
*
*
nopt = 2 ; iopt = 0 ;
* Paramètres de DEDUADAP
thdedu = 0.2 ; rdepa = 1. ; nitm = 1 ;
*thdedu = 0.5 ; rdepa = 1. ; nitm = 1 ;
maili = mail3 ;
vcnx = '/' 1. nx ;
vcnx2 = '**' vcnx -2 ;
ldep = 'PROG' ; lqmin = 'PROG' ; lqmoy = 'PROG' ;
'REPE' bclopt nopt ;
   iopt = iopt '+' 1 ;
   tit = 'CHAI' 'i=' iopt ;
* Partie DEDUADAP
   maili1 = maili ;
   modi1 = 'MODE' maili1 'MECANIQUE' ;
   cmet = 'MANU' 'CHPO' maili1 3 'G11' vcnx2 'G22' vcnx2 'G21' 0. ;
   ccmet = 'CHAN' 'CHAM' cmet modi1 ;
   depa = 'DEDU' 'ADAP' maili1 'METR' ccmet modi1 'THET' thdedu 'NITM' nitm ;
   depa = '*' depa rdepa ;
   mcdep = 'MAXI' depa 'ABS' ; ldep = ldep 'ET' mcdep ;
   'MESS' tit ' dedu max. dep=' mcdep ;
   'FORM' depa ;
   qmaili1 = 'INDI' 'TOPO' 'COHE' 'DENS' maili1 vcnx ;
   miq meq maq = MIMEMA qmaili1 'TOPO' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   miq meq maq = MIMEMA qmaili1 'COHE' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qcohemin=' miq ' Qcohemed=' meq ' Qcohemax=' maq ;
   miq meq maq = MIMEMA qmaili1 'DENS' ;
   'MESS'  'FORMAT' for tit ' deduadap : Qdensmin=' miq ' Qdensmed=' meq ' Qdensmax=' maq ;
   'SI' graph ;
      momaili1 = 'MODE' maili1 'THERMIQUE' ;
      vdep = 'VECT' depa -1. 'UX' 'UY' 'NOIR' ;
      titg = 'CHAI' tit ' deduadap' ;
      'TRAC' ('EXCO' 'TOPO' qmaili1) momaili1 vdep maili1 lqual 'TITR' titg ;
   'FINS' ;
* Partie MAILTOPO
   maili2 = 'REMA' maili1 ('CONT' maili1) vcnx ;
* Qualités
   qmaili2 = 'INDI' 'TOPO' 'COHE' 'DENS' maili2 vcnx ;
   miq meq maq = MIMEMA qmaili2 'TOPO' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qmin=' miq ' Qmed=' meq ' Qmax=' maq ;
   miqa meqa maqa = MIMEMA qmaili2 'COHE' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qcohemin=' miqa ' Qcohemed=' meqa ' Qcohemax=' maqa ;
   miqe meqe maqe = MIMEMA qmaili2 'DENS' ;
   'MESS'  'FORMAT' for tit ' mailtopo : Qdensmin=' miqe ' Qdensmed=' meqe ' Qdensmax=' maqe ;
   'SI' graph ;
      momaili2 = 'MODE' maili2 'THERMIQUE' ;
      titg = 'CHAI' tit ' mailtopo' ;
      'TRAC' ('EXCO' 'TOPO' qmaili2) momaili2 lqual 'TITR' titg ;
   'FINSI' ;
   maili = maili2 ;
'FIN' bclopt ;
* Sur mon linux64 au 02/04/2020 : qmin=0.723 qmoy=0.890 qmax=1.00
*!!!Mieux  miqr = 0.71 ; meqr = 0.88 ; maqr = 0.99 ;
*miqr = 0.69 ; meqr = 0.88 ; maqr = 0.99 ;
* 2025/11/21
*!!!Mieux miqar = 0.74 ; meqar = 0.95 ; maqar = 0.99 ;
* 2025/11/21 new
*miqar = 0.70 ; meqar = 0.93 ; maqar = 0.99 ;
* 2026/01/08
*miqar = 0.79 ; meqar = 0.92 ; maqar = 0.99 ;
* 2026/06/03
miqar = 0.75 ; meqar = 0.95 ; maqar = 0.99 ;
'MESS'  'FORMAT' for 'TEST 6 : Qcohemir=' miqar ' Qcohemer=' meqar ' Qcohemar=' maqar ;
'SI' (('<EG' miqa miqar) 'OU' ('<EG' meqa meqar) 'OU' ('<EG' maqa maqar)) ;
   'MESS' '!!! TEST 6 coherence failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
* 2025/11/21
*miqer = 0.60 ; meqer = 0.92 ; maqer = 0.99 ;
* 2026/01/08
miqer = 0.71 ; meqer = 0.88 ; maqer = 1.12 ;
'MESS'  'FORMAT' for 'TEST 6 : Qdensmir=' miqer ' Qdensmer=' meqer ' Qdensmar=' maqer ;
'SI' (('<EG' miqe miqer) 'OU' ('NEG' meqe meqer 0.01) 'OU' ('>EG' maqe maqer)) ;
   'MESS' '!!! TEST 6 density distribution failed' ;
   lok = lok 'ET' faux ;
'FINS' ;
*
* Test final
*
'SI' ('NON' lok) ;
   'ERREUR' 5 ;
'SINON' ;
   'SAUT' 1 'LIGN' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file MATO-2D1
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales