Télécharger la plaquette Cast3M


fr en

Télécharger konv_cons.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  konv_cons.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ***********************************************************
  5. ***********************************************************
  6. **** APPROCHE VF "Cell-Centred Formulation" pour la    ****
  7. **** solution des                                      ****
  8. **** Equations d Euler pour un gaz parfait             ****
  9. **** OPERATEURS PRIM, PRET, KONV                       ****
  10. ****                                                   ****
  11. **** Cas gaz monoespece, "calorically perfect"         ****
  12. **** Consistence                                       ****
  13. ****                                                   ****
  14. **** Methodes: VANLEER                                 ****
  15. ****           VLH                                     ****
  16. ****           HUSVL                                   ****
  17. ****           HUSVLH                                  ****
  18. ****           GODUNOV                                 ****
  19. ****           AUSMPLUS                                ****
  20. ****           ROE                                     ****
  21. ****           SS                                      ****
  22. ****           RUSANOV                                 ****
  23. ****           AUSMPLM                                 ****
  24. ****           RUSANOLM                                ****
  25. ****           CENTERED                                ****
  26. ****           HLLC                                    ****
  27. ****           HLLCLM                                  ****
  28. ****                                                   ****
  29. **** A. BECCANTINI DRN/DMT/SEMT/LTMF  DECEMBRE 2003    ****
  30. ***********************************************************
  31. ***********************************************************
  32.  
  33.  'OPTION'  'DIME' 2 'ELEM' QUA4 'ECHO' 1 'TRAC' 'X' ;
  34.  
  35. *
  36. *** GRAPH
  37. *
  38.  
  39.  GRAPH = FAUX ;
  40. *  GRAPH = VRAI ;
  41.  
  42.  
  43.  
  44. ***************************
  45. ***** DOMAINE SPATIAL  ****
  46. ***************************
  47.  
  48.  
  49.  A1 = 0.0D0 0.0D0;
  50.  A2 = 1.0D0 0.0D0;
  51.  A3 = 2.0D0 0.0D0;
  52.  A4 = 2.0D0 1.0D0;
  53.  A5 = 1.0D0 1.0D0;
  54.  A6 = 0.0D0 1.0D0;
  55.  
  56.  L12 = A1 'DROIT' 1 A2;
  57.  L23 = A2 'DROIT' 1 A3;
  58.  L34 = A3 'DROIT' 1 A4;
  59.  L45 = A4 'DROIT' 1 A5;
  60.  L56 = A5 'DROIT' 1 A6;
  61.  L61 = A6 'DROIT' 1 A1;
  62.  L25 = A2 'DROIT' 1 A5;
  63.  
  64.  
  65.  DOM10 = 'DALL' L12 L25 L56 L61
  66.          'PLANE';
  67.  DOM20 = 'DALL' L23 L34 L45 ('INVERSE' L25)
  68.          'PLANE';
  69. *
  70. *** Point ou on controlle la consistence
  71. *
  72.  
  73.  P10 = 1.0 0.5;
  74.  
  75. *
  76. *** Etats gauche et droite eguals
  77. *
  78.  
  79.  rogd = 1.11;
  80.  ungd  = 1.3;
  81.  utgd  = 18.2;
  82.  pgd   = 1234.7;
  83.  gamgd = 1.4D0;
  84.  
  85. *
  86. *** retgd
  87. *
  88.  
  89.  ecingd = 0.5D0 '*' rogd '*' ((ungd '*' ungd) '+' (utgd '*' utgd));
  90.  retgd = (pgd '/' (gamgd '-' 1.0)) '+' ecingd;
  91.  
  92. *
  93. ***  flux en (n,t)
  94. *
  95.  
  96.  f1gd = ungd  '*'  rogd;
  97.  f2gd = (rogd '*' (ungd '*' ungd)) '+' pgd;
  98.  f3gd = rogd '*' ungd '*' utgd ;
  99.  f4gd = ungd * (retgd '+' pgd);
  100.  
  101.  
  102. ****************************************************
  103. ****************************************************
  104. ******** Boucle sur les angles             *********
  105. ****************************************************
  106. ****************************************************
  107.  
  108.  DANGLE = 360 '/' 7.15;
  109.  ANGLE = 11.3 ;
  110.  
  111.  'REPETER' BLOC 8;
  112.  
  113. *
  114. *** Rotation
  115. *
  116.  
  117.     ANGLE = ANGLE '+' DANGLE;
  118.     ORIG = 0.0D0 0.0D0;
  119.  
  120.     'MESSAGE' ;
  121.     'MESSAGE' ('CHAINE'  'Angle de rotation= ' ANGLE);
  122.     'MESSAGE' ;
  123.  
  124.     DOM1   = DOM10   'TOURNER' ANGLE ORIG;
  125.     DOM2   = DOM20   'TOURNER' ANGLE ORIG;
  126.     P1     = P10     'TOURNER' ANGLE ORIG;
  127.  
  128.     'ELIMINATION' (DOM1 ET DOM2) 1D-6;
  129.     DOMTOT = DOM1 ET DOM2;
  130.  
  131.     $DOMTOT = 'MODELISER' DOMTOT 'EULER';
  132.     $DOM1 = 'MODELISER'  DOM1 'EULER';
  133.     $DOM2 = 'MODELISER'  DOM2 'EULER';
  134.  
  135.     TDOMTOT = 'DOMA'  $DOMTOT 'VF';
  136.     TDOM1 = 'DOMA'  $DOM1 'VF';
  137.     TDOM2 = 'DOMA'  $DOM2 'VF';
  138.  
  139.     MDOM1 = TDOM1 . 'QUAF' ;
  140.     MDOM2 = TDOM2 . 'QUAF' ;
  141.     MDOMTOT = TDOMTOT . 'QUAF' ;
  142.  
  143.     'ELIMINATION'  (MDOMTOT ET MDOM1) 0.0001 ;
  144.     'ELIMINATION'  (MDOMTOT ET MDOM2) 0.0001 ;
  145.  
  146.     'SI' GRAPH;
  147.       'TRACER' (('DOMA' $DOMTOT 'MAILLAGE' ) 'ET'
  148.       ('DOMA' $DOMTOT 'FACEL') 'ET' P1) 'TITRE' 'Domaine et FACEL';
  149.     'FINSI' ;
  150.  
  151. *
  152. **** Redefinition de P1 dans $DOMTOT 'FACE'
  153. *
  154.  
  155.     P1 = ('DOMA' $DOMTOT 'FACE') 'POIN' 'PROC' P1;
  156.  
  157. ***********************
  158. **** Les CHPOINTs  ****
  159. ***********************
  160.  
  161.     uxgd = (ungd '*' ('COS' ANGLE)) '-' (utgd '*' ('SIN' ANGLE));
  162.     uygd = (ungd '*' ('SIN' ANGLE)) '+' (utgd '*' ('COS' ANGLE));
  163.  
  164.  
  165.     GAMMAN = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' gamgd;
  166.  
  167.     RN1  = 'KCHT' $DOM1   'SCAL' 'CENTRE' rogd;
  168.     RN2  = 'KCHT' $DOM2   'SCAL' 'CENTRE' rogd;;
  169.     RN   = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' (RN1 'ET' RN2);
  170.  
  171.     GN1  = 'KCHT' $DOM1   'VECT' 'CENTRE' ((rogd '*' uxgd)
  172.                                            (rogd '*' uygd));
  173.     GN2  = 'KCHT' $DOM2   'VECT' 'CENTRE' ((rogd '*' uxgd)
  174.                                            (rogd '*' uygd));
  175.     GN    = 'KCHT' $DOMTOT 'VECT' 'CENTRE' (GN1 'ET' GN2);
  176.  
  177.     PN1   = 'KCHT' $DOM1   'SCAL' 'CENTRE' pgd;
  178.     PN2   = 'KCHT' $DOM2   'SCAL' 'CENTRE' pgd;
  179.     PN    = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' (PN1 'ET' PN2);
  180.  
  181. *
  182. *** La vitesse
  183. *
  184.  
  185.     VITX = ('EXCO' 'UX  ' GN) '/' RN;
  186.     VITY = ('EXCO' 'UY  ' GN) '/' RN;
  187.  
  188. *
  189. *** L'energie totale (RETN)
  190. *
  191.  
  192.     GM1 = GAMMAN '-' ('KCHT' $DOMTOT 'SCAL' 'CENTRE' 1.0D0) ;
  193.     RETHER = PN '/' GM1 ;
  194.     a2= GN (mots 'UX' 'UY') PSCA GN (mots 'UX' 'UY');
  195.     RECIN = (0.5D0 '*' a2) '/' RN;
  196.     RETN = 'KCHT' $DOMTOT 'SCAL' 'CENTRE' (RECIN '+' RETHER);
  197.  
  198.  
  199. ***************************
  200. ****  L'operateur  PRIM****
  201. ***************************
  202.  
  203.     VITESSE PRES   = 'PRIM' 'PERFMONO'  RN GN RETN GAMMAN ;
  204.  
  205. ***************************
  206. ****  L'operateur  PRET****
  207. ***************************
  208.  
  209.     ORDESP = 1;
  210.     ORDTEM = 1;
  211.  
  212.  
  213.     ROF VITF PF GAMF   =  'PRET' 'PERFMONO'  ORDESP ORDTEM
  214.                            $DOMTOT RN VITESSE PRES GAMMAN ;
  215.  
  216. *********************************************************
  217. *** Control des etats sur la surface qui contient P1 ****
  218. *********************************************************
  219.  
  220.     GEOP1    = ('DOMA' $DOMTOT 'FACEL') 'ELEM' 'APPUYE' 'LARGEMENT' P1;
  221.     GEOP2    = ('DOMA' $DOMTOT 'FACE')  'ELEM' 'APPUYE' 'LARGEMENT' P1;
  222.  
  223.     ROGEOP1  = 'REDU' ROF GEOP1;
  224.     VGEOP1   = 'REDU' VITF GEOP1;
  225.     PGEOP1   = 'REDU' PF GEOP1;
  226.     GAMGEOP1 = 'REDU' GAMF GEOP1;
  227.     REFGEOP1 = 'REDU' VITF GEOP2;
  228.  
  229.  
  230.     rog = 'EXTRAIRE' ROGEOP1 'SCAL' 1 1 1;
  231.     rod = 'EXTRAIRE' ROGEOP1 'SCAL' 1 1 3;
  232.     ung = 'EXTRAIRE' VGEOP1 'UN  ' 1 1 1;
  233.     und = 'EXTRAIRE' VGEOP1 'UN  ' 1 1 3;
  234.     utg = 'EXTRAIRE' VGEOP1 'UT  ' 1 1 1;
  235.     utd = 'EXTRAIRE' VGEOP1 'UT  ' 1 1 3;
  236.     pg = 'EXTRAIRE' PGEOP1 'SCAL' 1 1 1;
  237.     pd = 'EXTRAIRE' PGEOP1 'SCAL' 1 1 3;
  238.  
  239. *
  240. **** Orientation de la normal n de castem par raport a la
  241. *    notre; t est par consequence
  242. *
  243.  
  244.     NCOS = 'EXTRAIRE' REFGEOP1 'NX' 1 1 1;
  245.     NSIN = 'EXTRAIRE' REFGEOP1 'NY' 1 1 1;
  246.  
  247.     'SI' (('ABS' NCOS) > ('ABS' NSIN));
  248.         ORIENT = ('COS' ANGLE) '/' NCOS;
  249.     'SINON';
  250.         ORIENT = ('SIN' ANGLE) '/' NSIN;
  251.     'FINSI' ;
  252.  
  253.     ORIENT = 'SIGN' ORIENT;
  254.  
  255. *
  256. **** TEST 'PRET', premier ordre en espace et en temps.
  257. *
  258.  
  259.     ERRO = 1D-13 '*' rogd;
  260.     LOGI1 = (('ABS' (rog '-' rod)) < ERRO) 'ET'
  261.             (('ABS' (rog '-' rogd)) < ERRO);
  262.  
  263.     ERRO = 1D-13 '*' pgd;
  264.     LOGI2 = (('ABS' (pg '-' pd )) < ERRO) 'ET'
  265.                  (('ABS' (pg '-' pgd)) < ERRO) ;
  266.     LOGI1 = LOGI1 'ET' LOGI2;
  267.  
  268.     ERRO = 1D-13 '*' ungd;
  269.     LOGI2 = (('ABS' (ung '-' und)) < ERRO) 'ET'
  270.         (('ABS' (ung '-' (ORIENT '*'ungd))) < ERRO) ;
  271.     LOGI1 = LOGI1 'ET' LOGI2;
  272.  
  273.     ERRO = 1D-13 '*' utgd;
  274.     LOGI2 = (( 'ABS' (utg '-' utd)) < ERRO) 'ET'
  275.         (('ABS' (utg '-' (ORIENT '*'utgd))) < ERRO) ;
  276.     LOGI1 = LOGI1 'ET' LOGI2;
  277.  
  278.     'SI' ('NON' LOGI1);
  279.        'MESSAGE' ;
  280.        'MESSAGE' 'Probleme en PRET' ;
  281.        'MESSAGE' ;
  282.        'MESSAGE' ('CHAINE' 'dRO ' ('ABS' (rog '-' rod))
  283.                        ' '    ('ABS' (rog '-' rogd)));
  284.        'MESSAGE' ('CHAINE' 'dp ' ('ABS' (pg '-' pd))
  285.                        ' '    ('ABS' (pg '-' pgd)));
  286.        'MESSAGE' ('CHAINE' 'dun ' ('ABS' (ung '-' und))
  287.                        ' '    ('ABS' (ung '-'  (ORIENT '*'ungd))));
  288.        'MESSAGE' ('CHAINE' 'dRO ' ('ABS' (utg '-' utd))
  289.                        ' '    ('ABS' (utg '-'  (ORIENT '*'utgd))));
  290.        'ERREUR' 5;
  291.     'FINSI' ;
  292.  
  293.     ORDESP = 1 ;
  294.     ORDTEM = 1 ;
  295.  
  296.     'REPETER' BLMETO 16 ;
  297.  
  298.        'SI' ('EGA' &BLMETO 1) ;
  299.            METO = 'VANLEER'  ;
  300.        'FINSI' ;
  301.  
  302.        'SI' ('EGA' &BLMETO 2) ;
  303.            METO = 'VLH'  ;
  304.        'FINSI' ;
  305.  
  306.        'SI' ('EGA' &BLMETO 3) ;
  307.            METO =  'HUSVL'  ;
  308.        'FINSI' ;
  309.  
  310.        'SI' ('EGA' &BLMETO 4) ;
  311.           METO =   'HUSVLH'  ;
  312.        'FINSI' ;
  313.  
  314.        'SI' ('EGA' &BLMETO 5) ;
  315.           METO =   'GODUNOV'  ;
  316.        'FINSI' ;
  317.  
  318.        'SI' ('EGA' &BLMETO 6) ;
  319.           METO =    'AUSMPLUS'  ;
  320.        'FINSI' ;
  321.  
  322.        'SI' ('EGA' &BLMETO 7) ;
  323.           METO =    'ROE' ;
  324.        'FINSI' ;
  325.  
  326.        'SI' ('EGA' &BLMETO 8) ;
  327.           METO =    'SS' ;
  328.        'FINSI' ;
  329.  
  330.        'SI' ('EGA' &BLMETO 9) ;
  331.           METO =    'RUSANOV' ;
  332.        'FINSI' ;
  333.  
  334.        'SI' ('EGA' &BLMETO 10) ;
  335.           METO =    'AUSMPLM' ;
  336.        'FINSI' ;
  337.  
  338.        'SI' ('EGA' &BLMETO 11) ;
  339.           METO =    'RUSANOLM' ;
  340.        'FINSI' ;
  341.  
  342.        'SI' ('EGA' &BLMETO 12) ;
  343.           METO =    'CENTERED' ;
  344.        'FINSI' ;
  345.  
  346.        'SI' ('EGA' &BLMETO 13) ;
  347.           METO =    'ROELM' ;
  348.        'FINSI' ;
  349.  
  350.        'SI' ('EGA' &BLMETO 14) ;
  351.           METO =    'HLLC' ;
  352.        'FINSI' ;
  353.  
  354.        'SI' ('EGA' &BLMETO 15) ;
  355.           METO =    'HLLCLM' ;
  356.        'FINSI' ;
  357.  
  358.        'SI' ('EGA' &BLMETO 16) ;
  359.           METO =    'AUSMPUP' ;
  360.        'FINSI' ;
  361.  
  362.        'MESSAGE' ('CHAINE' 'METO = ' METO) ;
  363.        LISTINCO = ('MOTS' 'RN' 'RUNX' 'RUNY' 'RETN') ;
  364.        'SI' ((&BLMETO 'EGA' 10) 'OU' (&BLMETO 'EGA' 11)
  365.          'OU' (&BLMETO 'EGA' 13) 'OU' (&BLMETO 'EGA' 15)
  366.          'OU' (&BLMETO 'EGA' 16)) ;
  367.           VCUTOFF = 'MANUEL' 'CHPO' ('DOMA' $DOMTOT 'CENTRE') 1 'SCAL'
  368.              0.0001 ;
  369.           CHPFLU DT = 'KONV' 'VF' 'PERFMONO' 'FLUX' METO
  370.              $DOMTOT ROF VITF PF GAMF LISTINCO VCUTOFF VCUTOFF ;
  371.        'SINON' ;
  372.           CHPFLU DT = 'KONV' 'VF' 'PERFMONO' 'FLUX' METO
  373.              $DOMTOT ROF VITF PF GAMF LISTINCO ;
  374.        'FINSI' ;
  375. *
  376. **** Les flux aux interfaces sont dans de
  377. *    CHPOINT FACE
  378. *
  379.  
  380.        FLUX1 = 'EXCO' ('EXTRAIRE' LISTINCO 1) CHPFLU ;
  381.        FLUX2X = 'EXCO' ('EXTRAIRE' LISTINCO 2) CHPFLU ;
  382.        FLUX2Y = 'EXCO' ('EXTRAIRE' LISTINCO 3) CHPFLU ;
  383.        FLUX3 = 'EXCO' ('EXTRAIRE' LISTINCO 4) CHPFLU ;
  384.  
  385.        FLUX2N = (FLUX2X '*' ('COS' ANGLE)) '+' (FLUX2Y * ('SIN' ANGLE));
  386.        FLUX2T = (FLUX2Y '*' ('COS' ANGLE)) '-' (FLUX2X * ('SIN' ANGLE));
  387.  
  388.  
  389.        f1 = 'EXTRAIRE' FLUX1 'SCAL' P1;
  390.        ERRO = 1D-13 '*' f1gd;
  391.        LOGI1 = ('ABS' ((f1 '*' ORIENT) '-' f1gd)) < ERRO ;
  392.  
  393.        f2 = 'EXTRAIRE' FLUX2N 'SCAL' P1;
  394.        ERRO = 1D-13 '*' f2gd;
  395.        LOGI2 = ('ABS' ((f2 '*' ORIENT) '-' f2gd)) < ERRO;
  396.        LOGI1 = LOGI1 'ET' LOGI2;
  397.  
  398.        f3 = 'EXTRAIRE' FLUX2T 'SCAL' P1;
  399.        ERRO = 1D-13 '*' f3gd;
  400.        LOGI2 = ('ABS' ((f3 '*' ORIENT) '-' f3gd)) < ERRO;
  401.        LOGI1 = LOGI1 'ET' LOGI2;
  402.  
  403.        f4 = 'EXTRAIRE' FLUX3 'SCAL' P1;
  404.        ERRO = 1D-13 '*' f4gd;
  405.        LOGI2 = ('ABS' ((f4 '*' ORIENT) '-' f4gd)) < ERRO;
  406.        LOGI1 = LOGI1 'ET' LOGI2;
  407.  
  408.        'SI' ('NON' LOGI1);
  409.           'MESSAGE' ;
  410.           'MESSAGE' 'OPERATEUR KONV';
  411.           'MESSAGE' ('CHAINE' METO);
  412.           'MESSAGE' ;
  413.           'MESSAGE' ('CHAINE' 'df1 ' ('ABS' (f1gd '-'  (ORIENT '*'f1)))
  414.                      ' f1 ' f1);
  415.           'MESSAGE' ('CHAINE' 'df2 ' ('ABS' (f2gd '-'  (ORIENT '*'f2)))
  416.                         ' f2 ' f2);
  417.           'MESSAGE' ('CHAINE' 'df3 ' ('ABS' (f3gd '-'  (ORIENT '*'f3)))
  418.                         ' f3 ' f3);
  419.           'MESSAGE' ('CHAINE' 'df4 ' ('ABS' (f4gd '-'  (ORIENT '*'f4)))
  420.                         ' f4 ' f4);
  421.           'ERREUR' 5;
  422.        'FINSI' ;
  423.  
  424. *
  425. ****** Le residu
  426. *
  427. *
  428. ****** CHPDIR = chpoint sur les face de chaque elts
  429. *
  430. *
  431. *      NB Dans ce cas particulier, DOMTOT n'a que de QUA4,
  432. *         donc  ($DOMTOT . 'XXNORMAE') contient une seule
  433. *         zona elementaire!
  434.  
  435.  
  436.        RESI MATCEL = 'KOPS' 'MATRIK' ;
  437.        MAICHA = 'EXTRAIRE' ('DOMA' $DOMTOT 'XXNORMAE') 'MAILLAGE' ;
  438.        NBELEM = 'NBEL' MAICHA ;
  439.  
  440.        'REPETER' BLELE NBELEM ;
  441.           CHPDIR MATCEL = 'KOPS' 'MATRIK' ;
  442.           ELEM1 = &BLELE 'ELEM' MAICHA ;
  443.           ELEMC1 = 'CHANGER' ELEM1 'POI1' ;
  444.           NBPOIN = 'NBNO' ELEMC1 ;
  445.           PCEN = ('DOMA' $DOMTOT 'CENTRE') 'POIN' &BLELE ;
  446.           XVOL = ('DOMA' $DOMTOT 'XXVOLUM') 'EXTRAIRE' PCEN 'SCAL' ;
  447.           MAICEN = 'MANU' 'POI1'PCEN ;
  448.           'REPETER' BLEPO NBPOIN ;
  449.              P1 = &BLEPO 'POIN' ELEMC1 ;
  450.              ELEP1 = 'MANUEL' 'POI1' P1 ;
  451.              COEFNO = 'EXTRAIRE' ('DOMA' $DOMTOT 'XXNORMAE')
  452.                 'SCAL' 1 &BLELE &BLEPO ;
  453.              CHPDIR = CHPDIR 'ET' ('MANUEL' 'CHPO' ELEP1 1 'SCAL'
  454.                 COEFNO 'NATU' 'DISCRET') ;
  455.           'FIN' BLEPO ;
  456.           MAIDIR = 'EXTRAIRE' CHPDIR 'MAILLAGE' ;
  457. *
  458. ********* Le flux qui sort
  459. *
  460.           FLUSOR = CHPDIR '*' ('REDU' CHPFLU MAIDIR)
  461.              ('MOTS' 'SCAL' 'SCAL' 'SCAL' 'SCAL')
  462.               LISTINCO LISTINCO ;
  463.           CHPUN = 'MANUEL' 'CHPO' MAIDIR 1 'SCAL' (-1./XVOL) ;
  464.           NBCOMP = 'DIME' LISTINCO ;
  465.           'REPETER' BLCOM NBCOMP ;
  466.               NOMCOM = 'EXTRAIRE' LISTINCO &BLCOM ;
  467.               CELSCA = 'XTY' FLUSOR CHPUN ('MOTS' NOMCOM)
  468.                  ('MOTS' 'SCAL') ;
  469.               RESI = RESI 'ET' ('MANUEL' 'CHPO' MAICEN 1
  470.               NOMCOM CELSCA 'NATU' 'DISCRET') ;
  471.           'FIN' BLCOM ;
  472.        'FIN' BLELE ;
  473.  
  474.        'SI' ((&BLMETO 'EGA' 10) 'OU' (&BLMETO 'EGA' 11)
  475.          'OU' (&BLMETO 'EGA' 13) 'OU' (&BLMETO 'EGA' 15)
  476.          'OU' (&BLMETO 'EGA' 16)) ;
  477.           VCUTOFF = 'MANUEL' 'CHPO' ('DOMA' $DOMTOT 'CENTRE') 1 'SCAL'
  478.              0.00001 ;
  479.           CHPRES DT1 = 'KONV' 'VF' 'PERFMONO' 'RESI' METO
  480.              $DOMTOT ROF VITF PF GAMF LISTINCO VCUTOFF VCUTOFF ;
  481.        'SINON' ;
  482.           CHPRES DT1 = 'KONV' 'VF' 'PERFMONO' 'RESI' METO
  483.              $DOMTOT ROF VITF PF GAMF LISTINCO ;
  484.        'FINSI' ;
  485. *
  486.  
  487.        ERRO = 'MAXIMUM' (RESI '-' CHPRES) 'ABS' ;
  488.        'SI' (ERRO > 1.0D-11) ;
  489.           'MESSAGE' ;
  490.           'MESSAGE' 'Probleme dans KONV' ;
  491.           'ERREUR' 5 ;
  492.        'FINSI' ;
  493.  
  494.        ERRO = 'ABS' (DT '-' DT1) ;
  495.        'SI' (ERRO > 1.0D-11) ;
  496.           'MESSAGE' ;
  497.           'MESSAGE' 'Probleme dans KONV' ;
  498.           'ERREUR' 5 ;
  499.        'FINSI' ;
  500.  
  501.     'FIN' BLMETO ;
  502.  
  503. ****************************************************
  504. ****************************************************
  505. ******** Fin boucle sur les angles         *********
  506. ****************************************************
  507. ****************************************************
  508.  
  509.  'FIN' BLOC;
  510.  
  511.  
  512.  'FIN' ;
  513.  
  514.  
  515.  
  516.  
  517.  
  518.  
  519.  
  520.  
  521.  
  522.  
  523.  
  524.  
  525.  
  526.  
  527.  
  528.  
  529.  
  530.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales