Exemples de jeux de données Cast3M

** Test de l'operateur de KRIGEAGE en dimension 1
 
 
 
** ------------- Test de la syntaxe avec des LISTREELs ----------------*
*                           (sans maillage)                            *
*----------------------------------------------------------------------*
 
** Options generales
OPTI 'ECHO' 1 ;
itrac = FAUX ;
 
 
** Coorodnnees et fonction aux points de mesure
lxm   = PROG 0.3  1.9  1.1  3.3  4.7 ;
lfm   = PROG 0.47 0.56 0.74 1.47 1.74 ;
evm   = EVOL 'VERT' 'MANU' 'LEGE' 'Donnees d''entree' 'STYL' 'NOLI' 'MARQ' 'ROND' 'X' lxm 'F' lfm ;
 
 
** Coodonnees des points cibles
lxc   = PROG -1. 'PAS' 0.01 6. ;
 
 
** Variogramme des mesures (modele gaussien)
c     = 0.5 ;
a     = 2. ;
ld    = PROG 0. 'PAS' 0.01 10. ;
lgam  = c * (1. - (EXP (-3. * ((ld / a) ** 2)))) ;
gam   = EVOL 'VERT' 'MANU' 'Distance' ld 'Semivariance' lgam ;
 
 
** Krigeage au points cibles (avec le variogramme)
t                       = TABL ;
t . 'MESURES'           = TABL ;
t . 'MESURES'     . 'X' = lxm ;
t . 'MESURES'     . 'F' = lfm ;
t . 'CIBLES'            = TABL ;
t . 'CIBLES'      . 'X' = lxc ;
t . 'COORDONNEES'       = MOTS 'X' ;
t . 'COMPOSANTE'        = MOT 'F' ;
t . 'VARIOGRAMME'       = gam ;
lfk1 lvk1 = KRIG t ;
 
 
** Covariogramme
lcov  = c * (EXP (-3. * ((ld / a) ** 2))) ;
cov   = EVOL 'VERT' 'MANU' 'Distance' ld 'Covariance' lcov ;
 
 
** Krigeage au points cibles (avec le covariogramme)
OTER t 'VARIOGRAMME' ;
t . 'COVARIOGRAMME' = cov ;
lfk2 lvk2 = KRIG t ;
 
 
** Test d'egalite des resultats
err1  = MAXI 'ABS' (lfk2 - lfk1) ;
err2  = MAXI 'ABS' (lvk2 - lvk1) ;
MESS 'Ecart max. sur l''estimation :' err1 ;
MESS 'Ecart max. sur la variance   :' err2 ;
SI ((err1 > 1.E-10) OU (err2 > 1.E-10)) ;
  ERRE 'Ecart entre le krigeage par variance et covariance !' ;
FINSI ;
 
 
** Trace des resultats
SI itrac ;
  fk    = EVOL 'ROUG' 'MANU' 'LEGE' 'Estimation par krigeage' 'X' lxc 'F' lfk1 ;
  lv1   = lfk1 + lvk1 ;
  lv2   = lfk1 - lvk1 ;
  vk1   = EVOL 'ORAN' 'MANU' 'LEGE' 'Esitmation + variance' 'STYL' 'TIRR' 'X' lxc 'F' lv1 ;
  vk2   = EVOL 'ORAN' 'MANU' 'LEGE' 'Estimation - variance' 'STYL' 'TIRR' 'X' lxc 'F' lv2 ;
  DESS (evm ET fk ET vk1 ET vk2) 'TITR' 'Interpolation par krigeage + variance d''estimation' 'LEGE' ;
FINSI ;
 
 
 
 
 
 
** -------------- Test de la syntaxe avec des CHPOINTs ----------------*
*                                                                      *
*----------------------------------------------------------------------*
 
** Options generales
OPTI 'DIME' 1 ;
 
 
** Rangement des mesures dans un CHPOINT
mpm   = POIN lxm ;
mes   = MANU 'CHPO' mpm 2 'X' lxm 'F' lfm 'NATURE' 'DIFFUS' ;
 
 
** Rangement des cibles dans un CHPOINT
mail  = POIN lxc ;
cib   = MANU 'CHPO' mail 1 'X' lxc 'NATURE' 'DIFFUS' ;
 
 
** Krigeage au points cibles (avec le variogramme)
t     = TABL ;
t . 'COORDONNEES' = MOTS 'X' ;
t . 'MESURES'     = mes ;
t . 'COMPOSANTE'  = MOT 'F' ;
t . 'CIBLES'      = cib ;
t . 'VARIOGRAMME' = gam ;
est1 var1 = KRIG t ;
 
 
** Krigeage au points cibles (avec le covariogramme)
t     = TABL ;
t . 'COORDONNEES'   = MOTS 'X' ;
t . 'MESURES'       = mes ;
t . 'COMPOSANTE'    = MOT 'F' ;
t . 'CIBLES'        = cib ;
t . 'COVARIOGRAMME' = cov ;
est2 var2 = KRIG t ;
 
 
** Test d'egalite des resultats
err1  = MAXI 'ABS' (est2 - est1) ;
err2  = MAXI 'ABS' (var2 - var1) ;
MESS 'Ecart max. sur l''estimation :' err1 ;
MESS 'Ecart max. sur la variance   :' err2 ;
SI ((err1 > 1.E-10) OU (err2 > 1.E-10)) ;
  ERRE 'Ecart entre le krigeage par variance et covariance !' ;
FINSI ;
 
 
** Trace des resultats
SI itrac ;
  lfk   = EXTR est1 'VALE' ;
  fk    = EVOL 'ROUG' 'MANU' 'LEGE' 'Estimation par krigeage' 'X' lxc 'F' lfk ;
  lvk   = EXTR var1 'VALE' ;
  lv1   = lfk + lvk ;
  lv2   = lfk - lvk ;
  vk1   = EVOL 'ORAN' 'MANU' 'LEGE' 'Esitmation + variance' 'STYL' 'TIRR' 'X' lxc 'F' lv1 ;
  vk2   = EVOL 'ORAN' 'MANU' 'LEGE' 'Estimation - variance' 'STYL' 'TIRR' 'X' lxc 'F' lv2 ;
  DESS (evm ET fk ET vk1 ET vk2) 'TITR' 'Interpolation par krigeage + variance d''estimation' 'LEGE' ;
FINSI ;
 
 
FIN ;