Télécharger indi3.dgibi

Retour à la liste

* fichier : indi3.dgibi
************************************************************************
************************************************************************
'OPTI' 'ECHO' 0 ;
************************************************************************
* NOM         : INDI3.DGIBI
* DESCRIPTION : Test elementaire
*               On verifie l'egalite entre des indicateurs de
*               qualite d'elements calcules par INDI et un recalcul a
*               partir des elements propres de la metrique locale
*               (Jt M J) calculee avec DEADMETR
*
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stephane GOUNAND (CEA/DES/ISAS/DM2S/SEMT/LTA)
*               mel : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 14/04/2026, version initiale
* HISTORIQUE : v1, 14/04/2026, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
graph    = faux ;
interact = faux ;
*
 
* Mini, mediane et maxi d'un MCHAML
'DEBP' MIMEMA ;
'ARGU' ch*'MCHAML' ;
'ARGU' cmp*'MOT' ;
   lr = 'EXTR' (CHGRAV ch) 'VALE' cmp ;
   lro = 'ORDO' lr ; dlr = 'DIME' lr ;
   mil = 'EXTR' lro 1 ; mal = 'EXTR' lro dlr ;
   mel = 'EXTR' lro ('/' ('+' 1 dlr) 2) ;
'FINP' mil mel mal ;
* Passage au gravite d'un MCHAML
'DEBP' CHGRAV ch*'MCHAML';
'FINP' ('CHAN' ch ('MODE' ('EXTR' ch 'MAIL') 'THERMIQUE') 'GRAVITE') ;
* MINI entre 2 MCHAML
'DEBP' MINICHEL ;
'ARGU' ch1*'MCHAML' ;
'ARGU' ch2*'MCHAML' ;
   m1 = 'MASQ' ch1 'INFERIEUR' ch2 ;
   m2 = '-' 1. m1 ;
   minchel = ('*' m1 ch1) '+' ('*' m2 ch2) ;
'FINP' minchel ;
* Mesure des aretes dans une métrique
'DEBP' MESUARET ;
'ARGU' are*'MAILLAGE' ;
'ARGU' im*'CHPOINT' ;
* Transformation metrique en table
vdim = 'VALE' 'DIME' ;
timet = 'TABL' ;
'REPE' ii vdim ;
   i = &ii ;
   timet . i = 'TABL' ;
   'REPE' ij i ;
      j = &ij ;
      ngij = 'CHAI' 'G' i j ;
      timet . i . j = 'MAXI' ('EXCO' ngij im) ;
      timet . j . i = timet . i . j ;
   'FIN' ij ;
'FIN' ii ;
*
laretot = 'PROG' ;
nare = 'NBEL' are ;
'REPE' iiare nare ;
   iare = &iiare ;
   ar = 'ELEM' iare are ;
   p1 = 'POIN' ar 'INITIAL' ;
   p2 = 'POIN' ar 'FINAL' ;
   tvec = 'TABL' ;
   'REPE' ii vdim ;
      i = &ii ;
      tvec . i = '-' ('COOR' i p2) ('COOR' i p1) ;
   'FIN' ii ;
   lar2 = 0. ;
   'REPE' ij vdim ; j = &ij ;
      'REPE' ii vdim ; i = &ii ;
         lar2 = lar2 '+' ((timet . i . j) '*' (tvec . i) '*' (tvec . j)) ;
      'FIN' ii ;
   'FIN' ij ;
   laretot = laretot 'ET' (lar2 '**' 0.5) ;
'FIN' iiare ;
'RESP' laretot ;
'FINP' ;
*
'SI' ('NON' interact) ;
  'OPTION' 'TRAC' 'PSC' ;
'SINON' ;
  'OPTION' 'TRAC' 'X' ;
'FINSI' ;
*
for = '(F7.2)' ;
*
tol = '*' ('VALE' 'PREC') 10. ;
lok = vrai ;
*
hal = 0.5 ; mhal = -0.5 ;
irac3 = '**' 3. -0.5 ;
irac6 = '**' 6. -0.5 ;
'REPE' iikas 4 ;
*'REPE' iikas 1 ;
   ikas = &iikas ;
*   ikas = 2 ;
   'SI' ('<EG' ikas 2) ;
      'OPTI' 'DIME' 2 'ELEM' 'TRI3' ;
      'SI' ('EGA' ikas 1) ;
         'MESS' '***********    Triangle equilateral   ****************' ;
* Sommet du triangle equilateral
         pA = mhal ('*' mhal irac3) ;
         pB = hal  ('*' mhal irac3) ;
         pC = 0.   irac3 ;
      'SINO' ;
         'MESS' '***********    Triangle quelconque    ****************' ;
         pA = 0. 0. ; pB = pi 0. ; pC = ('EXP' 1) ('**' 2. 0.5) ;
      'FINS' ;
      ele = 'MANU' 'TRI3' pA pB pC ;
      met = 'MANU' 'CHPO' ele 3 'G11' 1.D0 'G22' 3.D0 'G21' 1.4 ;
      cmet = 'MANU' 'CHML' ele 'G11' 1.D0 'G22' 3.D0 'G21' 1.4 ;
      imet = 'TENS' 'INVE' met ; cimet = 'TENS' 'INVE' cmet ;
      metuni = 'MANU' 'CHPO' ele 3 'G11' 1.D0 'G22' 1.D0 'G21' 0.0 ;
      cmetuni = 'MANU' 'CHML' ele 'G11' 1.D0 'G22' 1.D0 'G21' 0.0 ;
   'SINO' ;
      'OPTI' 'DIME' 3 'ELEM' 'TET4' ;
      'SI' ('EGA' ikas 3) ;
         'MESS' '***********    Tetraedre equilateral   ****************' ;
* Sommet du tetraedre equilateral
         pA = mhal ('*' mhal irac3) ('*' mhal irac6) ;
         pB = hal  ('*' mhal irac3) ('*' mhal irac6) ;
         pC = 0.   irac3            ('*' mhal irac6) ;
         pD = 0.   0.               ('*' 1.5  irac6) ;
      'SINO' ;
         'MESS' '***********    Tetraedre quelconque    ****************' ;
         pA = 0. 0. 0. ; pB = pi 0. 0. ; pC = ('EXP' 1) ('**' 2. 0.5) 0. ;
         pD = 1. 1. ('**' 3. 0.5) ;
      'FINS' ;
      ele = 'MANU' 'TET4' pA pB pC pD ;
      met = 'MANU' 'CHPO' ele 6 'G11' 1.D0 'G22' 3.D0 'G33' 1.4 'G21' 0.14 'G31' 0.16 'G32' 0.15 ;
      cmet = 'MANU' 'CHML' ele 'G11' 1.D0 'G22' 3.D0 'G33' 1.4  'G21' 0.14 'G31' 0.16 'G32' 0.15 ;
      imet = 'TENS' 'INVE' met ; cimet = 'TENS' 'INVE' cmet ;
      metuni = 'MANU' 'CHPO' ele 6 'G11' 1.D0 'G22' 1.D0 'G33' 1.D0 'G21' 0.0 'G31' 0.0 'G32' 0.0 ;
      cmetuni = 'MANU' 'CHML' ele 'G11' 1.D0 'G22' 1.D0 'G33' 1.D0  'G21' 0.0 'G31' 0.0 'G32' 0.0 ;
 
   'FINS' ;
   vd = 'VALE' 'DIME' ; xvd = 'FLOT' vd ;
*
   metele = DEADMETR ele ;
   melele = metele ;
   melelem = DEADMETR ele imet ;
   'SI' ('OU' ('EGA' ikas 1) ('EGA' ikas 3)) ;
      dmet1  = '-' metele cmetuni ; mdmet1 = 'MAXI' dmet1 'ABS' ;
      'SI' ('NEG' mdmet1 0. tol) ; 'MESS'  '!!! TEST 1 failed'  ; lok = lok 'ET' faux ;
      'SINO' ;  'MESS'  '    TEST 1 passed' ; 'FINS' ;
      dmet2  = '-' melele cmetuni ; mdmet2 = 'MAXI' dmet2 'ABS' ;
      'SI' ('NEG' mdmet2 0. tol) ; 'MESS'  '!!! TEST 2 failed'  ; lok = lok 'ET' faux ;
      'SINO' ;  'MESS'  '    TEST 2 passed' ; 'FINS' ;
      dmet3  = '-' melelem cimet ; mdmet3 = 'MAXI' dmet3 'ABS' ;
      'SI' ('NEG' mdmet3 0. tol) ; 'MESS'  '!!! TEST 3 failed'  ; lok = lok 'ET' faux ;
      'SINO' ;  'MESS'  '    TEST 3 passed' ; 'FINS' ;
   'FINS' ;
*
   nomin = 'CHAI' 'SI' vd vd ;
   det   = 'TENS' 'DET'  melele  ; tra     = 'TENS' 'TRACE' melele ;
   vps2  = 'TENS' 'VALP' melele  ; vpmax2  = 'EXCO' 'SI11' vps2 'SCAL'  ; vpmin2  = 'EXCO' nomin vps2 'SCAL' ;
   detm  = 'TENS' 'DET'  melelem ; tram    = 'TENS' 'TRACE' melelem ;
   vpsm2 = 'TENS' 'VALP' melelem ; vpmaxm2 = 'EXCO' 'SI11' vpsm2 'SCAL' ; vpminm2 = 'EXCO' nomin vpsm2 'SCAL' ;
   'SI' ('EGA' vd 3) ; vpmoy2 = 'EXCO' 'SI22' vps2 'SCAL' ; vpmoym2 = 'EXCO' 'SI22' vpsm2 'SCAL' ; 'FINS' ;
*
   ldet  = det '**' (1. '/' (2. '*' vd))  ; ltra  = (tra '/' vd)  '**' (1. '/' 2.) ;
   ldetm = detm '**' (1. '/' (2. '*' vd)) ; ltram = (tram '/' vd) '**' (1. '/' 2.) ;
   vpmin  = '**' vpmin2  0.5 ; vpmax  = '**' vpmax2  0.5 ;
   vpminm = '**' vpminm2 0.5 ; vpmaxm = '**' vpmaxm2 0.5 ;
   'SI' ('EGA' vd 3) ; vpmoy = '**' vpmoy2 0.5 ; vpmoym = '**' vpmoym2 0.5 ; 'FINS' ;
   'SI' ('EGA' vd 2) ;
      ldet1 = '**' ('*' vpmin vpmax) ('/' 1. vd) ;
      ltra1 = '/'  ('+' vpmin vpmax) vd ;
      ldet1m = '**' ('*' vpminm vpmaxm) ('/' 1. vd) ;
      ltra1m = '/'  ('+' vpminm vpmaxm) vd ;
      lvp1m  = 'PROG' ('MAXI' vpmaxm) ('MAXI' vpminm) ;
   'FINS' ;
   'SI' ('EGA' vd 3) ;
      ldet1 = '**' ('*' vpmin vpmax '*' vpmoy) ('/' 1. vd) ;
      ltra1 = '/'  ('+' vpmin vpmax '+' vpmoy) vd ;
      ldet1m = '**' ('*' vpminm vpmaxm '*' vpmoym) ('/' 1. vd) ;
      ltra1m = '/'  ('+' vpminm vpmaxm '+' vpmoym) vd ;
      lvp1m  = 'PROG' ('MAXI' vpmaxm) ('MAXI' vpmoym) ('MAXI' vpminm) ;
   'FINS' ;
*
* Sans métrique (sans TOPO)
*
   inds = 'INDI' 'COHE' 'EQLT' 'DENS' ele ;
   cohe1 = 'EXCO' 'COHE' inds 'SCAL' ;
   cohe2 = ('/' ldet ltra) '**' ('/' xvd ('-' xvd 1)) ;
   dcohe = '-' cohe2 cohe1 ; mdcohe = 'MAXI' dcohe 'ABS' ;
   'SI' ('NEG' mdcohe 0. tol) ; 'MESS'  '!!! TEST COHE sans metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST COHE sans metrique passed' ; 'FINS' ;
   eqlt1 = 'EXCO' 'EQLT' inds 'SCAL' ;
   eqlt2 = cohe2 ;
   deqlt = '-' eqlt2 eqlt1 ; mdeqlt = 'MAXI' deqlt 'ABS' ;
   'SI' ('NEG' mdeqlt 0. tol) ; 'MESS'  '!!! TEST EQLT sans metrique failed'  ; lok = lok 'ET' faux ; 'FINS' ;
   'SINO' ; 'MESS'  '    TEST EQLT sans metrique passed' ; 'FINS' ;
   dens1 = 'EXCO' 'DENS' inds 'SCAL' ;
   dens2 = ldet ;
   ddens = '-' dens2 dens1 ; mddens = 'MAXI' ddens 'ABS' ;
   'SI' ('NEG' mddens 0. tol) ; 'MESS'  '!!! TEST DENS sans metrique failed'  ; lok = lok 'ET' faux ; 'FINS' ;
   'SINO' ; 'MESS'  '    TEST DENS sans metrique passed' ; 'FINS' ;
*
* Avec métrique (sans TOPO)
*
   indsm = 'INDI' 'COHE' 'EQLT' 'DENS' ele imet ;
   cohe1m = 'EXCO' 'COHE' indsm 'SCAL' ;
   cohe2m = ('/' ldetm ltram) '**' ('/' xvd ('-' xvd 1)) ;
   dcohem = '-' cohe2m cohe1m ; mdcohem = 'MAXI' dcohem 'ABS' ;
   'SI' ('NEG' mdcohem 0. tol) ; 'MESS'  '!!! TEST COHE avec metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST COHE avec metrique passed' ; 'FINS' ;
   eqlt1m = 'EXCO' 'EQLT' indsm 'SCAL' ;
   eqlt2m = cohe2 ;
   deqltm = '-' eqlt2m eqlt1m ; mdeqltm = 'MAXI' deqltm 'ABS' ;
   'SI' ('NEG' mdeqltm 0. tol) ; 'MESS'  '!!! TEST EQLT avec metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST EQLT avec metrique passed' ; 'FINS' ;
   dens1m = 'EXCO' 'DENS' indsm 'SCAL' ;
   dens2m = ldetm ;
   ddensm = '-' dens2m dens1m ; mddensm = 'MAXI' ddensm 'ABS' ;
   'SI' ('NEG' mddensm 0. tol) ; 'MESS'  '!!! TEST DENS avec metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST DENS avec metrique passed' ; 'FINS' ;
*
* TOPO (sans metrique)
*
*  icrit=0 (Coupez)
   indsm = 'INDI' 'TOPO' ele ('PROG' 0  -3. -3.) ;
   icrit0 = 'EXCO' 'TOPO' indsm  'SCAL' ;
* xcoq = n! sqrt(2^n/(n+1))
   xcoq= (FACTORIE vd) '*' ('**' ('/' ('**' 2. vd) ('+' vd 1.)) 0.5) ;
   are = 'CHAN' ele 'LIGN' ;
*   xlaari = '/' ('MESU' are) ('NBEL' are) ;
   mare = MESUARET are metuni ;
   xlaari = '/' ('SOMM' mare) ('DIME' mare) ;
   icrit0b = '/' ('**' ('*' ('MESU' ele) xcoq) ('/' 1. vd)) xlaari ;
   dicrit0 = '-' icrit0b icrit0 ; mdicrit0 = 'MAXI' dicrit0 'ABS' ;
   'SI' ('NEG' mdicrit0 0. tol) ; 'MESS'  '!!! TEST TOPO 0 sans metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST TOPO 0 sans metrique passed' ; 'FINS' ;
*  icrit=1 (XALIN2)
   indsm  = 'INDI' 'TOPO' ele ('PROG' 1  -3. -3.) ;
   icrit1 = 'EXCO' 'TOPO' indsm  'SCAL' ;
   icrit1b = cohe2 ;
   dicrit1 = '-' icrit1b icrit1 ; mdicrit1 = 'MAXI' dicrit1 'ABS' ;
   'SI' ('NEG' mdicrit1 0. tol) ; 'MESS'  '!!! TEST TOPO 1 sans metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST TOPO 1 sans metrique passed' ; 'FINS' ;
*  icrit=2 (XALIN1)
   indsm  = 'INDI' 'TOPO' ele ('PROG' 2  -3. -3.) ;
   icrit2 = 'EXCO' 'TOPO' indsm  'SCAL' ;
   icrit2b = ('/' ldet1 ltra1) '**' ('/' xvd ('-' xvd 1)) ;
   dicrit2 = '-' icrit2b icrit2 ; mdicrit2 = 'MAXI' dicrit2 'ABS' ;
   'SI' ('NEG' mdicrit2 0. tol) ; 'MESS'  '!!! TEST TOPO 2 sans metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST TOPO 2 sans metrique passed' ; 'FINS' ;
*  icrit=3 (lmin/lmax)
   indsm  = 'INDI' 'TOPO' ele ('PROG' 3  -3. -3.) ;
   icrit3 = 'EXCO' 'TOPO' indsm  'SCAL' ;
   icrit3b = '/' vpmin vpmax ;
   dicrit3 = '-' icrit3b icrit3 ; mdicrit3 = 'MAXI' dicrit3 'ABS' ;
   'SI' ('NEG' mdicrit3 0. tol) ; 'MESS'  '!!! TEST TOPO 3 sans metrique failed'  ; lok = lok 'ET' faux ;
   'SINO' ; 'MESS'  '    TEST TOPO 3 sans metrique passed' ; 'FINS' ;
*
* TOPO (avec metrique)
*
   ljcrit = 'LECT' 0 1 2 3 ;
   tjcrit = 'TABL' ;
   tjcrit . 0 = 'Coupez' ;
   tjcrit . 3 = 'lmin/lmax' ;
   tjcrit . 1 = 'XALIN2' ;
   tjcrit . 2 = 'XALIN1' ;
   'REPE' iilj ('DIME' ljcrit) ;
      jcrit = 'EXTR' ljcrit &iilj ;
      'MESS' '**** Critere j=' jcrit ' (' (tjcrit . jcrit) ')' ;
      'REPE' iicrit 2 ;
         icrit = &iicrit ;
         'SI' ('EGA' icrit 1) ;
            pcrit = 1. ; qcrit = 1. ;
         'SINO' ;
            pcrit = 10. ; qcrit = 3. ;
         'FINS' ;
         'MESS' '  avec  p=' pcrit ' et q=' qcrit ;
* Qualite
         jcritt = '+' jcrit 100 ;
         indsm  = 'INDI' 'TOPO' ele imet ('PROG' jcritt pcrit qcrit) ;
         jcrit100 = 'EXCO' 'TOPO' indsm  'SCAL' ;
         jcrit100b = ' ' ;
         'SI' ('EGA' jcrit 0) ;
* xcoq = n! sqrt(2^n/(n+1))
            xcoq= (FACTORIE vd) '*' ('**' ('/' ('**' 2. vd) ('+' vd 1.)) 0.5) ;
            are = 'CHAN' ele 'LIGN' ;
            mare = MESUARET are imet ;
            xlaari = '/' ('SOMM' mare) ('DIME' mare) ;
            dimet = '**' ('MAXI' ('TENS' 'DET' imet)) 0.5D0 ;
            jcrit100b = '/' ('**' ('*' ('*' ('MESU' ele) dimet) xcoq) ('/' 1. vd)) xlaari ;
         'FINS' ;
         'SI' ('EGA' jcrit 3) ;
            jcrit100b = '/' vpminm vpmaxm ;
         'FINS' ;
         'SI' ('EGA' jcrit 1) ;
            jcrit100b = cohe2m ;
         'FINS' ;
         'SI' ('EGA' jcrit 2) ;
            jcrit100b = ('/' ldet1m ltra1m) '**' ('/' xvd ('-' xvd 1)) ;
         'FINS' ;
         jcrit100b = '**' jcrit100b ('/' 1. qcrit) ;
         djcrit100 = '-' jcrit100b jcrit100 ; mdjcrit100 = 'MAXI' djcrit100 'ABS' ;
         'SI' ('NEG' mdjcrit100 0. tol) ; 'MESS'  '!!! TEST TOPO' ' ' jcritt ' avec metrique failed'  ; lok = lok 'ET' faux ;
         'SINO' ; 'MESS'  '    TEST TOPO' ' ' jcritt ' avec metrique passed' ; 'FINS' ;
* Longueur
         jcritt = '+' jcrit 200 ;
         indsm  = 'INDI' 'TOPO' ele imet ('PROG' jcritt pcrit qcrit) ;
         jcrit200 = 'EXCO' 'TOPO' indsm  'SCAL' ;
         jcrit200b = ' ' ;
         'SI' ('EGA' jcrit 0) ;
            jcrit200b = 'AGRE' 'PMOY' mare pcrit 'ROBU' ;
         'SINO' ;
            jcrit200b = 'AGRE' 'PMOY' lvp1m pcrit 'ROBU' ;
         'FINS' ;
         djcrit200 = '-' jcrit200b jcrit200 ; mdjcrit200 = 'MAXI' djcrit200 'ABS' ;
         'SI' ('NEG' mdjcrit200 0. tol) ; 'MESS'  '!!! TEST TOPO' ' ' jcritt ' avec metrique failed'  ; lok = lok 'ET' faux ;
         'SINO' ; 'MESS'  '    TEST TOPO' ' ' jcritt ' avec metrique passed' ; 'FINS' ;
* Longueur Inverse
         jcritt = '+' jcrit 300 ;
         indsm  = 'INDI' 'TOPO' ele imet ('PROG' jcritt pcrit qcrit) ;
         jcrit300 = 'EXCO' 'TOPO' indsm  'SCAL' ;
         jcrit300b = 1.D0 '/' jcrit200b ;
         djcrit300 = '-' jcrit300b jcrit300 ; mdjcrit300 = 'MAXI' djcrit300 'ABS' ;
         'SI' ('NEG' mdjcrit300 0. tol) ; 'MESS'  '!!! TEST TOPO' ' ' jcritt ' avec metrique failed'  ; lok = lok 'ET' faux ;
         'SINO' ; 'MESS'  '    TEST TOPO' ' ' jcritt ' avec metrique passed' ; 'FINS' ;
* Total
         jcritt = jcrit ;
         indsm  = 'INDI' 'TOPO' ele imet ('PROG' jcritt pcrit qcrit) ;
         jcrit0 = 'EXCO' 'TOPO' indsm  'SCAL' ;
         jcrit0b = 'MINI' ('PROG' ('MAXI' jcrit100b) jcrit200b jcrit300b) ;
         djcrit0 = '-' jcrit0b jcrit0 ; mdjcrit0 = 'MAXI' djcrit0 'ABS' ;
         'SI' ('NEG' mdjcrit0 0. tol) ; 'MESS'  '!!! TEST TOPO' ' ' jcritt ' avec metrique failed'  ; lok = lok 'ET' faux ;
         'SINO' ; 'MESS'  '    TEST TOPO' ' ' jcritt ' avec metrique passed' ; 'FINS' ;
      'FIN' iicrit ;
   'FIN' iilj ;
'FIN' iikas ;
*
'SI' ('NON' lok) ;
   'MESSAGE' ('CHAINE' '!!! Il y a eu des erreurs') ;
'SINON' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'OPTI' echo 1 ;
'SI' interact ;
   'OPTI' 'DONN'  5 ;
'FINS' ;
'SI' ('NON' lok) ;
   'ERRE' 5 ;
'FINS' ;
 
*
* End of dgibi file INDI3.DGIBI
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales