Télécharger la plaquette Cast3M


fr en

Télécharger huittra3d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : huittra3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE 8Chaines       QUASI-INCOMPRESSIBLE    *
  6. *                  EN GRANDES TRANSFORMATIONS                          *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE             *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22. message ' ce cas test fini par non convergence ! ';
  23. fin;
  24. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  25. option epsilon 'UTILISATEUR'
  26. *opti trac PSC;
  27. * Mettre VRAI si l'on souhaite divers traces.
  28. GRAPH = VRAI ;
  29. GRAPH = FAUX;
  30. * Mettre 1 ou 2 selon le type de calcul voulu
  31. ICALCUL = 1;
  32. *
  33. 'SI' ('>' ICALCUL 2) ;
  34.   'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  35.   'ERREUR' 5 ;
  36. 'FINSI' ;
  37.  
  38. title = 'CHAINE'  '8 Chaines - '  'TRACTION UNIAXIALE Z' ;
  39.  
  40. *======================================================================*
  41. *             Geometrie - Maillage                                     *
  42. *======================================================================*
  43. * Longueur (direction x) du pave :
  44. Lg_x = 1. ;
  45. * Largeur (direction y) du pave :
  46. Lg_y = 1. ;
  47. * Hauteur (direction z) du pave :
  48. Lg_z = 1. ;
  49. * Nombre d'elements selon les directions x, y et z :
  50. 'SI' ('EGA' ICALCUL 1) ;
  51.   Nel_x = 2  ;
  52.   Nel_y = 2  ;
  53.   Nel_z = 2 ;
  54. * 'TET4' 'PRI6'  'PYR5' 'TET4' 'CUB8'
  55.   'OPTION' 'ELEM' 'CUB8'  ;
  56. 'FINSI' ;
  57. 'SI' ('EGA' ICALCUL 2) ;
  58.   Nel_x = 3 ;
  59.   Nel_y = 3 ;
  60.   Nel_z = 3 ;
  61. *CU20  
  62.   'OPTION' 'ELEM' 'CUB8';
  63. 'FINSI' ;
  64. *'CU20'
  65. P1 =  0.    0. 0. ;
  66. P2 = Lg_x   0. 0. ;
  67. P3 = Lg_x Lg_y 0. ;
  68. P4 =  0.  Lg_y 0. ;
  69. *
  70. L1 = 'DROITE' Nel_x P1 P2 ;
  71. L2 = 'DROITE' Nel_y P2 P3 ;
  72. L3 = 'DROITE' Nel_x P3 P4 ;
  73. L4 = 'DROITE' Nel_y P4 P1 ;
  74. *
  75. SBas = 'DALLER' L1 L2 L3 L4 ;
  76. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  77. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  78. 'SI' GRAPH ;
  79.   'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  80. 'FINSI' ;
  81.  
  82. *======================================================================*
  83. *             Modele - Materiau - Caracteristiques (en MPa)             *
  84. *======================================================================*
  85. * Ne pas oublier de definir les parametres lies a l'elasticite.
  86. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  87. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  88. *
  89. LCMAT = MOTS 'YOUN' 'NU  '   'NKT'  'VN  '    'D  ';
  90. MO = MODE Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  91.                     'NON_LINEAIRE' 'UTILISATEUR'
  92.                 'NUME_LOI' 36  'C_MATERIAU' LCMAT ;
  93. *
  94. * Pour calculer le module d'Young, on utilise les
  95. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  96. * 
  97. C1 = 0.183  ;     C2 = 0.0034   ;
  98. * 
  99. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  100. * du fait de l'incompressibilite inherente au modele.
  101. * Le module de Young YOU est alors connu, car, pour ce modele, le
  102. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  103. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  104. * de la traction. En fonction du niveau de deformation atteinte en 
  105. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  106. * converger les calculs (module tangent en fin de calculs).
  107. * Prendre des valeurs superieures n'entraine pas de modification des
  108. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  109. *XNU = 0.497 ;
  110. YOUini = 3.*(2.*(C1+C2)) ;  
  111. *
  112. 'SI' ('EGA' ICALCUL 1) ;
  113.   XNU = 0.497 ;
  114.   CoeD  = 1.E-4   ; 
  115.   YOU = 1000. * YOUini ;
  116. 'FINSI' ;
  117. 'SI' ('EGA' ICALCUL 2) ;
  118.   XNU = 0.497;
  119.   CoeD  = 1.E-4   ;  
  120. *  YOU = 50000. * YOUini ;
  121.   YOU = 1000. * YOUini ;
  122. 'FINSI' ;
  123. *
  124. *Parametres du modèle 8chaines : essais Treloar/Kawabata MPa
  125. xnkt = 0.28;
  126. xvn = 25.4;
  127. * 
  128. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'NKT' xnkt 'VN' xvn 
  129.  'D   ' CoeD ;
  130. *==================================================================*
  131. *                      Conditions aux limites                      *
  132. *==================================================================*
  133. BL1 = 'BLOQUER' 'UZ  ' Shau ;
  134. BL2 = 'BLOQUER' 'UZ  ' Sbas ;
  135. BL3 = 'BLOQUER' 'UX  ' L4 ;
  136. BL4 = 'BLOQUER' 'UY  ' L1 ;
  137. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  138. *
  139. * Definition des instants du chargement :
  140. t_deb = 0. ;   t_fin = 10. ;
  141. L_tps = 'PROG' t_deb t_fin ;
  142. * Deplacement suivant Z : 
  143. L_UZ = 'PROG' 0. (6.  * Lg_z) ;
  144. FF_z = 'DEPIMP' BL1 1. ;
  145. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMZ' L_UZ ;
  146. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  147. *======================================================================*
  148. *             Initialisation de la table pour appel a PASAPAS          *
  149. *======================================================================*
  150. TAB1 = 'TABLE' ;
  151. TAB1.'MODELE' = MO ;
  152. TAB1.'CARACTERISTIQUES' = MA ;
  153. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  154. TAB1.'CHARGEMENT' = CHARTOT ;
  155. *TAB1.'PAS_AJUSTE'= VRAI;
  156. *TAB1.'PRECISION' = 1.E-7 ;
  157. *TAB1.'FTOL' = 1.E-5 ;
  158. *TAB1.'MTOL' = 1.E-5 ;
  159. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  160. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  161. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  162. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  163. tab1.'REAC_GRANDS'=500.;
  164. tab1.precision=1.2e-4;
  165. *
  166. L_abs = TAB1.'TEMPS_SAUVES' ;
  167. n_abs = 'DIMENSION' L_abs ;
  168. *
  169. PASAPAS TAB1 ;
  170. *
  171. * Quelques traces de controle apres calculs
  172. 'SI' GRAPH ;
  173.   Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  174.   Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  175.   'TRACER' (Defo_0 'ET' Defo_1)
  176.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  177.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  178.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  179. 'FINSI' ;
  180. *
  181. *======================================================================*
  182. *             Construction de la solution analytique INCOMPRESSIBLE    *
  183. *======================================================================*
  184. * Definitions :
  185. * - Allongement selon direction y : Lamz = 1 + (UY/Lg_y)
  186. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  187. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  188. * Dans le cas du modele de 8 Chaines :
  189. *   W =   , soit dW/dI1 =   et dW/dI2 =  0
  190. * Les contraintes de Cauchy sont calculables analytiquement :
  191. * - SCzz = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  192. *
  193. L_Un  = 'PROG' n_abs '*' 1. ;
  194. Lamz  = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  195. *
  196. SCxx_th = 0. * L_Un ;
  197. SCyy_th = 0. * L_Un ;
  198. L_z1 = Lamz * Lamz ;  L_z2 = L_Un / Lamz ;
  199. L_tr = L_Un * 3.;
  200. I1 = L_z1 + (2. * L_z2);
  201. I2 = (2. * Lamz) + ( L_Un /  L_z1 );
  202. ************************************************************************
  203. ****************** modele 8 Chaines *************************************
  204.       ufj = L_Un*xnkt*0.5;
  205.       alp = xnkt*(0.1/xvn)*(L_Un * I1 );
  206.       xop = xnkt*((33./(1050.*(xvn**2)))*((L_Un * (I1 **2))));
  207.       lmp = xnkt*((19.*4./(7000.*(xvn**3)))*((L_Un * (I1 **3))));
  208.       mpo = xnkt*((519.*5./(673750.*(xvn**4)))*((L_Un * (I1 **4))));
  209. *
  210. dWI1= ufj+alp+xop+lmp+mpo;
  211. dWI2= L_Un*0.;
  212. ************************************************************************
  213. SCzz_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  214. SCxy_th = 0. * L_Un ;
  215. SCxz_th = 0. * L_Un ;
  216. SCyz_th = 0. * L_Un ;
  217. * 
  218. *======================================================================*
  219. *             Comparaison des resultats avec la solution analytique    *
  220. *======================================================================*
  221. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  222. * calculees et les solutions analytiques correspondantes.
  223. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  224. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  225. *
  226. TabD = TAB1.'DEPLACEMENTS' ;
  227. TabS = TAB1.'CONTRAINTES' ;
  228. Confini = 'FORM' ;
  229. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  230. *
  231. SCxx = 'PROG' 0. ;
  232. SCyy = 'PROG' 0. ;
  233. SCzz = 'PROG' 0. ;
  234. SCxy = 'PROG' 0. ;
  235. SCxz = 'PROG' 0. ;
  236. SCyz = 'PROG' 0. ;
  237. 'REPETER' Boucle (n_abs - 1) ;
  238.   'FORM' (TabD.&Boucle) ;
  239.   VolSU = 'INTG' MO ChmUn ;
  240. *  mess ' volsu '  volsu; 
  241.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  242.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  243.   SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  244.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  245.   SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  246.   SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  247.   'FORM' Confini ;
  248. 'FIN' Boucle ;
  249. *
  250. *  LG lamb
  251. L_abs = Lamz;
  252. *
  253. 'SI' GRAPH ;
  254.   tlege = 'TABLE' ;
  255.   tlege. 1 = 'MARQ CROI' ;
  256.   tlege.'TITRE' = 'TABLE' ;
  257.   tlege.'TITRE'. 1 = 'Numerique' ;
  258.   tlege.'TITRE'. 2 = 'Analytique' ;
  259.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  260.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  261.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  262.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  263.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  264.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  265.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  266.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  267.   Evzz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  268.   Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  269.   'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  270.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  271.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  272.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  273.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  274.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  275.   Evxz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  276.   Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  277.   'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  278.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  279.   Evyz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  280.   Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  281.   'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  282.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  283. 'FINSI' ;
  284. *
  285. * Tests de bon fonctionnement :
  286. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  287. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  288. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  289. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  290. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  291. list sczz; list SCzz_th;  list uu;
  292. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  293. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  294. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  295. *
  296. MESS ' RESULTATS : ' title ;
  297. MESS ' ------------------------------------------------- ';
  298. 'SAUTER' 1 'LIGNE' ;
  299. 'MESS' '  Tests de bon fonctionnement :' ;
  300. 'MESS' ' -------------------------------' ;
  301. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  302. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  303. 'MESS' '                          et la solution analytique' ;
  304. 'MESS' ' Composante XX : ' r_xx   ;
  305. 'MESS' ' Composante YY : ' r_yy   ;
  306. 'MESS' ' Composante ZZ : ' r_zz   ;
  307. 'MESS' ' Composante XY : ' r_xy   ;
  308. 'MESS' ' Composante XZ : ' r_xz   ;
  309. 'MESS' ' Composante YZ : ' r_yz   ;
  310. 'SAUTER' 1 'LIGNE' ;
  311. * Ecart relatif maximal tolere
  312. 'SI' ('EGA' ICALCUL 1) ;
  313.   Sigref = 1.E-3 ;
  314. 'FINSI' ;
  315. 'SI' ('EGA' ICALCUL 2) ;
  316.   Sigref = 1.E-2 ;
  317. 'FINSI' ;
  318. *
  319. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  320. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  321.   'MESS' ' ---------------------' ;
  322.   'MESS' '  ECHEC DU CAS-TEST !' ;
  323.   'MESS' ' ---------------------' ;
  324.   'ERREUR' 5 ;
  325. 'SINON' ;
  326.   'MESS' ' ----------------------' ;
  327.   'MESS' '  SUCCES DU CAS-TEST !' ;
  328.   'MESS' ' ----------------------' ;
  329. 'FINSI' ;
  330. 'SAUTER' 1 'LIGNE' ;
  331. 'FIN' ;
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  
  342.  
  343.  
  344.  
  345.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales