Télécharger la plaquette Cast3M


fr en

Télécharger gdtractdp.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : gdtractdp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE GORNET-DESMORAT QUASI INCOMPRESSIBLE   *
  6. *           EN GRANDES TRANSFORMATIONS - DEFORMATIONS PLANES           *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y       *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  14. *                                                                      *
  15. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  16. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  17. *         pas melanger les derivees objectives et les modeles de C3m.  *
  18. *======================================================================*
  19. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  20. * Mettre VRAI si l'on souhaite divers traces.
  21. GRAPH = VRAI ;
  22. GRAPH = FAUX ;
  23. title = 'CHAINE' 'GORNET-DESMORAT -DEFO PLANES' 'TRACTION UNIAXIALE Y';
  24. *======================================================================*
  25. *             Geometrie - Maillage                                     *
  26. *======================================================================*
  27. * Longueur (direction x) de la plaque/membrane :
  28. Lg_x = 1. ;
  29. * Largeur (direction y) de la plaque/membrane :
  30. Lg_y = 1. ;
  31. * Nombre d'elements selon les directions x et y :
  32. Nel_x = 3;
  33. Nel_y = 2 ;
  34. * 'TRI6' 'TRI3'  'QUA8' 'QUA4'
  35. 'OPTION' 'ELEM' 'QUA4' ;
  36. *
  37. P1 =  0.    0. ;
  38. P2 = Lg_x   0. ;
  39. P3 = Lg_x Lg_y ;
  40. P4 =  0.  Lg_y ;
  41. *
  42. L1 = 'DROITE' Nel_x P1 P2 ;
  43. L2 = 'DROITE' Nel_y P2 P3 ;
  44. L3 = 'DROITE' Nel_x P3 P4 ;
  45. L4 = 'DROITE' Nel_y P4 P1 ;
  46. *
  47. SU = 'DALLER' L1 L2 L3 L4 ;
  48. 'SI' GRAPH ;
  49.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  50. 'FINSI' ;
  51.  
  52. *======================================================================*
  53. *             Modele - Materiau - Caracteristiques (en MPa)             *
  54. *======================================================================*
  55. *
  56. * Calcul du Module d'Young
  57. * Ne pas oublier de definir les parametres lies a l'elasticite.
  58. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  59. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  60. *
  61. LCMAT = MOTS 'YOUN' 'NU  '    'H1'  'H2'  'H3'  'D  ';
  62. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  63.                     'NON_LINEAIRE' 'UTILISATEUR'
  64.                 'NUME_LOI' 33  'C_MATERIAU' LCMAT ;
  65. *
  66. * Pour calculer le module d'Young, on utilise les
  67. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  68. * 
  69. C1 = 0.183  ;     C2 = 0.0034   ;
  70. * 
  71. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  72. * du fait de l'incompressibilite inherente au modele.
  73. * Le module de Young YOU est alors connu, car, pour ce modele, le
  74. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  75. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  76. * de la traction. En fonction du niveau de deformation atteinte en 
  77. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  78. * converger les calculs (module tangent en fin de calculs).
  79. * Prendre des valeurs superieures n'entraine pas de modification des
  80. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  81. *
  82. XNU = 0.497 ;
  83. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  84. *
  85. * Coef quasi-incompressible
  86. CoeD  =   1.E-4 ;
  87. *Parametres de Treloar
  88. H1 = 0.142236  ;
  89. H2 = 1.5854659E-2   ;
  90. H3 = 3.4946541E-4   ;
  91. *
  92. * 
  93. MA = MATE MO 'YOUN' YOU 'NU  ' XNU  'H1' H1 'H2' H2 
  94. 'H3' H3  'D   ' CoeD ;
  95. *
  96. *
  97. *======================================================================*
  98. *             Conditions aux limites - Traction suivant UY             *
  99. *======================================================================*
  100. BL1 = 'BLOQUER' 'UY  ' L1 ;
  101. BL2 = 'BLOQUER' 'UY  ' L3 ;
  102. BL4 = 'BLOQUER' 'UX  ' P1 ;
  103. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  104. *
  105. * Definition des instants du chargement :
  106. t_deb = 0. ;   t_fin = 10. ;
  107. L_tps = 'PROG' t_deb t_fin ;
  108. * Deplacement suivant Y :
  109. L_UY = 'PROG' 0. ( 5. * Lg_y) ;
  110. *
  111. FF_y = 'DEPIMP' BL2 1. ;
  112. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  113. *
  114. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  115. *
  116. *======================================================================*
  117. *             Initialisation de la table pour appel a PASAPAS          *
  118. *======================================================================*
  119. TAB1 = 'TABLE' ;
  120. TAB1.'MODELE' = MO ;
  121. TAB1.'CARACTERISTIQUES' = MA ;
  122. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  123. TAB1.'CHARGEMENT' = CHARTOT ;
  124. ***** LG
  125. *TAB1 . 'DELTAITER' = 150;
  126. *TAB1.'PRECISION' = 1.E-5 ;
  127. *TAB1.'FTOL' = 1.E-5 ;
  128. *TAB1.'MTOL' = 1.E-5 ;
  129. *****
  130. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  131. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  132. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  133. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  134. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  135. *
  136. L_abs = TAB1.'TEMPS_SAUVES' ;
  137. n_abs = 'DIMENSION' L_abs ;
  138. *
  139. PASAPAS TAB1 ;
  140. *
  141. * Quelques traces de controle apres calculs
  142. 'SI' GRAPH ;
  143.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  144.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  145.   'TRACER' (Defo_0 'ET' Defo_1)
  146.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  147.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  148.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  149. 'FINSI' ;
  150. *
  151. *======================================================================*
  152. *             Construction de la solution analytique                   *
  153. *======================================================================*
  154. * Definitions : 
  155. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  156. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  157. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  158. * Dans le cas du modele GD  : Incompressible
  159. * Les contraintes de Cauchy sont calculables analytiquement :
  160. * - SCxx = 0.
  161. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  162. * - SCxy = 0  (pas de cisaillement)
  163. * - SCzz = 0  (hypothese des contraintes planes)
  164. *
  165. L_Un  = 'PROG' n_abs '*' 1. ;
  166. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  167. *
  168. L_z1 = Lamy * Lamy ;  L_z2 = L_Un / (Lamy *Lamy);
  169. * LG modif hartsmith !! averifier
  170. L_tr = L_Un * 3.;
  171. I1 = L_z1 + (2. * L_z2);
  172. I1 = L_z1 + L_Un + L_z2;
  173. I2=I1;
  174. ************************************************************************ 
  175. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  176. dWI2= 3. * H2 * L_Un / (I2**0.5);
  177. ************************************************************************* 
  178. *dWI1=C1;
  179. *dWI2=C2;
  180. ******************
  181. SCxx_th = 0. * L_Un ;
  182. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_Un)) ;
  183. SCxy_th = 0. * L_Un ;
  184. *
  185. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  186. *dess  Evyy_th ;
  187.  
  188. *======================================================================*
  189. *             Comparaison des resultats avec la solution analytique    *
  190. *======================================================================*
  191. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  192. * calculees et les solutions analytiques correspondantes.
  193. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  194. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  195. *
  196. TabD = TAB1.'DEPLACEMENTS' ;
  197. TabS = TAB1.'CONTRAINTES' ;
  198. Confini = 'FORM' ;
  199. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  200. *
  201. SCxx = 'PROG' 0. ;
  202. SCyy = 'PROG' 0. ;
  203. SCxy = 'PROG' 0. ;
  204. 'REPETER' Boucle (n_abs - 1) ;
  205.   'FORM' (TabD.&Boucle) ;
  206.   VolSU = 'INTG' MO ChmUn ;
  207.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  208.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  209.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  210.   'FORM' Confini ;
  211. 'FIN' Boucle ;
  212. *  LG lamb
  213. L_abs = Lamy;
  214. *
  215. 'SI' GRAPH ;
  216.   tlege = 'TABLE' ;
  217.   tlege. 1 = 'MARQ CROI' ;
  218.   tlege.'TITRE' = 'TABLE' ;
  219.   tlege.'TITRE'. 1 = 'Numerique' ;
  220.   tlege.'TITRE'. 2 = 'Analytique' ;
  221.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  222.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  223.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  224.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  225.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  226.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  227.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  228.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  229.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  230.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  231.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  232.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  233. 'FINSI' ;
  234. *
  235. * Tests de bon fonctionnement :
  236. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  237. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  238. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  239. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  240. *
  241. MESS ' RESULTATS : ' title ;
  242. MESS ' ------------------------------------------------- ';
  243. 'SAUTER' 1 'LIGNE' ;
  244. 'MESS' '  Tests de bon fonctionnement :' ;
  245. 'MESS' ' -------------------------------' ;
  246. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  247. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  248.        'calculee' ;
  249. 'MESS' '                          et la '
  250.        'solution analytique associee' ;
  251. 'MESS' ' Composante XX : ' r_xx ;
  252. 'MESS' ' Composante YY : ' r_yy ;
  253. 'MESS' ' Composante XY : ' r_xy ;
  254. 'SAUTER' 1 'LIGNE' ;
  255. * Ecart relatif maximal tolere
  256. Sigref = 1.E-3 ;
  257. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  258.   'MESS' ' ---------------------' ;
  259.   'MESS' '  ECHEC DU CAS-TEST !' ;
  260.   'MESS' ' ---------------------' ;
  261.   'ERREUR' 5 ;
  262. 'SINON' ;
  263.   'MESS' ' ----------------------' ;
  264.   'MESS' '  SUCCES DU CAS-TEST !' ;
  265.   'MESS' ' ----------------------' ;
  266. 'FINSI' ;
  267. 'SAUTER' 1 'LIGNE' ;
  268. 'FIN' ;
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales