Télécharger la plaquette Cast3M


fr en

Télécharger harttracdp.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : harttracdp.dgibi 
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE HART-SMITH QUASI-INCOMPRESSIBLE        *
  6. *           EN GRANDES TRANSFORMATIONS - DEFORMATIONS PLANES           *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION  Y      *
  9. *    DEFORMATIONS PLANES COMPARAISON AVEC LA SOLUTION ANALYTIQUE       *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22. * 
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  24.  
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = VRAI ;
  28. GRAPH = FAUX ;
  29. title = 'CHAINE' 'HART-SMITH -' 'TRACTION UNIAXIALE Y' ;
  30. *
  31. *======================================================================*
  32. *             Geometrie - Maillage                                     *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1. ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 1. ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 3;
  40. Nel_y = 4 ;
  41. * 'TRI6' 'TRI3'   'QUA8'
  42. 'OPTION' 'ELEM' 'QUA4' ;
  43. *
  44. P1 =  0.    0. ;
  45. P2 = Lg_x   0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 =  0.  Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58. *
  59. *======================================================================*
  60. *             Modele - Materiau - Caracteristiques (en Pa)             *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  63.       ('NEG' ('VALEUR' 'MODE') 'PLANDEFO' )) ;
  64.   'MESS' 'Ce modele ne fonctionne qu en 2D DEFORMATIONS PLANES' ;
  65.   'ERREUR' 5 ;
  66. 'FINSI' ;
  67. * 
  68. * Calcul du Module d'Young 
  69. * Ne pas oublier de definir les parametres lies a l'elasticite.
  70. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  71. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  72. *
  73. LCMAT = MOTS 'YOUN' 'NU  ' 'G'  'K1'  'K2' 'D' ;
  74. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  75.                     'NON_LINEAIRE' 'UTILISATEUR'
  76.                     'NUME_LOI' 34  'C_MATERIAU' LCMAT ;
  77. *
  78. * Pour calculer le module d'Young, on utilise les
  79. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  80. * 
  81. C1 = 0.183  ;     C2 = 0.0034   ;
  82. * 
  83. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  84. * du fait de l'incompressibilite inherente au modele.
  85. * Le module de Young YOU est alors connu, car, pour ce modele, le
  86. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  87. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  88. * de la traction. En fonction du niveau de deformation atteinte en 
  89. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  90. * converger les calculs (module tangent en fin de calculs).
  91. * Prendre des valeurs superieures n'entraine pas de modification des
  92. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  93. *
  94. XNU = 0.499 ;
  95. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  96. *
  97. *Parametres du modèle HS : essais Treloar/Kawabata MPa
  98. G = 0.175  ;
  99. K1 = 2.86E-4   ;
  100. K2 = 0.311   ;
  101. * 
  102. CoeD  =   1.E-4 ; 
  103. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'G' G 'K1' K1 'K2' K2 'D' CoeD ;
  104. *
  105. *======================================================================*
  106. *             Conditions aux limites - Traction suivant UY             *
  107. *======================================================================*
  108. BL1 = 'BLOQUER' 'UY  ' L1 ;
  109. BL2 = 'BLOQUER' 'UY  ' L3 ;
  110. BL4 = 'BLOQUER' 'UX  ' P1 ;
  111. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  112. *
  113. * Definition des instants du chargement :
  114. t_deb = 0. ;   t_fin = 10. ;
  115. L_tps = 'PROG' t_deb t_fin ;
  116. * Deplacement suivant Y :
  117. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  118. FF_y = 'DEPIMP' BL2 1. ;
  119. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  120.  
  121. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  122.  
  123. *======================================================================*
  124. *             Initialisation de la table pour appel a PASAPAS          *
  125. *======================================================================*
  126. TAB1 = 'TABLE' ;
  127. TAB1.'MODELE' = MO ;
  128. TAB1.'CARACTERISTIQUES' = MA ;
  129. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  130. TAB1.'CHARGEMENT' = CHARTOT ;
  131. ***** LG
  132. *TAB1 . 'DELTAITER' = 150;
  133. *TAB1.'PRECISION' = 1.E-5 ;
  134. *TAB1.'FTOL' = 1.E-5 ;
  135. *TAB1.'MTOL' = 1.E-5 ;
  136. *****
  137. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  138. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  139. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  140. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  141. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  142. tab1.reac_grands=500.;
  143. *
  144. L_abs = TAB1.'TEMPS_SAUVES' ;
  145. n_abs = 'DIMENSION' L_abs ;
  146. *
  147. PASAPAS TAB1 ;
  148. *
  149. * Quelques traces de controle apres calculs
  150. 'SI' GRAPH ;
  151.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  152.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  153.   'TRACER' (Defo_0 'ET' Defo_1)
  154.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  155.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  156.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  157. 'FINSI' ;
  158. *
  159. *======================================================================*
  160. *             Construction de la solution analytique                   *
  161. *======================================================================*
  162. * Definitions :
  163. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  164. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  165. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  166. * Dans le cas du modele de HART-SMITH : Incompressible
  167. * dW/dI1 = G * exp (k1 * (I1 - 3)**2) et dW/dI2 = G * k2 * 1 / I2 
  168. *
  169. * Les contraintes de Cauchy sont calculables analytiquement :
  170. * - SCxx = 0.
  171. * - SCyy = 2.(Lamy**2 - 1./Lamy**2).(dW/dI1 + dW/dI2)
  172. * - SCxy = 0  (pas de cisaillement)
  173. * - SCzz = 0  (hypothese des contraintes planes)
  174. *
  175. L_Un  = 'PROG' n_abs '*' 1. ;
  176. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  177. *
  178. L_z1 = Lamy * Lamy ;  L_z2 = L_Un / (Lamy * Lamy);
  179. * LG modif hartsmith !! averifier
  180. L_tr = L_Un * 3.;
  181. I1 = L_z1 +   L_z2 + L_Un ;
  182. I2 = I1 ;
  183. **********************************************************************
  184. dWI1= G * (exp (k1 *((I1 - L_tr)**2)));
  185. dWI2= G * k2 * L_Un / I2;
  186. **********************************************************************
  187. SCxx_th = 0. * L_Un ;
  188. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_Un)) ;
  189. SCxy_th = 0. * L_Un ;
  190.  
  191. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  192. *dess  Evyy_th ;
  193. *======================================================================*
  194. *             Comparaison des resultats avec la solution analytique    *
  195. *======================================================================*
  196. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  197. * calculees et les solutions analytiques correspondantes.
  198. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  199. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  200. *
  201. TabD = TAB1.'DEPLACEMENTS' ;
  202. TabS = TAB1.'CONTRAINTES' ;
  203. Confini = 'FORM' ;
  204. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  205. *
  206. SCxx = 'PROG' 0. ;
  207. SCyy = 'PROG' 0. ;
  208. SCxy = 'PROG' 0. ;
  209. 'REPETER' Boucle (n_abs - 1) ;
  210.   'FORM' (TabD.&Boucle) ;
  211.   VolSU = 'INTG' MO ChmUn ;
  212.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  213.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  214.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  215.   'FORM' Confini ;
  216. 'FIN' Boucle ;
  217. *  LG lamb
  218. L_abs = Lamy;
  219. *
  220. 'SI' GRAPH ;
  221.   tlege = 'TABLE' ;
  222.   tlege. 1 = 'MARQ CROI' ;
  223.   tlege.'TITRE' = 'TABLE' ;
  224.   tlege.'TITRE'. 1 = 'Numerique' ;
  225.   tlege.'TITRE'. 2 = 'Analytique' ;
  226.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  227.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  228.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  229.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  230.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  231.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  232.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  233.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  234.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  235.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  236.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  237.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  238. 'FINSI' ;
  239. *
  240. * Tests de bon fonctionnement :
  241. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  242. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  243. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  244. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  245. *
  246. MESS ' RESULTATS : ' title ;
  247. MESS ' ------------------------------------------------- ';
  248. 'SAUTER' 1 'LIGNE' ;
  249. 'MESS' '  Tests de bon fonctionnement :' ;
  250. 'MESS' ' -------------------------------' ;
  251. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  252. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  253.        'calculee' ;
  254. 'MESS' '                          et la '
  255.        'solution analytique associee' ;
  256. 'MESS' ' Composante XX : ' r_xx   ;
  257. 'MESS' ' Composante YY : ' r_yy   ;
  258. 'MESS' ' Composante XY : ' r_xy   ;
  259. 'SAUTER' 1 'LIGNE' ;
  260. * Ecart relatif maximal tolere
  261. Sigref = 1.E-3 ;
  262. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  263.   'MESS' ' ---------------------' ;
  264.   'MESS' '  ECHEC DU CAS-TEST !' ;
  265.   'MESS' ' ---------------------' ;
  266.   'ERREUR' 5 ;
  267. 'SINON' ;
  268.   'MESS' ' ----------------------' ;
  269.   'MESS' '  SUCCES DU CAS-TEST !' ;
  270.   'MESS' ' ----------------------' ;
  271. 'FINSI' ;
  272. 'SAUTER' 1 'LIGNE' ;
  273.  
  274. 'FIN' ;
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales