Exemples de jeux de données Cast3M

* fichier :  hy2.dgibi
**
**  --- 2 JUIN 1993 ---
**   PERTES DE CHARGE et GMV (Groupe Moto Ventilateur)
**
**   CANAL LONGUEUR 10. LARGEUR 1.
**
**   test cas isotherme NS FROT ET GMV
**
**  On considre l'coulement dans un canal plan vertical
**  compris entre les plans x=0 et x=1. la hauteur est de 10.
**  A proximite de la sortie du canal on a place un faisceau de tube.
**  modelise par une perte de charge du type K U**BETA
**  Dans la zone d'entree on a place un GMV
**
**
**
**
**
**
OPTION DIME 2 ELEM QUA4 ;                                               
GRAPH=VRAI ;
GRAPH=FAUX ;
FIN;
p1=0  0.;
p2=1. 0.;
entree= p1 d 14 p2 ;                                                    
c1= 5. 0. ;
 
* ikas= 0 --> DROIT (option par defaut)  ikas=1 --> COURBE
ikas=0 ;
mess 'ikas= 0 --> DROIT (option par defaut)  ikas=1 --> COURBE  ? ';
*obtenir ikas*entier ;
 
si (EGA ikas 1) ;
 
q1=p1 tour c1 -90. ;
q2=p2 tour c1 -90. ;
pp1=p1 c c1 q1 20 ;                                                     
pp2=p2 c c1 q2 20 ;
sortie=entree tour c1 -90 ;
 
sinon ;
 
q1=p1 plus (0 10)  ;
q2=p2 plus (0 10)  ;
pp1=p1 d q1 20 ;
pp2=p2 d q2 20 ;
sortie=entree plus (0 10) ;
finsi ;
 
pp1=inve pp1 ;
sortie=inve sortie;
elim 0.0001 (sortie et pp1 et pp2 );
cnt=entree et pp2 et sortie et pp1 ;
*bell=surf cnt ;
 
bell=daller entree pp2 sortie pp1 ;
angle=0. ;
*obtenir angle*flottant ;
 
 
bell=bell tour c1 angle ;
entree=entree tour c1 angle ;
sortie=sortie tour c1 angle ;
pp1=pp1 tour c1 angle ;
pp2=pp2 tour c1 angle ;
 
*pp1=inve pp1 ;
elim (pp1 et pp2 et entree et sortie et bell) 0.0001 ;
entref=entree elem seg2 (lect 2 pas 1 13) ;
*entree=inve entree ;
*sortie=inve sortie ;
 
 $bell=doma bell ;
 $bell.titre= 'CHAINE' 'TEST PERTES DE CHARGE ET GMV' ;
 $entree = doma entree 'INCL' $bell 1.e-4 ;
 $entref = doma entref 'INCL' $bell 1.e-4 ;
 $sortie = doma sortie 'INCL' $bell 1.e-4 ;
 $pp1    = doma pp1    'INCL' $bell 1.e-4 ;
 $pp2    = doma pp2    'INCL' $bell 1.e-4 ;
ech=bell elem qua4 (lect 211 pas 1 252) ;
 $ech    = doma ech    'INCL' $bell 1.e-4 ;
 
gmvi=bell elem qua4 ( (lect 62 pas 1 65) et (lect 76 pas 1 79)) ;
cgmv=cont gmvi ;
legmv=cgmv elem seg2 (lect 1 pas 1 4) ;
lsgmv=cgmv elem seg2 (lect 7 pas 1 10) ;
$gmv=doma gmvi 'INCL' $bell 1.e-5 ;
egmv=gmvi elem 'APPUYE' 'LARGEMENT' legmv;
sgmv=gmvi elem 'APPUYE' 'LARGEMENT' lsgmv;
$egmv=doma egmv 'INCL' $gmv 1.e-5 ;
$sgmv=doma sgmv 'INCL' $gmv 1.e-5 ;
 
 
 CK= 100. 100. ;
 CB= 2. 2. ;
 
 tabgmv=table ;
 tabgmv.'DIR'= 0. 1. ;
 tabgmv.'PENTREE'=($egmv.centre);
 tabgmv.'PSORTIE'=($sgmv.centre);
 tabgmv.'LDEBIT'=legmv ;
 tabgmv.'IMPR'=5 ;
*tabgmv.'KIMP'=10. ;
 tabgmv.'GMV'= EVOL 'MANU'
 'DEBIT'
 (prog 0.3 0.6 0.8 1.)
 'PRESSION'
 (prog 180. 130. 80. 0.) ;
 Si GRAPH ;dessin tabgmv.'GMV' ;FINSI ;
 tabgmv.omega=0.2 ;
 list tabgmv ;
 
 nu=5.E-1 ;
 tpsc=1500 ;
 zero=1.e-20 ;
 
  rv=eqex $bell 'DUMP' ALFA 0.7  ITMA 400
  ZONE  $BELL    OPER    NS     NU        INCO 'UN'
  ZONE  $ech     OPER    'FROT' CK CB     INCO 'UN'
  ZONE  $gmv     OPER    'GMV'  tabgmv    INCO 'UN'
  CLIM  'UN' UIMP GMVi 0. ;
 
  rvp= eqpr $bell zone $bell oper PRESSION  0.
  zone $PP1    oper VNIMP 0.
  zone $PP1    oper VTIMP 0.
  zone $PP2    oper VNIMP 0.
  zone $PP2    oper VTIMP 0. ;
 
rv.'INCO'.'UN' = kcht $bell vect sommet (1.e-5 1.   ) ;
rv.pression=rvp ;
rv.'FIDT'=20;
 
lh= (noeu 10) et (noeu 20) et (noeu 30) et (noeu 40)  et
 (noeu 50) et (noeu 60) ;
lj= (manu poi1 ($bell.maillage poin proc( 0.5 0.5) ) ) ;
    his = khis 'UN' 1 lh 'UN' 2 (lh et lj) ;
   rv.'HIST'=his ;
opti veri 1;
    exec rv ;
 
  PN = rvp.'PN' ;
  un= (rv.'INCO'.'UN') ;
  ung1 = vect 0.1 un ux uy jaune ;
 
qe=dbit un $entree  ;
qs=dbit un $sortie  ;
dq=(abs qe )-(abs qs) ;
mess (' BILAN : dq=')  dq ;
Si GRAPH ;
dessin his.'TABD' his.'1UN' ;
dessin his.'TABD' his.'2UN' ;
 
trace ung1 bell ;
trace pn   bell ;
FINSI ;
FIN ;