Télécharger la plaquette Cast3M


fr en

Télécharger gdtract3d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. optio debug 1;
  2. * fichier : gdtract3d.dgibi
  3. *======================================================================*
  4. *         MODELE HYPERELASTIQUE GORNET-DESMORAT QUASI-INCOMPRESSIBLE   *
  5. *                  EN GRANDES TRANSFORMATIONS                          *
  6. *                                                                      *
  7. *   TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z    *
  8. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE             *
  9. *                                                                      *
  10. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  11. *======================================================================*
  12. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  13. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  14. *======================================================================*
  15. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  16. *                                                                      *
  17. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  18. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  19. *         pas melanger les derivees objectives et les modeles de C3m.  *
  20. *======================================================================*
  21.  
  22. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  23. *opti trac PSC;
  24. * Mettre VRAI si l'on souhaite divers traces.
  25. GRAPH = VRAI ;
  26. GRAPH = Faux;
  27. * Mettre 1 ou 2 selon le type de calcul voulu
  28. ICALCUL = 1;
  29. *
  30. 'SI' ('>' ICALCUL 2) ;
  31.   'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  32.   'ERREUR' 5 ;
  33. 'FINSI' ;
  34.  
  35. title = 'CHAINE' 'GORNET-DESMORAT - ' 'TRACTION UNIAXIALE Z' ;
  36.  
  37. *======================================================================*
  38. *             Geometrie - Maillage                                     *
  39. *======================================================================*
  40. * Longueur (direction x) du pave :
  41. Lg_x = 1. ;
  42. * Largeur (direction y) du pave :
  43. Lg_y = 1. ;
  44. * Hauteur (direction z) du pave :
  45. Lg_z = 1. ;
  46. * Nombre d'elements selon les directions x, y et z :
  47. 'SI' ('EGA' ICALCUL 1) ;
  48.   Nel_x = 2  ;
  49.   Nel_y = 2  ;
  50.   Nel_z = 2 ;
  51. * 'TET4' 'PRI6'  'PYR5' 'TET4' 'CUB8'
  52.   'OPTION' 'ELEM' 'CUB8'  ;
  53. 'FINSI' ;
  54. 'SI' ('EGA' ICALCUL 2) ;
  55.   Nel_x = 3 ;
  56.   Nel_y = 3 ;
  57.   Nel_z = 3 ;
  58. *CU20  
  59.   'OPTION' 'ELEM' 'CUB8';
  60. 'FINSI' ;
  61. *'CU20'
  62. P1 =  0.    0. 0. ;
  63. P2 = Lg_x   0. 0. ;
  64. P3 = Lg_x Lg_y 0. ;
  65. P4 =  0.  Lg_y 0. ;
  66. *
  67. L1 = 'DROITE' Nel_x P1 P2 ;
  68. L2 = 'DROITE' Nel_y P2 P3 ;
  69. L3 = 'DROITE' Nel_x P3 P4 ;
  70. L4 = 'DROITE' Nel_y P4 P1 ;
  71. *
  72. SBas = 'DALLER' L1 L2 L3 L4 ;
  73. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  74. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  75. 'SI' GRAPH ;
  76.   'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  77. 'FINSI' ;
  78.  
  79. *======================================================================*
  80. *             Modele - Materiau - Caracteristiques (en MPa)             *
  81. *======================================================================*
  82. * Ne pas oublier de definir les parametres lies a l'elasticite.
  83. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  84. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  85. *
  86. LCMAT = MOTS 'YOUN' 'NU  '    'H1'  'H2'  'H3'  'D  ' ;
  87. MO = MODE Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  88.                     'NON_LINEAIRE' 'UTILISATEUR'
  89.                 'NUME_LOI' 33  'C_MATERIAU' LCMAT ;
  90. *
  91. * Pour calculer le module d'Young, on utilise les
  92. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  93. * 
  94. C1 = 0.183  ;     C2 = 0.0034   ;
  95. * 
  96. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  97. * du fait de l'incompressibilite inherente au modele.
  98. * Le module de Young YOU est alors connu, car, pour ce modele, le
  99. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  100. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  101. * de la traction. En fonction du niveau de deformation atteinte en 
  102. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  103. * converger les calculs (module tangent en fin de calculs).
  104. * Prendre des valeurs superieures n'entraine pas de modification des
  105. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  106.  
  107.  
  108. *XNU = 0.497 ;
  109. YOUini = 3.*(2.*(C1+C2)) ;  
  110. *
  111. 'SI' ('EGA' ICALCUL 1) ;
  112.   XNU = 0.497 ;
  113.   CoeD  = 1.E-4   ; 
  114.   YOU = 100. * YOUini ;
  115. 'FINSI' ;
  116. 'SI' ('EGA' ICALCUL 2) ;
  117.   XNU = 0.497;
  118.   CoeD  = 1.E-4   ;  
  119. *  YOU = 50000. * YOUini ;
  120.   YOU = 100. * YOUini ;
  121. 'FINSI' ;
  122. *
  123. *Parametres du modèle GD : essais Treloar/Kawabata MPa
  124. H1 = 0.142236  ;
  125. H2 = 1.5854659E-2   ;
  126. H3 = 3.4946541E-4   ;
  127. *
  128. * 
  129. MA = MATE MO 'YOUN' YOU 'NU  ' XNU  'H1' H1 'H2' H2 
  130. 'H3' H3  'D   ' CoeD ;
  131. *==================================================================*
  132. *                      Conditions aux limites                      *
  133. *==================================================================*
  134. BL1 = 'BLOQUER' 'UZ  ' Shau ;
  135. BL2 = 'BLOQUER' 'UZ  ' Sbas ;
  136. BL3 = 'BLOQUER' 'UX  ' L4 ;
  137. BL4 = 'BLOQUER' 'UY  ' L1 ;
  138. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  139. *
  140. * Definition des instants du chargement :
  141. t_deb = 0. ;   t_fin = 10. ;
  142. L_tps = 'PROG' t_deb t_fin ;
  143. * Deplacement suivant Z : 
  144. L_UZ = 'PROG' 0. (6.  * Lg_z) ;
  145. FF_z = 'DEPIMP' BL1 1. ;
  146. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMZ' L_UZ ;
  147. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  148.  
  149. *======================================================================*
  150. *             Initialisation de la table pour appel a PASAPAS          *
  151. *======================================================================*
  152. TAB1 = 'TABLE' ;
  153. TAB1.'MODELE' = MO ;
  154. TAB1.'CARACTERISTIQUES' = MA ;
  155. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  156. TAB1.'CHARGEMENT' = CHARTOT ;
  157. *TAB1.'PAS_AJUSTE'= VRAI;
  158. TAB1.'PRECISION' = 1.E-7 ;
  159. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  160. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  161. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  162. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.02 t_fin ;
  163. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  164. *
  165. L_abs = TAB1.'TEMPS_SAUVES' ;
  166. n_abs = 'DIMENSION' L_abs ;
  167. *
  168. PASAPAS TAB1 ;
  169. *
  170. * Quelques traces de controle apres calculs
  171. 'SI' GRAPH ;
  172.   Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  173.   Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  174.   'TRACER' (Defo_0 'ET' Defo_1)
  175.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  176.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  177.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  178. 'FINSI' ;
  179. *
  180. *======================================================================*
  181. *             Construction de la solution analytique INCOMPRESSIBLE    *
  182. *======================================================================*
  183. * Definitions :
  184. * - Allongement selon direction y : Lamz = 1 + (UY/Lg_y)
  185. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  186. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  187. * Dans le cas du modele GD  : Incompressible
  188. * Les contraintes de Cauchy sont calculables analytiquement :
  189. * - SCzz = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  190. *
  191. L_Un  = 'PROG' n_abs '*' 1. ;
  192. Lamz  = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  193. *
  194. SCxx_th = 0. * L_Un ;
  195. SCyy_th = 0. * L_Un ;
  196. L_z1 = Lamz * Lamz ;  L_z2 = L_Un / Lamz ;
  197. L_tr = L_Un * 3.;
  198. I1 = L_z1 + (2. * L_z2);
  199. I2 = (2. * Lamz) + ( L_Un /  L_z1 );
  200. ************************************************************************           
  201. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  202. dWI2= 3. * H2 * L_Un / (I2**0.5);
  203. ************************************************************************
  204. SCzz_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  205. SCxy_th = 0. * L_Un ;
  206. SCxz_th = 0. * L_Un ;
  207. SCyz_th = 0. * L_Un ;
  208. * 
  209. *======================================================================*
  210. *             Comparaison des resultats avec la solution analytique    *
  211. *======================================================================*
  212. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  213. * calculees et les solutions analytiques correspondantes.
  214. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  215. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  216. *
  217. TabD = TAB1.'DEPLACEMENTS' ;
  218. TabS = TAB1.'CONTRAINTES' ;
  219. Confini = 'FORM' ;
  220. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  221. *
  222. SCxx = 'PROG' 0. ;
  223. SCyy = 'PROG' 0. ;
  224. SCzz = 'PROG' 0. ;
  225. SCxy = 'PROG' 0. ;
  226. SCxz = 'PROG' 0. ;
  227. SCyz = 'PROG' 0. ;
  228. 'REPETER' Boucle (n_abs - 1) ;
  229.   'FORM' (TabD.&Boucle) ;
  230.   VolSU = 'INTG' MO ChmUn ;
  231. *  mess ' volsu '  volsu; 
  232.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  233.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  234.   SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  235.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  236.   SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  237.   SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  238.   'FORM' Confini ;
  239. 'FIN' Boucle ;
  240. *
  241. *  LG lamb
  242. L_abs = Lamz;
  243. *
  244. 'SI' GRAPH ;
  245.   tlege = 'TABLE' ;
  246.   tlege. 1 = 'MARQ CROI' ;
  247.   tlege.'TITRE' = 'TABLE' ;
  248.   tlege.'TITRE'. 1 = 'Numerique' ;
  249.   tlege.'TITRE'. 2 = 'Analytique' ;
  250.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  251.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  252.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  253.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  254.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  255.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  256.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  257.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  258.   Evzz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  259.   Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  260.   'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  261.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  262.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  263.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  264.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  265.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  266.   Evxz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  267.   Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  268.   'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  269.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  270.   Evyz    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  271.   Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  272.   'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  273.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  274. 'FINSI' ;
  275. *
  276. * Tests de bon fonctionnement :
  277. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  278. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  279. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  280. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  281. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  282. list sczz; list SCzz_th;  list uu;
  283. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  284. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  285. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  286. *
  287. MESS ' RESULTATS : ' title ;
  288. MESS ' ------------------------------------------------- ';
  289. 'SAUTER' 1 'LIGNE' ;
  290. 'MESS' '  Tests de bon fonctionnement :' ;
  291. 'MESS' ' -------------------------------' ;
  292. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  293. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  294. 'MESS' '                          et la solution analytique' ;
  295. 'MESS' ' Composante XX : ' r_xx ;
  296. 'MESS' ' Composante YY : ' r_yy ;
  297. 'MESS' ' Composante ZZ : ' r_zz ;
  298. 'MESS' ' Composante XY : ' r_xy ;
  299. 'MESS' ' Composante XZ : ' r_xz ;
  300. 'MESS' ' Composante YZ : ' r_yz ;
  301. 'SAUTER' 1 'LIGNE' ;
  302. * Ecart relatif maximal tolere
  303. 'SI' ('EGA' ICALCUL 1) ;
  304.   Sigref = 1.E-3 ;
  305. 'FINSI' ;
  306. 'SI' ('EGA' ICALCUL 2) ;
  307.   Sigref = 1.E-2 ;
  308. 'FINSI' ;
  309. *
  310. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  311. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  312.   'MESS' ' ---------------------' ;
  313.   'MESS' '  ECHEC DU CAS-TEST !' ;
  314.   'MESS' ' ---------------------' ;
  315.   'ERREUR' 5 ;
  316. 'SINON' ;
  317.   'MESS' ' ----------------------' ;
  318.   'MESS' '  SUCCES DU CAS-TEST !' ;
  319.   'MESS' ' ----------------------' ;
  320. 'FINSI' ;
  321. 'SAUTER' 1 'LIGNE' ;
  322. 'FIN' ;
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales